wasi-libc/trunk/PKGBUILD

   1 # Maintainer: Frederik Schwan <freswa at archlinux dot org>
   2
   3 pkgname=wasi-libc
   4 pkgver=0+328+1dfe5c3
   5 _commit=1dfe5c302d1c5ab621f7abf04620fae92700fd22  # main
   6 pkgrel=1
   7 epoch=1
   8 pkgdesc='WASI libc implementation for WebAssembly'
   9 arch=('any')
  10 url='https://github.com/WebAssembly/wasi-libc'
  11 license=('Apache' 'MIT')
  12 makedepends=('git' 'llvm' 'clang')
  13 source=("git+https://github.com/WebAssembly/wasi-libc.git#commit=${_commit}")
  14 b2sums=('SKIP')
  15 options=('staticlibs')
  16
  17 pkgver() {
  18   cd ${pkgname}
  19   printf "0+%s+%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
  20 }
  21
  22 build() {
  23   local make_options=(
  24     WASM_CC=/usr/bin/clang
  25     WASM_AR=/usr/bin/llvm-ar
  26     WASM_NM=/usr/bin/llvm-nm
  27
  28     # Remove bulk memory support
  29     # https://bugzilla.mozilla.org/show_bug.cgi?id=1773200#c4
  30     BULK_MEMORY_SOURCES=
  31   )
  32
  33   cd ${pkgname}
  34   make "${make_options[@]}"
  35 }
  36
  37 package() {
  38   cd ${pkgname}
  39   install -dm755 "${pkgdir}"/usr/share
  40   cp -dr --preserve=mode,timestamp sysroot "${pkgdir}"/usr/share/wasi-sysroot
  41 }