wimlib/trunk/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2 # Contributor: Alad Wenter <alad@mailbox.org>
   3 # Contributor: Eric Biggers <ebiggers3 at gmail dot com>
   4
   5 pkgname=wimlib
   6 pkgver=1.14.1
   7 pkgrel=1
   8 pkgdesc='A library and program to extract, create, and modify WIM files'
   9 arch=('x86_64')
  10 url='https://wimlib.net'
  11 license=('custom')
  12 depends=('fuse3' 'ntfs-3g')
  13 checkdepends=('attr')
  14 optdepends=(
  15   'cdrkit: for making ISO image of Windows PE'
  16   'mtools: for making disk image of Windows PE'
  17   'syslinux: for making disk image of Windows PE'
  18   'cabextract: for extracting Windows PE from the WAIK'
  19 )
  20 provides=('libwim.so')
  21 source=("https://wimlib.net/downloads/$pkgname-$pkgver.tar.gz")
  22 sha512sums=('9f92a8ce2d386918d66a1a3e52d4fbffeeb9f8b9345b25012fd0bd07039a00be84fd83d83a9bb25bcefab09597a81e9392522be835dd6693dd00050f8624af00')
  23 b2sums=('56e44928229c9c4fda662fa64fc4021bd361c2c959f0786764b84fa4cc9d7f7b0d5440edb4d4079657cc7bf450ac9c755f554c7da7a8b2b7e96d69ddbeb4f22f')
  24
  25 build() {
  26   cd "$pkgname-$pkgver"
  27
  28   ./configure \
  29     --disable-static \
  30     --with-libcrypto \
  31     --with-fuse \
  32     --with-ntfs-3g \
  33     --prefix=/usr
  34
  35   make
  36 }
  37
  38 check() {
  39   cd "$pkgname-$pkgver"
  40
  41   make check
  42 }
  43
  44 package() {
  45   cd "$pkgname-$pkgver"
  46
  47   make DESTDIR="$pkgdir" install
  48
  49   # documentation
  50   install -Dm644 {NEWS,README}.md -t "$pkgdir/usr/share/doc/$pkgname"
  51
  52   # licenses
  53   install -Dm644 COPYING* -t "$pkgdir/usr/share/licenses/$pkgname"
  54 }