xdot/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Randy Heydon <randy.heydon at clockworklab dot net>
   3
   4 pkgname=xdot
   5 _pkgname=${pkgname}.py
   6 pkgver=1.2
   7 pkgrel=3
   8 pkgdesc="Interactive viewer for graphs written in Graphviz's dot language"
   9 url='https://github.com/jrfonseca/xdot.py'
  10 arch=('any')
  11 license=('LGPL2.1')
  12 depends=('graphviz' 'gtk3' 'python' 'python-cairo' 'python-gobject' 'python-numpy')
  13 makedepends=('python-build' 'python-installer' 'python-setuptools' 'python-wheel')
  14 checkdepends=('xorg-server-xvfb')
  15 source=(${pkgname}-${pkgver}.tar.gz::https://github.com/jrfonseca/${_pkgname}/archive/${pkgver}.tar.gz
  16         xdot.desktop)
  17 sha512sums=('b4d3b15114b982c7c38cc71c0602f6d1ba9874c7315c2b8c4a8a48bf7674e9b38bf19a0d4a2d319acc9a29cf8f177a651d4e213761e88b0b3cb26e95e8a92dda'
  18             '7bd7994f03c4d7634a9ab780423f1e9d647df0836fd6d8f825dc0bac6ad506ad44457ba473367d1a16b89d00f441c730cb2b66cb5c300542addcf622be82c867')
  19
  20 build() {
  21   cd ${_pkgname}-${pkgver}
  22   python -m build --wheel --no-isolation
  23 }
  24
  25 check() {
  26   cd ${_pkgname}-${pkgver}
  27   xvfb-run python test.py
  28 }
  29
  30 package() {
  31   cd ${_pkgname}-${pkgver}
  32   python -m installer --destdir="$pkgdir" dist/*.whl
  33   install -Dm 644 ../xdot.desktop -t "${pkgdir}/usr/share/applications"
  34 }
  35
  36 # vim: ts=2 sw=2 et: