CMakeLua/Tests/FunctionTest/CMakeLists.txt

   1 # a simple C only test case
   2 cmake_minimum_required (VERSION 2.6)
   3 PROJECT (FunctionTest)
   4
   5 SET(CMAKE_C_FLAGS "${CMAKE_ANSI_CFLAGS} ${CMAKE_C_FLAGS}")
   6
   7 FUNCTION(FAILED testname)
   8   MESSAGE(SEND_ERROR "${testname} failed ${ARGN}")
   9 ENDFUNCTION(FAILED)
  10
  11 FUNCTION(PASS testname)
  12   MESSAGE("${testname} passed ${ARGN}")
  13 ENDFUNCTION(PASS)
  14
  15
  16 # test scope
  17 SET(COUNT 3)
  18 FUNCTION(scope_test)
  19   SET(COUNT 4)
  20 ENDFUNCTION(scope_test)
  21 scope_test()
  22 IF(COUNT EQUAL "3")
  23   PASS("scope")
  24 ELSE(COUNT EQUAL "3")
  25   FAILED("COUNT Got: ${COUNT}")
  26 ENDIF(COUNT EQUAL "3")
  27
  28 # test ARGC
  29 FUNCTION(weird_name)
  30   IF("${ARGC}" EQUAL "3")
  31     PASS("ARGC")
  32   ELSE("${ARGC}" EQUAL "3")
  33     FAILED("ARGC" "Got: ${ARGC}")
  34   ENDIF("${ARGC}" EQUAL "3")
  35 ENDFUNCTION(weird_name)
  36 WeIrD_nAmE(a1 a2 a3)
  37
  38 # test ARGN
  39 FUNCTION(test_argn_function argument)
  40   IF("${ARGN}" EQUAL "3")
  41     PASS("ARGN")
  42   ELSE("${ARGN}" EQUAL "3")
  43     FAILED("ARGN" "Got: ${ARGN}")
  44   ENDIF("${ARGN}" EQUAL "3")
  45 ENDFUNCTION(test_argn_function)
  46 Test_Argn_Function(ignored 3)
  47
  48 # test argument naming and raise scope
  49 function(track_find_variable cache_variable is_changed)
  50  set("${is_changed}" changed PARENT_SCOPE)
  51 endfunction(track_find_variable)
  52 track_find_variable(testvar is_changed)
  53 if ("${is_changed}" STREQUAL changed)
  54   pass("same argument name test")
  55 else ("${is_changed}" STREQUAL changed)
  56   pass("same argument name test")
  57 endif ("${is_changed}" STREQUAL changed)
  58
  59 include("Util.cmake")
  60 tester()
  61 if (tester_res STREQUAL "${CMAKE_CURRENT_LIST_FILE}")
  62   pass("CMAKE_CURRENT_LIST_FILE test")
  63 else (tester_res STREQUAL "${CMAKE_CURRENT_LIST_FILE}")
  64   pass("CMAKE_CURRENT_LIST_FILE test")
  65 endif (tester_res STREQUAL "${CMAKE_CURRENT_LIST_FILE}")
  66
  67
  68
  69 # test recursion and return via set(... PARENT_SCOPE)
  70 function (factorial argument result)
  71   if (argument LESS 2)
  72     set (lresult 1)
  73   else (argument LESS 2)
  74     math (EXPR temp "${argument} - 1")
  75     factorial (${temp} tresult)
  76     math (EXPR lresult "${argument}*${tresult}")
  77   endif (argument LESS 2)
  78   set ("${result}" "${lresult}" PARENT_SCOPE)
  79 endfunction (factorial)
  80
  81 factorial (5 fresult)
  82 if (fresult EQUAL 120)
  83   pass("factorial")
  84 else (fresult EQUAL 120)
  85   failed ("factorial, computed ${fresult} instead of 120")
  86 endif (fresult EQUAL 120)
  87
  88
  89
  90 # case test
  91 FUNCTION(strange_function m)
  92   SET("${m}" strange_function PARENT_SCOPE)
  93 ENDFUNCTION(strange_function m)
  94
  95 STRANGE_FUNCTION(var)
  96 set(second_var "second_var")
  97 IF("${var}" STREQUAL "strange_function" AND "${second_var}" STREQUAL "second_var")
  98   PASS("Case Test" "(${var} ${second_var})")
  99 ELSE("${var}" STREQUAL "strange_function" AND "${second_var}" STREQUAL "second_var")
 100   FAILED("Case test" "(${var} ${second_var})")
 101 ENDIF("${var}" STREQUAL "strange_function" AND "${second_var}" STREQUAL "second_var")
 102
 103 # test backing up command
 104 FUNCTION(ADD_EXECUTABLE exec)
 105   _ADD_EXECUTABLE(mini${exec} ${ARGN})
 106 ENDFUNCTION(ADD_EXECUTABLE)
 107
 108 # var undef case
 109 FUNCTION(undef_var m)
 110   SET("${m}" PARENT_SCOPE)
 111 ENDFUNCTION(undef_var)
 112
 113 SET(FUNCTION_UNDEFINED 1)
 114 undef_var(FUNCTION_UNDEFINED)
 115 IF(DEFINED FUNCTION_UNDEFINED)
 116   FAILED("Function Undefine Test" "(${FUNCTION_UNDEFINED})")
 117 ELSE(DEFINED FUNCTION_UNDEFINED)
 118   PASS("Function Undefine Test" "(${FUNCTION_UNDEFINED})")
 119 ENDIF(DEFINED FUNCTION_UNDEFINED)
 120
 121 # Subdirectory scope raise.
 122 SET(SUBDIR_UNDEFINED 1)
 123 ADD_SUBDIRECTORY(SubDirScope)
 124 IF(DEFINED SUBDIR_UNDEFINED)
 125   FAILED("Subdir Undefine Test" "(${SUBDIR_UNDEFINED})")
 126 ELSE(DEFINED SUBDIR_UNDEFINED)
 127   PASS("Subdir Undefine Test" "(${SUBDIR_UNDEFINED})")
 128 ENDIF(DEFINED SUBDIR_UNDEFINED)
 129 IF(DEFINED SUBDIR_DEFINED)
 130   PASS("Subdir Define Test" "(${SUBDIR_DEFINED})")
 131 ELSE(DEFINED SUBDIR_DEFINED)
 132   FAILED("Subdir Define Test" "(${SUBDIR_DEFINED})")
 133 ENDIF(DEFINED SUBDIR_DEFINED)
 134
 135 ADD_EXECUTABLE(FunctionTest functionTest.c)