CMakeLua/Tests/StringFileTest/CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6)
   2 PROJECT(StringFileTest)
   3 INCLUDE_DIRECTORIES(${StringFileTest_BINARY_DIR})
   4
   5 # Read file test
   6 FILE(READ "${CMAKE_CURRENT_SOURCE_DIR}/InputFile.h.in" infile)
   7
   8 # FILE(STRINGS) test
   9 FILE(STRINGS "${CMAKE_CURRENT_SOURCE_DIR}/InputFile.h.in" infile_strings
  10   LIMIT_COUNT 1 LIMIT_INPUT 1024 LIMIT_OUTPUT 1024
  11   LENGTH_MINIMUM 10 LENGTH_MAXIMUM 23 REGEX include NEWLINE_CONSUME)
  12 SET(infile_strings_goal "#include \"includefile\"\n")
  13 IF("${infile_strings}" STREQUAL "${infile_strings_goal}")
  14   MESSAGE("FILE(STRINGS) correctly read [${infile_strings}]")
  15 ELSE("${infile_strings}" STREQUAL "${infile_strings_goal}")
  16   MESSAGE(SEND_ERROR
  17     "FILE(STRINGS) incorrectly read [${infile_strings}]")
  18 ENDIF("${infile_strings}" STREQUAL "${infile_strings_goal}")
  19
  20 # test reading a file and getting its binary data as hex string
  21 FILE(READ "${CMAKE_CURRENT_SOURCE_DIR}/main.srec" infilehex LIMIT 4 HEX)
  22 IF(NOT "${infilehex}" STREQUAL "53313036")
  23   MESSAGE(SEND_ERROR
  24     "FILE(READ ... HEX) error, read: \"${infilehex}\", expected \"53313036\"")
  25 ENDIF(NOT "${infilehex}" STREQUAL "53313036")
  26
  27
  28 # test that FILE(STRINGS) also work with Intel hex and Motorola S-record files
  29 # this file has been created with "sdcc main.c"
  30 FILE(STRINGS "${CMAKE_CURRENT_SOURCE_DIR}/main.ihx" infile_strings REGEX INFO)
  31 SET(infile_strings_goal "INFO:compiler\\[SDCC-HEX\\]")
  32 IF("${infile_strings}" MATCHES "${infile_strings_goal}")
  33   MESSAGE("FILE(STRINGS) correctly read from hex file [${infile_strings}]")
  34 ELSE("${infile_strings}" MATCHES "${infile_strings_goal}")
  35   MESSAGE(SEND_ERROR
  36     "FILE(STRINGS) incorrectly read from hex file [${infile_strings}]")
  37 ENDIF("${infile_strings}" MATCHES "${infile_strings_goal}")
  38
  39 # this file has been created with "sdcc main.c --out-fmt-s19"
  40 FILE(STRINGS "${CMAKE_CURRENT_SOURCE_DIR}/main.srec" infile_strings REGEX INFO)
  41 SET(infile_strings_goal "INFO:compiler\\[SDCC-SREC\\]")
  42 IF("${infile_strings}" MATCHES "${infile_strings_goal}")
  43   MESSAGE("FILE(STRINGS) correctly read from srec file [${infile_strings}]")
  44 ELSE("${infile_strings}" MATCHES "${infile_strings_goal}")
  45   MESSAGE(SEND_ERROR
  46     "FILE(STRINGS) incorrectly read from srec file [${infile_strings}]")
  47 ENDIF("${infile_strings}" MATCHES "${infile_strings_goal}")
  48
  49 # String test
  50 STRING(REGEX MATCH "[cC][mM][aA][kK][eE]" rmvar "CMake is great")
  51 STRING(REGEX MATCHALL "[cC][mM][aA][kK][eE]" rmallvar "CMake is better than cmake or CMake")
  52 STRING(REGEX REPLACE "[Aa][uU][tT][oO]([cC][oO][nN][fF]|[mM][aA][kK][eE])"
  53   "CMake" rrepvar "People should use Autoconf and Automake")
  54 STRING(COMPARE EQUAL "CMake" "Autoconf" nceqvar)
  55 STRING(COMPARE EQUAL "CMake" "CMake" ceqvar)
  56 STRING(COMPARE NOTEQUAL "CMake" "Autoconf" cneqvar)
  57 STRING(COMPARE NOTEQUAL "CMake" "CMake" ncneqvar)
  58 STRING(COMPARE LESS "before" "after" nclvar)
  59 STRING(COMPARE LESS "max" "min" clvar)
  60 STRING(COMPARE GREATER "before" "after" cgvar)
  61 STRING(COMPARE GREATER "max" "min" ncgvar)
  62 STRING(ASCII 67 109 97 107 101 savar)
  63 STRING(TOUPPER "CMake" tuvar)
  64 STRING(TOLOWER "CMake" tlvar)
  65 STRING(REPLACE "Autoconf" "CMake" repvar "People should use Autoconf")
  66
  67 IF("abc" STREQUAL "xyz")
  68   MESSAGE(SEND_ERROR "Problem with the IF(STREQUAL), \"abc\" and \"xyz\" considered equal")
  69 ENDIF("abc" STREQUAL "xyz")
  70
  71 IF("CMake is cool" MATCHES "(CMake) (is).+")
  72   IF(NOT "${CMAKE_MATCH_0}" STREQUAL "CMake is cool")
  73     MESSAGE(SEND_ERROR "CMAKE_MATCH_0 wrong: \"${CMAKE_MATCH_0}\", expected \"CMake is cool\"")
  74   ENDIF(NOT "${CMAKE_MATCH_0}" STREQUAL "CMake is cool")
  75   IF(NOT "${CMAKE_MATCH_1}" STREQUAL "CMake")
  76     MESSAGE(SEND_ERROR "CMAKE_MATCH_1 wrong: \"${CMAKE_MATCH_1}\", expected \"CMake\"")
  77   ENDIF(NOT "${CMAKE_MATCH_1}" STREQUAL "CMake")
  78   IF(NOT "${CMAKE_MATCH_2}" STREQUAL "is")
  79     MESSAGE(SEND_ERROR "CMAKE_MATCH_2 wrong: \"${CMAKE_MATCH_2}\", expected \"is\"")
  80   ENDIF(NOT "${CMAKE_MATCH_2}" STREQUAL "is")
  81 ELSE("CMake is cool" MATCHES "(CMake) (is).+")
  82   MESSAGE(SEND_ERROR "Problem with the IF(MATCHES), no match found")
  83 ENDIF("CMake is cool" MATCHES "(CMake) (is).+")
  84
  85 STRING(REGEX MATCH "(People).+CMake" matchResultVar "People should use CMake")
  86 IF(NOT "${matchResultVar}" STREQUAL "People should use CMake")
  87   MESSAGE(SEND_ERROR "STRING(REGEX MATCH) problem: \"${matchResultVar}\", expected \"People should use CMake\"")
  88 ENDIF(NOT "${matchResultVar}" STREQUAL "People should use CMake")
  89 IF(NOT "${CMAKE_MATCH_0}" STREQUAL "People should use CMake")
  90   MESSAGE(SEND_ERROR "CMAKE_MATCH_0 wrong: \"${CMAKE_MATCH_0}\", expected \"People should use CMake\"")
  91 ENDIF(NOT "${CMAKE_MATCH_0}" STREQUAL "People should use CMake")
  92 IF(NOT "${CMAKE_MATCH_1}" STREQUAL "People")
  93   MESSAGE(SEND_ERROR "CMAKE_MATCH_1 wrong: \"${CMAKE_MATCH_1}\", expected \"People\"")
  94 ENDIF(NOT "${CMAKE_MATCH_1}" STREQUAL "People")
  95 IF(NOT "${CMAKE_MATCH_2}" STREQUAL "")
  96   MESSAGE(SEND_ERROR "CMAKE_MATCH_2 wrong: \"${CMAKE_MATCH_2}\", expected empty string")
  97 ENDIF(NOT "${CMAKE_MATCH_2}" STREQUAL "")
  98
  99
 100 STRING(STRIP "
 101   ST1
 102   " ST1)
 103 STRING(STRIP "ST2 " ST2)
 104 STRING(STRIP "  ST3" ST3)
 105
 106 FOREACH(var ST1 ST2 ST3)
 107   IF("${var}" STREQUAL "${${var}}")
 108     MESSAGE("[${var}] == [${${var}}]")
 109   ELSE("${var}" STREQUAL "${${var}}")
 110     MESSAGE(SEND_ERROR "Problem with the STRIP command for ${var}: [${${var}}]")
 111   ENDIF("${var}" STREQUAL "${${var}}")
 112 ENDFOREACH(var)
 113
 114 STRING(SUBSTRING "People should use Autoconf" 7 10 substringres)
 115 SET(substringres "Everybody ${substringres} CMake")
 116
 117 STRING(LENGTH ${substringres} lengthres)
 118
 119 FILE(RELATIVE_PATH relpath "/usr/local/bin" "/usr/X11R6/bin/xnest")
 120
 121 # Escaping test
 122 SET(var "\\ \" \  \t \n \r \# \( \) \0")
 123 MESSAGE("Output: [${var}]")
 124 SET(var \\ \" \  \t \n \r \# \( \) \0)
 125 MESSAGE("Output: [${var}]")
 126
 127 # Make-style unquoted argument test
 128 SET(var $(VAR1)$(VAR2)/$(VAR3))
 129 MESSAGE("Output: [${var}]")
 130 STRING(COMPARE EQUAL "${var}" "$(VAR1)$(VAR2)/$(VAR3)" result)
 131 IF(NOT result)
 132   MESSAGE(SEND_ERROR "Unquoted $(VAR) syntax is broken.")
 133 ENDIF(NOT result)
 134
 135 # Make directories test
 136 FILE(MAKE_DIRECTORY
 137   "${CMAKE_CURRENT_BINARY_DIR}/Includes"
 138   "${CMAKE_CURRENT_BINARY_DIR}/Directory1"
 139   "${CMAKE_CURRENT_BINARY_DIR}/Directory2"
 140   )
 141
 142 # Write results to the file (test write file)
 143 SET(file "${CMAKE_CURRENT_BINARY_DIR}/Includes/Values.h")
 144 FILE(WRITE "${file}" "/* this file is generated */\n")
 145 FOREACH(var
 146     rmvar
 147     rmallvar
 148     rrepvar
 149     repvar
 150     relpath
 151     substringres
 152     lengthres
 153     nceqvar
 154     ceqvar
 155     cneqvar
 156     ncneqvar
 157     nclvar
 158     clvar
 159     cgvar
 160     ncgvar
 161     savar
 162     tuvar
 163     tlvar)
 164   FILE(APPEND "${file}" "#define ${var} \"${${var}}\"\n")
 165 ENDFOREACH(var)
 166
 167 # Verify that the file was created recently.
 168 IF(NOT "${file}" IS_NEWER_THAN "${CMAKE_CURRENT_SOURCE_DIR}/InputFile.h.in")
 169   MESSAGE(FATAL_ERROR "IF(FILE_IS_NEWER) does not seem to work.")
 170 ENDIF(NOT "${file}" IS_NEWER_THAN "${CMAKE_CURRENT_SOURCE_DIR}/InputFile.h.in")
 171
 172 # Test configuration of the string
 173 SET(TEST_DEFINED 123)
 174 SET(TEST_NOT_DEFINED)
 175 STRING(CONFIGURE "${infile}" infile+-/out @ONLY)
 176 SET(infile "${infile+-/out}")
 177
 178 # Write include file to a file
 179 STRING(REGEX REPLACE "includefile" "${file}" outfile "${infile}")
 180 FILE(WRITE "${CMAKE_CURRENT_BINARY_DIR}/OutputFile.h" "${outfile}")
 181
 182 # Test file glob
 183 FILE(GLOB_RECURSE src_files "${CMAKE_CURRENT_SOURCE_DIR}/*")
 184 MESSAGE("Files in ${CMAKE_CURRENT_SOURCE_DIR} are ${src_files}")
 185 SET(expr "${CMAKE_CURRENT_SOURCE_DIR}/[sS][!a-su-zA-Z0-9][^a-qs-zA-Z0-9]ing?ile*.cxx")
 186 MESSAGE("Glob expression is [${expr}].")
 187 FILE(GLOB src_files "${expr}")
 188 MESSAGE("Globbed files [${src_files}].")
 189 ADD_EXECUTABLE(StringFileTest ${src_files})
 190
 191 SET(expr "${CMAKE_CURRENT_SOURCE_DIR}/../*.cxx")
 192 FILE(GLOB_RECURSE rel_src_files RELATIVE "${CMAKE_CURRENT_SOURCE_DIR}/.." "${expr}")
 193 MESSAGE("Globbed files [${rel_src_files}].")
 194
 195 # Test FOREACH range
 196 MESSAGE("Cheack if FOREACH with RANGE works")
 197 MACRO(TEST_RANGE ARGS CHECK)
 198   SET(r)
 199   FOREACH(a RANGE ${ARGS})
 200     SET(r ${r} ${a})
 201   ENDFOREACH(a)
 202   MESSAGE("FOREACH with RANGE ${ARGS} produces ${r}")
 203   IF("x${r}x" MATCHES "^x${CHECK}x$")
 204   ELSE("x${r}x" MATCHES "^x${CHECK}x$")
 205     MESSAGE(SEND_ERROR "The range resulted in: ${r} should be ${CHECK}")
 206   ENDIF("x${r}x" MATCHES "^x${CHECK}x$")
 207 ENDMACRO(TEST_RANGE)
 208 TEST_RANGE("5" "0;1;2;3;4;5")
 209 TEST_RANGE("3;5" "3;4;5")
 210 TEST_RANGE("5;3" "5;4;3")
 211 TEST_RANGE("3;10;2" "3;5;7;9")
 212 TEST_RANGE("10;0;-3" "10;7;4;1")