CMakeLua/Source/QtDialog/CMakeLists.txt

   1 PROJECT(QtDialog)
   2 SET(QT_MIN_VERSION "4.2.0")
   3 FIND_PACKAGE(Qt4 REQUIRED)
   4
   5 IF(NOT QT4_FOUND)
   6   MESSAGE(SEND_ERROR "Failed to find Qt 4.3 or greater.")
   7 ELSE(NOT QT4_FOUND)
   8
   9   INCLUDE(${QT_USE_FILE})
  10   SET(CMAKE_PACKAGE_QTGUI TRUE)
  11   # i don't want to install or package the qt gui on windows
  12   # unless qt is static
  13   IF(WIN32 AND NOT QT_CONFIG MATCHES "static")
  14     SET(CMAKE_PACKAGE_QTGUI FALSE)
  15   ENDIF(WIN32 AND NOT QT_CONFIG MATCHES "static")
  16   CONFIGURE_FILE("${QtDialog_SOURCE_DIR}/QtDialogCPack.cmake.in"
  17     "${QtDialog_BINARY_DIR}/QtDialogCPack.cmake" @ONLY)
  18   SET(SRCS
  19     AddCacheEntry.cxx
  20     AddCacheEntry.h
  21     CMakeSetup.cxx
  22     CMakeSetupDialog.cxx
  23     CMakeSetupDialog.h
  24     QCMake.cxx
  25     QCMake.h
  26     QCMakeCacheView.cxx
  27     QCMakeCacheView.h
  28     )
  29   QT4_WRAP_UI(UI_SRCS
  30     CMakeSetupDialog.ui
  31     AddCacheEntry.ui
  32     )
  33   QT4_WRAP_CPP(MOC_SRCS
  34     AddCacheEntry.h
  35     CMakeSetupDialog.h
  36     QCMake.h
  37     QCMakeCacheView.h
  38     )
  39   QT4_ADD_RESOURCES(RC_SRCS CMakeSetup.qrc)
  40
  41   SET(SRCS ${SRCS} ${UI_SRCS} ${MOC_SRCS} ${RC_SRCS})
  42   IF(Q_WS_WIN)
  43     SET(SRCS ${SRCS} CMakeSetup.rc)
  44   ENDIF(Q_WS_WIN)
  45   IF(Q_WS_MAC)
  46     SET(SRCS ${SRCS} CMakeSetup.icns)
  47     SET(MACOSX_BUNDLE_ICON_FILE CMakeSetup.icns)
  48     SET_SOURCE_FILES_PROPERTIES(CMakeSetup.icns PROPERTIES
  49       MACOSX_PACKAGE_LOCATION Resources)
  50   ENDIF(Q_WS_MAC)
  51
  52   INCLUDE_DIRECTORIES(${CMAKE_CURRENT_BINARY_DIR})
  53   INCLUDE_DIRECTORIES(${CMAKE_CURRENT_SOURCE_DIR})
  54
  55   ADD_EXECUTABLE(cmake-gui WIN32 MACOSX_BUNDLE ${SRCS})
  56   TARGET_LINK_LIBRARIES(cmake-gui CMakeLib ${QT_QTMAIN_LIBRARY} ${QT_LIBRARIES})
  57   # if qt is not static and we are on windows then skip the install
  58   # I don't want to distribute qt dlls
  59   IF(CMAKE_PACKAGE_QTGUI)
  60     INSTALL_TARGETS(/bin cmake-gui)
  61   ENDIF(CMAKE_PACKAGE_QTGUI)
  62
  63 ENDIF(NOT QT4_FOUND)
  64