perl/etc/pmver

   1 #! /usr/bin/perl -w
   2 #---------------------------------------------------------------------
   3 # $Id: pmver.pl 2537 2011-10-27 07:20:59Z cjm $
   4 # Copyright 2007 Christopher J. Madsen <perl@cjmweb.net>
   5 #
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the same terms as Perl itself.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See either the
  12 # GNU General Public License or the Artistic License for more details.
  13 #
  14 # Print version numbers for Perl modules
  15 #---------------------------------------------------------------------
  16
  17 use strict;
  18 use Getopt::Long 2.10;
  19
  20 my $VERSION = join('', 'r', (q$Rev: 2537 $ =~ /(\d+)/));
  21
  22 #---------------------------------------------------------------------
  23 my ($editModule, $pathOnly);
  24
  25 Getopt::Long::config(qw(bundling no_getopt_compat));
  26 GetOptions(
  27     'edit|e'    => \$editModule,
  28     'path-only|p'=>\$pathOnly,
  29     'x'         => sub { warn "-x is deprecated, use -e instead\n";
  30                          $editModule = 1 },
  31     'help'      => \&usage,
  32     'version'   => \&usage
  33 ) or usage();
  34
  35 usage() unless @ARGV;
  36
  37 sub usage {
  38     print "pmver $VERSION\n";
  39     exit if $_[0] and $_[0] eq 'version';
  40     print "\n" . <<'END HELP';
  41 Usage:  pmver [options] MODULE ...
  42   -e, --edit       Open MODULE.pm in your editor
  43   -p, --path-only  Display only the pathname (no version)
  44   -?, --help       Display this help message
  45       --version    Display version information
  46 END HELP
  47
  48     exit;
  49 } # end usage
  50
  51 #---------------------------------------------------------------------
  52 my $errorCount = 0;
  53
  54 foreach my $module (@ARGV) {
  55   $module =~ s!\s+\z!!g;      # Remove trailing space, just in case
  56   $module =~ s![-/\\ ]!::!g;  # Allow pathnames and distribution names
  57   $module =~ s!^dzp::!Dist::Zilla::Plugin::!i;
  58   $module =~ s!^dzpb::!Dist::Zilla::PluginBundle::!i;
  59
  60   eval "require $module;";
  61   if (my $error = $@) {
  62     $error =~ s/\s+at \(eval \d+\) line \d+\.$//;
  63     print "$module not found:\n$error\n";
  64     ++$errorCount;
  65   } else {
  66     my $file = $module;
  67     $file =~ s!::!/!g;
  68     my $fn = $INC{"$file.pm"};
  69
  70     if ($pathOnly) {
  71       printf("%s\n", $fn);
  72     } else {
  73       my $version = $module->VERSION;
  74       printf("%s %s is\n %s\n",
  75              $module, (defined $version ? $version : '<NO $VERSION>'),
  76              $fn);
  77     }
  78
  79     if ($editModule) {
  80       my $editor = ($ENV{EDITOR_NOWAIT} || $ENV{VISUAL} || $ENV{EDITOR} ||
  81                     die "Please set EDITOR_NOWAIT, VISUAL, or EDITOR\n");
  82       system qq'$editor "$fn"';
  83     }
  84   } # end else module found
  85 } # end foreach module to check
  86
  87 exit $errorCount;