c_cpp/lib/gnulib/m4/obstack-printf.m4

   1 # obstack-printf.m4 serial 4
   2 dnl Copyright (C) 2008-2015 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Eric Blake.
   8 dnl Test whether obstack_printf() exists.  For now, we assume that
   9 dnl obstack_vprintf behaves identically, so we only test for one.
  10
  11 AC_DEFUN([gl_FUNC_OBSTACK_PRINTF],
  12 [
  13   dnl Persuade glibc <stdio.h> to declare obstack_printf(), obstack_vprintf().
  14   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
  15
  16   AC_REQUIRE([gl_STDIO_H_DEFAULTS])
  17   AC_CHECK_FUNCS_ONCE([obstack_printf])
  18   if test $ac_cv_func_obstack_printf = no ; then
  19     gl_REPLACE_OBSTACK_PRINTF
  20   fi
  21
  22   gl_DECL_OBSTACK_PRINTF
  23 ])
  24
  25 AC_DEFUN([gl_REPLACE_OBSTACK_PRINTF],
  26 [
  27   AC_REQUIRE([gl_STDIO_H_DEFAULTS])
  28   if test $ac_cv_func_obstack_printf = yes; then
  29     REPLACE_OBSTACK_PRINTF=1
  30   fi
  31 ])
  32
  33 dnl Ensure obstack_printf() and obstack_vprintf() are declared
  34 dnl (whether or not they are being replaced).
  35 AC_DEFUN([gl_DECL_OBSTACK_PRINTF],
  36 [
  37   AC_CHECK_DECLS_ONCE([obstack_printf])
  38   if test $ac_cv_have_decl_obstack_printf = no; then
  39     HAVE_DECL_OBSTACK_PRINTF=0
  40   fi
  41 ])