CMakeLists.txt

   1 # Copyright 2016-2021 Google Inc.
   2 # SPDX-License-Identifier: Apache-2.0 OR MIT
   3 #
   4 # Licensed under the Apache License, Version 2.0 (the "License");
   5 # you may not use this file except in compliance with the License.
   6 # You may obtain a copy of the License at
   7 #
   8 # http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS,
  12 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  13 # See the License for the specific language governing permissions and
  14 # limitations under the License.
  15
  16 #
  17 # At your option, you may choose to accept this material under either:
  18 #  1. The Apache License, Version 2.0, found at <http://www.apache.org/licenses/LICENSE-2.0>, or
  19 #  2. The MIT License, found at <http://opensource.org/licenses/MIT>.
  20 #
  21
  22 cmake_minimum_required(VERSION 3.10)
  23 set(CMAKE_CXX_STANDARD 11)
  24 set(CMAKE_CXX_EXTENSIONS OFF)
  25
  26 # Avoid a warning if parent project sets VERSION in project().
  27 if (${CMAKE_VERSION} VERSION_GREATER "3.0.1")
  28         cmake_policy(SET CMP0048 NEW)
  29 endif()
  30
  31 # Avoid error on Android NDK 27+'s CMake files
  32 cmake_policy(SET CMP0057 NEW)
  33
  34 project(SPIRV-Cross LANGUAGES CXX C)
  35 enable_testing()
  36
  37 include(GNUInstallDirs)
  38
  39 option(SPIRV_CROSS_EXCEPTIONS_TO_ASSERTIONS "Instead of throwing exceptions assert" OFF)
  40 option(SPIRV_CROSS_SHARED "Build the C API as a single shared library." OFF)
  41 option(SPIRV_CROSS_STATIC "Build the C and C++ API as static libraries." ON)
  42 option(SPIRV_CROSS_CLI "Build the CLI binary. Requires SPIRV_CROSS_STATIC." ON)
  43 option(SPIRV_CROSS_ENABLE_TESTS "Enable SPIRV-Cross tests." ON)
  44
  45 option(SPIRV_CROSS_ENABLE_GLSL "Enable GLSL support." ON)
  46 option(SPIRV_CROSS_ENABLE_HLSL "Enable HLSL target support." ON)
  47 option(SPIRV_CROSS_ENABLE_MSL "Enable MSL target support." ON)
  48 option(SPIRV_CROSS_ENABLE_CPP "Enable C++ target support." ON)
  49 option(SPIRV_CROSS_ENABLE_REFLECT "Enable JSON reflection target support." ON)
  50 option(SPIRV_CROSS_ENABLE_C_API "Enable C API wrapper support in static library." ON)
  51 option(SPIRV_CROSS_ENABLE_UTIL "Enable util module support." ON)
  52
  53 option(SPIRV_CROSS_SANITIZE_ADDRESS "Sanitize address" OFF)
  54 option(SPIRV_CROSS_SANITIZE_MEMORY "Sanitize memory" OFF)
  55 option(SPIRV_CROSS_SANITIZE_THREADS "Sanitize threads" OFF)
  56 option(SPIRV_CROSS_SANITIZE_UNDEFINED "Sanitize undefined" OFF)
  57
  58 option(SPIRV_CROSS_NAMESPACE_OVERRIDE "" "Override the namespace used in the C++ API.")
  59 option(SPIRV_CROSS_FORCE_STL_TYPES "Force use of STL types instead of STL replacements in certain places. Might reduce performance." OFF)
  60
  61 option(SPIRV_CROSS_SKIP_INSTALL "Skips installation targets." OFF)
  62
  63 option(SPIRV_CROSS_WERROR "Fail build on warnings." OFF)
  64 option(SPIRV_CROSS_MISC_WARNINGS "Misc warnings useful for Travis runs." OFF)
  65
  66 option(SPIRV_CROSS_FORCE_PIC "Force position-independent code for all targets." OFF)
  67
  68 if(${CMAKE_GENERATOR} MATCHES "Makefile")
  69         if(${CMAKE_CURRENT_SOURCE_DIR} STREQUAL ${CMAKE_CURRENT_BINARY_DIR})
  70                 message(FATAL_ERROR "Build out of tree to avoid overwriting Makefile")
  71         endif()
  72 endif()
  73
  74 set(spirv-compiler-options "")
  75 set(spirv-compiler-defines "")
  76 set(spirv-cross-link-flags "")
  77
  78 message(STATUS "SPIRV-Cross: Finding Git version for SPIRV-Cross.")
  79 set(spirv-cross-build-version "unknown")
  80 find_package(Git)
  81 if (GIT_FOUND)
  82         execute_process(
  83                 COMMAND ${GIT_EXECUTABLE} describe --always --tags --dirty=+
  84                 WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  85                 OUTPUT_VARIABLE spirv-cross-build-version
  86                 ERROR_QUIET
  87                 OUTPUT_STRIP_TRAILING_WHITESPACE
  88                 )
  89         message(STATUS "SPIRV-Cross: Git hash: ${spirv-cross-build-version}")
  90 else()
  91         message(STATUS "SPIRV-Cross: Git not found, using unknown build version.")
  92 endif()
  93
  94 string(TIMESTAMP spirv-cross-timestamp)
  95 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/cmake/gitversion.in.h ${CMAKE_CURRENT_BINARY_DIR}/gitversion.h @ONLY)
  96
  97 if (SPIRV_CROSS_EXCEPTIONS_TO_ASSERTIONS)
  98         set(spirv-compiler-defines ${spirv-compiler-defines} SPIRV_CROSS_EXCEPTIONS_TO_ASSERTIONS)
  99         if (NOT MSVC)
 100                 set(spirv-compiler-options ${spirv-compiler-options} -fno-exceptions)
 101         endif()
 102 endif()
 103
 104 if (SPIRV_CROSS_FORCE_STL_TYPES)
 105         set(spirv-compiler-defines ${spirv-compiler-defines} SPIRV_CROSS_FORCE_STL_TYPES)
 106 endif()
 107
 108 if (WIN32)
 109         set(CMAKE_DEBUG_POSTFIX "d")
 110 endif()
 111
 112 if (CMAKE_COMPILER_IS_GNUCXX OR ((${CMAKE_CXX_COMPILER_ID} MATCHES "Clang") AND NOT MSVC))
 113         set(spirv-compiler-options ${spirv-compiler-options} -Wall -Wextra -Wshadow -Wno-deprecated-declarations)
 114         if (SPIRV_CROSS_MISC_WARNINGS)
 115                 if (${CMAKE_CXX_COMPILER_ID} MATCHES "Clang")
 116                         set(spirv-compiler-options ${spirv-compiler-options} -Wshorten-64-to-32)
 117                 endif()
 118         endif()
 119         if (SPIRV_CROSS_WERROR)
 120                 set(spirv-compiler-options ${spirv-compiler-options} -Werror)
 121         endif()
 122
 123         if (SPIRV_CROSS_EXCEPTIONS_TO_ASSERTIONS)
 124                 set(spirv-compiler-options ${spirv-compiler-options} -fno-exceptions)
 125         endif()
 126
 127         if (SPIRV_CROSS_SANITIZE_ADDRESS)
 128                 set(spirv-compiler-options ${spirv-compiler-options} -fsanitize=address)
 129                 set(spirv-cross-link-flags "${spirv-cross-link-flags} -fsanitize=address")
 130         endif()
 131
 132         if (SPIRV_CROSS_SANITIZE_UNDEFINED)
 133                 set(spirv-compiler-options ${spirv-compiler-options} -fsanitize=undefined)
 134                 set(spirv-cross-link-flags "${spirv-cross-link-flags} -fsanitize=undefined")
 135         endif()
 136
 137         if (SPIRV_CROSS_SANITIZE_MEMORY)
 138                 set(spirv-compiler-options ${spirv-compiler-options} -fsanitize=memory)
 139                 set(spirv-cross-link-flags "${spirv-cross-link-flags} -fsanitize=memory")
 140         endif()
 141
 142         if (SPIRV_CROSS_SANITIZE_THREADS)
 143                 set(spirv-compiler-options ${spirv-compiler-options} -fsanitize=thread)
 144                 set(spirv-cross-link-flags "${spirv-cross-link-flags} -fsanitize=thread")
 145         endif()
 146 elseif (MSVC)
 147         # AppVeyor spuriously fails in debug build on older MSVC without /bigobj.
 148         set(spirv-compiler-options ${spirv-compiler-options} /wd4267 /wd4996 $<$<CONFIG:DEBUG>:/bigobj>)
 149 endif()
 150
 151 macro(extract_headers out_abs file_list)
 152         set(${out_abs}) # absolute paths
 153         foreach(_a ${file_list})
 154                 # get_filename_component only returns the longest extension, so use a regex
 155                 string(REGEX REPLACE ".*\\.(h|hpp)" "\\1" ext ${_a})
 156
 157                 # For shared library, we are only interested in the C header.
 158                 if (SPIRV_CROSS_STATIC)
 159                         if(("${ext}" STREQUAL "h") OR ("${ext}" STREQUAL "hpp"))
 160                                 list(APPEND ${out_abs} "${_a}")
 161                         endif()
 162                 else()
 163                         if("${ext}" STREQUAL "h")
 164                                 list(APPEND ${out_abs} "${_a}")
 165                         endif()
 166                 endif()
 167         endforeach()
 168 endmacro()
 169
 170 macro(spirv_cross_add_library name config_name library_type)
 171         add_library(${name} ${library_type} ${ARGN})
 172         extract_headers(hdrs "${ARGN}")
 173         target_include_directories(${name} PUBLIC
 174                         $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>
 175                         $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}/spirv_cross>)
 176         set_target_properties(${name} PROPERTIES
 177                         PUBLIC_HEADERS "${hdrs}")
 178         if (SPIRV_CROSS_FORCE_PIC)
 179                 set_target_properties(${name} PROPERTIES POSITION_INDEPENDENT_CODE ON)
 180         endif()
 181         target_compile_options(${name} PRIVATE ${spirv-compiler-options})
 182         target_compile_definitions(${name} PRIVATE ${spirv-compiler-defines})
 183         if (SPIRV_CROSS_NAMESPACE_OVERRIDE)
 184                 if (${library_type} MATCHES "STATIC")
 185                         target_compile_definitions(${name} PUBLIC SPIRV_CROSS_NAMESPACE_OVERRIDE=${SPIRV_CROSS_NAMESPACE_OVERRIDE})
 186                 else()
 187                         target_compile_definitions(${name} PRIVATE SPIRV_CROSS_NAMESPACE_OVERRIDE=${SPIRV_CROSS_NAMESPACE_OVERRIDE})
 188                 endif()
 189         endif()
 190
 191         if (NOT SPIRV_CROSS_SKIP_INSTALL)
 192                 install(TARGETS ${name}
 193                         EXPORT ${config_name}Config
 194                         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 195                         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 196                         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 197                         PUBLIC_HEADER DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/spirv_cross)
 198                 install(FILES ${hdrs} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/spirv_cross)
 199                 install(EXPORT ${config_name}Config DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/${config_name}/cmake)
 200                 export(TARGETS ${name} FILE ${config_name}Config.cmake)
 201         endif()
 202 endmacro()
 203
 204 set(spirv-cross-core-sources
 205                 ${CMAKE_CURRENT_SOURCE_DIR}/GLSL.std.450.h
 206                 ${CMAKE_CURRENT_SOURCE_DIR}/spirv_common.hpp
 207                 ${CMAKE_CURRENT_SOURCE_DIR}/spirv_cross_containers.hpp
 208                 ${CMAKE_CURRENT_SOURCE_DIR}/spirv_cross_error_handling.hpp
 209                 ${CMAKE_CURRENT_SOURCE_DIR}/spirv.hpp
 210                 ${CMAKE_CURRENT_SOURCE_DIR}/spirv_cross.hpp
 211                 ${CMAKE_CURRENT_SOURCE_DIR}/spirv_cross.cpp
 212                 ${CMAKE_CURRENT_SOURCE_DIR}/spirv_parser.hpp
 213                 ${CMAKE_CURRENT_SOURCE_DIR}/spirv_parser.cpp
 214                 ${CMAKE_CURRENT_SOURCE_DIR}/spirv_cross_parsed_ir.hpp
 215                 ${CMAKE_CURRENT_SOURCE_DIR}/spirv_cross_parsed_ir.cpp
 216                 ${CMAKE_CURRENT_SOURCE_DIR}/spirv_cfg.hpp
 217                 ${CMAKE_CURRENT_SOURCE_DIR}/spirv_cfg.cpp)
 218
 219 set(spirv-cross-c-sources
 220                 spirv.h
 221                 ${CMAKE_CURRENT_SOURCE_DIR}/spirv_cross_c.cpp
 222                 ${CMAKE_CURRENT_SOURCE_DIR}/spirv_cross_c.h)
 223
 224 set(spirv-cross-glsl-sources
 225                 ${CMAKE_CURRENT_SOURCE_DIR}/spirv_glsl.cpp
 226                 ${CMAKE_CURRENT_SOURCE_DIR}/spirv_glsl.hpp)
 227
 228 set(spirv-cross-cpp-sources
 229                 ${CMAKE_CURRENT_SOURCE_DIR}/spirv_cpp.cpp
 230                 ${CMAKE_CURRENT_SOURCE_DIR}/spirv_cpp.hpp)
 231
 232 set(spirv-cross-msl-sources
 233                 ${CMAKE_CURRENT_SOURCE_DIR}/spirv_msl.cpp
 234                 ${CMAKE_CURRENT_SOURCE_DIR}/spirv_msl.hpp)
 235
 236 set(spirv-cross-hlsl-sources
 237                 ${CMAKE_CURRENT_SOURCE_DIR}/spirv_hlsl.cpp
 238                 ${CMAKE_CURRENT_SOURCE_DIR}/spirv_hlsl.hpp)
 239
 240 set(spirv-cross-reflect-sources
 241                 ${CMAKE_CURRENT_SOURCE_DIR}/spirv_reflect.cpp
 242                 ${CMAKE_CURRENT_SOURCE_DIR}/spirv_reflect.hpp)
 243
 244 set(spirv-cross-util-sources
 245                 ${CMAKE_CURRENT_SOURCE_DIR}/spirv_cross_util.cpp
 246                 ${CMAKE_CURRENT_SOURCE_DIR}/spirv_cross_util.hpp)
 247
 248 set(spirv-cross-abi-major 0)
 249 set(spirv-cross-abi-minor 64)
 250 set(spirv-cross-abi-patch 0)
 251 set(SPIRV_CROSS_VERSION ${spirv-cross-abi-major}.${spirv-cross-abi-minor}.${spirv-cross-abi-patch})
 252
 253 if (SPIRV_CROSS_STATIC)
 254         if (NOT SPIRV_CROSS_SKIP_INSTALL)
 255                 configure_file(
 256                         ${CMAKE_CURRENT_SOURCE_DIR}/pkg-config/spirv-cross-c.pc.in
 257                         ${CMAKE_CURRENT_BINARY_DIR}/spirv-cross-c.pc @ONLY)
 258                 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/spirv-cross-c.pc DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
 259         endif()
 260
 261         spirv_cross_add_library(spirv-cross-core spirv_cross_core STATIC
 262                         ${spirv-cross-core-sources})
 263
 264         if (SPIRV_CROSS_ENABLE_GLSL)
 265                 spirv_cross_add_library(spirv-cross-glsl spirv_cross_glsl STATIC
 266                                 ${spirv-cross-glsl-sources})
 267                 target_link_libraries(spirv-cross-glsl PRIVATE spirv-cross-core)
 268         endif()
 269
 270         if (SPIRV_CROSS_ENABLE_CPP)
 271                 spirv_cross_add_library(spirv-cross-cpp spirv_cross_cpp STATIC
 272                                 ${spirv-cross-cpp-sources})
 273
 274                 if (SPIRV_CROSS_ENABLE_GLSL)
 275                         target_link_libraries(spirv-cross-cpp PRIVATE spirv-cross-glsl)
 276                 else()
 277                         message(FATAL_ERROR "Must enable GLSL support to enable C++ support.")
 278                 endif()
 279         endif()
 280
 281         if (SPIRV_CROSS_ENABLE_REFLECT)
 282                 if (SPIRV_CROSS_ENABLE_GLSL)
 283                         spirv_cross_add_library(spirv-cross-reflect spirv_cross_reflect STATIC
 284                                         ${spirv-cross-reflect-sources})
 285                 else()
 286                         message(FATAL_ERROR "Must enable GLSL support to enable JSON reflection support.")
 287                 endif()
 288         endif()
 289
 290         if (SPIRV_CROSS_ENABLE_MSL)
 291                 spirv_cross_add_library(spirv-cross-msl spirv_cross_msl STATIC
 292                                 ${spirv-cross-msl-sources})
 293                 if (SPIRV_CROSS_ENABLE_GLSL)
 294                         target_link_libraries(spirv-cross-msl PRIVATE spirv-cross-glsl)
 295                 else()
 296                         message(FATAL_ERROR "Must enable GLSL support to enable MSL support.")
 297                 endif()
 298         endif()
 299
 300         if (SPIRV_CROSS_ENABLE_HLSL)
 301                 spirv_cross_add_library(spirv-cross-hlsl spirv_cross_hlsl STATIC
 302                                 ${spirv-cross-hlsl-sources})
 303                 if (SPIRV_CROSS_ENABLE_GLSL)
 304                         target_link_libraries(spirv-cross-hlsl PRIVATE spirv-cross-glsl)
 305                 else()
 306                         message(FATAL_ERROR "Must enable GLSL support to enable HLSL support.")
 307                 endif()
 308         endif()
 309
 310         if (SPIRV_CROSS_ENABLE_UTIL)
 311                 spirv_cross_add_library(spirv-cross-util spirv_cross_util STATIC
 312                                 ${spirv-cross-util-sources})
 313                 target_link_libraries(spirv-cross-util PRIVATE spirv-cross-core)
 314         endif()
 315
 316         if (SPIRV_CROSS_ENABLE_C_API)
 317                 spirv_cross_add_library(spirv-cross-c spirv_cross_c STATIC
 318                                 ${spirv-cross-c-sources})
 319                 target_include_directories(spirv-cross-c PRIVATE ${CMAKE_CURRENT_BINARY_DIR})
 320                 target_compile_definitions(spirv-cross-c PRIVATE HAVE_SPIRV_CROSS_GIT_VERSION)
 321
 322                 if (SPIRV_CROSS_ENABLE_GLSL)
 323                         target_link_libraries(spirv-cross-c PRIVATE spirv-cross-glsl)
 324                         target_compile_definitions(spirv-cross-c PRIVATE SPIRV_CROSS_C_API_GLSL=1)
 325                 endif()
 326
 327                 if (SPIRV_CROSS_ENABLE_HLSL)
 328                         target_link_libraries(spirv-cross-c PRIVATE spirv-cross-hlsl)
 329                         target_compile_definitions(spirv-cross-c PRIVATE SPIRV_CROSS_C_API_HLSL=1)
 330                 endif()
 331
 332                 if (SPIRV_CROSS_ENABLE_MSL)
 333                         target_link_libraries(spirv-cross-c PRIVATE spirv-cross-msl)
 334                         target_compile_definitions(spirv-cross-c PRIVATE SPIRV_CROSS_C_API_MSL=1)
 335                 endif()
 336
 337                 if (SPIRV_CROSS_ENABLE_CPP)
 338                         target_link_libraries(spirv-cross-c PRIVATE spirv-cross-cpp)
 339                         target_compile_definitions(spirv-cross-c PRIVATE SPIRV_CROSS_C_API_CPP=1)
 340                 endif()
 341
 342                 if (SPIRV_CROSS_ENABLE_REFLECT)
 343                         target_link_libraries(spirv-cross-c PRIVATE spirv-cross-reflect)
 344                         target_compile_definitions(spirv-cross-c PRIVATE SPIRV_CROSS_C_API_REFLECT=1)
 345                 endif()
 346         endif()
 347 endif()
 348
 349 if (SPIRV_CROSS_SHARED)
 350         if (NOT SPIRV_CROSS_SKIP_INSTALL)
 351                 configure_file(
 352                         ${CMAKE_CURRENT_SOURCE_DIR}/pkg-config/spirv-cross-c-shared.pc.in
 353                         ${CMAKE_CURRENT_BINARY_DIR}/spirv-cross-c-shared.pc @ONLY)
 354                 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/spirv-cross-c-shared.pc DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
 355         endif()
 356
 357         spirv_cross_add_library(spirv-cross-c-shared spirv_cross_c_shared SHARED
 358                         ${spirv-cross-core-sources}
 359                         ${spirv-cross-c-sources})
 360
 361         target_include_directories(spirv-cross-c-shared PRIVATE ${CMAKE_CURRENT_BINARY_DIR})
 362         target_compile_definitions(spirv-cross-c-shared PRIVATE HAVE_SPIRV_CROSS_GIT_VERSION)
 363
 364         if (SPIRV_CROSS_ENABLE_GLSL)
 365                 target_sources(spirv-cross-c-shared PRIVATE ${spirv-cross-glsl-sources})
 366                 target_compile_definitions(spirv-cross-c-shared PRIVATE SPIRV_CROSS_C_API_GLSL=1)
 367         endif()
 368
 369         if (SPIRV_CROSS_ENABLE_HLSL)
 370                 if (SPIRV_CROSS_ENABLE_GLSL)
 371                         target_sources(spirv-cross-c-shared PRIVATE ${spirv-cross-hlsl-sources})
 372                 else()
 373                         message(FATAL_ERROR "Must enable GLSL support to enable HLSL support.")
 374                 endif()
 375                 target_compile_definitions(spirv-cross-c-shared PRIVATE SPIRV_CROSS_C_API_HLSL=1)
 376         endif()
 377
 378         if (SPIRV_CROSS_ENABLE_MSL)
 379                 if (SPIRV_CROSS_ENABLE_GLSL)
 380                         target_sources(spirv-cross-c-shared PRIVATE ${spirv-cross-msl-sources})
 381                 else()
 382                         message(FATAL_ERROR "Must enable GLSL support to enable MSL support.")
 383                 endif()
 384                 target_compile_definitions(spirv-cross-c-shared PRIVATE SPIRV_CROSS_C_API_MSL=1)
 385         endif()
 386
 387         if (SPIRV_CROSS_ENABLE_CPP)
 388                 if (SPIRV_CROSS_ENABLE_GLSL)
 389                         target_sources(spirv-cross-c-shared PRIVATE ${spirv-cross-cpp-sources})
 390                 else()
 391                         message(FATAL_ERROR "Must enable GLSL support to enable C++ support.")
 392                 endif()
 393                 target_compile_definitions(spirv-cross-c-shared PRIVATE SPIRV_CROSS_C_API_CPP=1)
 394         endif()
 395
 396         if (SPIRV_CROSS_ENABLE_REFLECT)
 397                 if (SPIRV_CROSS_ENABLE_GLSL)
 398                         target_sources(spirv-cross-c-shared PRIVATE ${spirv-cross-reflect-sources})
 399                 else()
 400                         message(FATAL_ERROR "Must enable GLSL support to enable JSON reflection support.")
 401                 endif()
 402                 target_compile_definitions(spirv-cross-c-shared PRIVATE SPIRV_CROSS_C_API_REFLECT=1)
 403         endif()
 404
 405         if (CMAKE_COMPILER_IS_GNUCXX OR (${CMAKE_CXX_COMPILER_ID} MATCHES "Clang"))
 406                 # Only export the C API.
 407                 target_compile_options(spirv-cross-c-shared PRIVATE -fvisibility=hidden)
 408                 if (NOT APPLE)
 409                         set_target_properties(spirv-cross-c-shared PROPERTIES LINK_FLAGS "${spirv-cross-link-flags}")
 410                 endif()
 411         endif()
 412
 413         target_compile_definitions(spirv-cross-c-shared PRIVATE SPVC_EXPORT_SYMBOLS)
 414
 415         set_target_properties(spirv-cross-c-shared PROPERTIES
 416                         VERSION ${SPIRV_CROSS_VERSION}
 417                         SOVERSION ${spirv-cross-abi-major})
 418 endif()
 419
 420 if (SPIRV_CROSS_CLI)
 421         if (NOT SPIRV_CROSS_ENABLE_GLSL)
 422                 message(FATAL_ERROR "Must enable GLSL if building CLI.")
 423         endif()
 424
 425         if (NOT SPIRV_CROSS_ENABLE_HLSL)
 426                 message(FATAL_ERROR "Must enable HLSL if building CLI.")
 427         endif()
 428
 429         if (NOT SPIRV_CROSS_ENABLE_MSL)
 430                 message(FATAL_ERROR "Must enable MSL if building CLI.")
 431         endif()
 432
 433         if (NOT SPIRV_CROSS_ENABLE_CPP)
 434                 message(FATAL_ERROR "Must enable C++ if building CLI.")
 435         endif()
 436
 437         if (NOT SPIRV_CROSS_ENABLE_REFLECT)
 438                 message(FATAL_ERROR "Must enable reflection if building CLI.")
 439         endif()
 440
 441         if (NOT SPIRV_CROSS_ENABLE_UTIL)
 442                 message(FATAL_ERROR "Must enable utils if building CLI.")
 443         endif()
 444
 445         if (NOT SPIRV_CROSS_STATIC)
 446                 message(FATAL_ERROR "Must build static libraries if building CLI.")
 447         endif()
 448         add_executable(spirv-cross main.cpp)
 449         target_compile_options(spirv-cross PRIVATE ${spirv-compiler-options})
 450         target_include_directories(spirv-cross PRIVATE ${CMAKE_CURRENT_BINARY_DIR})
 451         target_compile_definitions(spirv-cross PRIVATE ${spirv-compiler-defines} HAVE_SPIRV_CROSS_GIT_VERSION)
 452         set_target_properties(spirv-cross PROPERTIES LINK_FLAGS "${spirv-cross-link-flags}")
 453         if (NOT SPIRV_CROSS_SKIP_INSTALL)
 454                 install(TARGETS spirv-cross DESTINATION ${CMAKE_INSTALL_BINDIR})
 455         endif()
 456         target_link_libraries(spirv-cross PRIVATE
 457                         spirv-cross-glsl
 458                         spirv-cross-hlsl
 459                         spirv-cross-cpp
 460                         spirv-cross-reflect
 461                         spirv-cross-msl
 462                         spirv-cross-util
 463                         spirv-cross-core)
 464
 465         if (SPIRV_CROSS_ENABLE_TESTS)
 466                 # Set up tests, using only the simplest modes of the test_shaders
 467                 # script.  You have to invoke the script manually to:
 468                 #  - Update the reference files
 469                 #  - Get cycle counts from malisc
 470                 #  - Keep failing outputs
 471                 if (${CMAKE_VERSION} VERSION_GREATER "3.12")
 472                         find_package(Python3)
 473                         if (${PYTHON3_FOUND})
 474                                 set(PYTHONINTERP_FOUND ON)
 475                                 set(PYTHON_VERSION_MAJOR 3)
 476                                 set(PYTHON_EXECUTABLE ${Python3_EXECUTABLE})
 477                         else()
 478                                 set(PYTHONINTERP_FOUND OFF)
 479                         endif()
 480                 else()
 481                         find_package(PythonInterp)
 482                 endif()
 483
 484                 find_program(spirv-cross-glslang NAMES glslangValidator
 485                                 PATHS ${CMAKE_CURRENT_SOURCE_DIR}/external/glslang-build/output/bin
 486                                 NO_DEFAULT_PATH)
 487                 find_program(spirv-cross-spirv-as NAMES spirv-as
 488                                 PATHS ${CMAKE_CURRENT_SOURCE_DIR}/external/spirv-tools-build/output/bin
 489                                 NO_DEFAULT_PATH)
 490                 find_program(spirv-cross-spirv-val NAMES spirv-val
 491                                 PATHS ${CMAKE_CURRENT_SOURCE_DIR}/external/spirv-tools-build/output/bin
 492                                 NO_DEFAULT_PATH)
 493                 find_program(spirv-cross-spirv-opt NAMES spirv-opt
 494                                 PATHS ${CMAKE_CURRENT_SOURCE_DIR}/external/spirv-tools-build/output/bin
 495                                 NO_DEFAULT_PATH)
 496
 497                 if ((${spirv-cross-glslang} MATCHES "NOTFOUND") OR (${spirv-cross-spirv-as} MATCHES "NOTFOUND") OR (${spirv-cross-spirv-val} MATCHES "NOTFOUND") OR (${spirv-cross-spirv-opt} MATCHES "NOTFOUND"))
 498                         set(SPIRV_CROSS_ENABLE_TESTS OFF)
 499                         message("SPIRV-Cross:  Testing will be disabled for SPIRV-Cross. Could not find glslang or SPIRV-Tools build under external/. To enable testing, run ./checkout_glslang_spirv_tools.sh and ./build_glslang_spirv_tools.sh first.")
 500                 else()
 501                         set(SPIRV_CROSS_ENABLE_TESTS ON)
 502                         message("SPIRV-Cross: Found glslang and SPIRV-Tools. Enabling test suite.")
 503                         message("SPIRV-Cross: Found glslangValidator in: ${spirv-cross-glslang}.")
 504                         message("SPIRV-Cross: Found spirv-as in: ${spirv-cross-spirv-as}.")
 505                         message("SPIRV-Cross: Found spirv-val in: ${spirv-cross-spirv-val}.")
 506                         message("SPIRV-Cross: Found spirv-opt in: ${spirv-cross-spirv-opt}.")
 507                 endif()
 508
 509                 set(spirv-cross-externals
 510                                 --glslang "${spirv-cross-glslang}"
 511                                 --spirv-as "${spirv-cross-spirv-as}"
 512                                 --spirv-opt "${spirv-cross-spirv-opt}"
 513                                 --spirv-val "${spirv-cross-spirv-val}")
 514
 515                 if (${PYTHONINTERP_FOUND} AND SPIRV_CROSS_ENABLE_TESTS)
 516                         if (${PYTHON_VERSION_MAJOR} GREATER 2)
 517                                 add_executable(spirv-cross-c-api-test tests-other/c_api_test.c)
 518                                 target_link_libraries(spirv-cross-c-api-test spirv-cross-c)
 519                                 set_target_properties(spirv-cross-c-api-test PROPERTIES LINK_FLAGS "${spirv-cross-link-flags}")
 520
 521                                 add_executable(spirv-cross-small-vector-test tests-other/small_vector.cpp)
 522                                 target_link_libraries(spirv-cross-small-vector-test spirv-cross-core)
 523                                 set_target_properties(spirv-cross-small-vector-test PROPERTIES LINK_FLAGS "${spirv-cross-link-flags}")
 524
 525                                 add_executable(spirv-cross-msl-constexpr-test tests-other/msl_constexpr_test.cpp)
 526                                 target_link_libraries(spirv-cross-msl-constexpr-test spirv-cross-c)
 527                                 set_target_properties(spirv-cross-msl-constexpr-test PROPERTIES LINK_FLAGS "${spirv-cross-link-flags}")
 528
 529                                 add_executable(spirv-cross-msl-resource-binding-test tests-other/msl_resource_bindings.cpp)
 530                                 target_link_libraries(spirv-cross-msl-resource-binding-test spirv-cross-c)
 531                                 set_target_properties(spirv-cross-msl-resource-binding-test PROPERTIES LINK_FLAGS "${spirv-cross-link-flags}")
 532
 533                                 add_executable(spirv-cross-hlsl-resource-binding-test tests-other/hlsl_resource_bindings.cpp)
 534                                 target_link_libraries(spirv-cross-hlsl-resource-binding-test spirv-cross-c)
 535                                 set_target_properties(spirv-cross-hlsl-resource-binding-test PROPERTIES LINK_FLAGS "${spirv-cross-link-flags}")
 536
 537                                 add_executable(spirv-cross-msl-ycbcr-conversion-test tests-other/msl_ycbcr_conversion_test.cpp)
 538                                 target_link_libraries(spirv-cross-msl-ycbcr-conversion-test spirv-cross-c)
 539                                 set_target_properties(spirv-cross-msl-ycbcr-conversion-test PROPERTIES LINK_FLAGS "${spirv-cross-link-flags}")
 540
 541                                 add_executable(spirv-cross-typed-id-test tests-other/typed_id_test.cpp)
 542                                 target_link_libraries(spirv-cross-typed-id-test spirv-cross-core)
 543                                 set_target_properties(spirv-cross-typed-id-test PROPERTIES LINK_FLAGS "${spirv-cross-link-flags}")
 544
 545                                 if (CMAKE_COMPILER_IS_GNUCXX OR (${CMAKE_CXX_COMPILER_ID} MATCHES "Clang"))
 546                                         target_compile_options(spirv-cross-c-api-test PRIVATE -std=c89 -Wall -Wextra)
 547                                 endif()
 548                                 add_test(NAME spirv-cross-c-api-test
 549                                                 COMMAND $<TARGET_FILE:spirv-cross-c-api-test> ${CMAKE_CURRENT_SOURCE_DIR}/tests-other/c_api_test.spv
 550                                                 ${spirv-cross-abi-major}
 551                                                 ${spirv-cross-abi-minor}
 552                                                 ${spirv-cross-abi-patch})
 553                                 add_test(NAME spirv-cross-small-vector-test
 554                                                 COMMAND $<TARGET_FILE:spirv-cross-small-vector-test>)
 555                                 add_test(NAME spirv-cross-msl-constexpr-test
 556                                                 COMMAND $<TARGET_FILE:spirv-cross-msl-constexpr-test> ${CMAKE_CURRENT_SOURCE_DIR}/tests-other/msl_constexpr_test.spv)
 557                                 add_test(NAME spirv-cross-msl-resource-binding-test
 558                                                 COMMAND $<TARGET_FILE:spirv-cross-msl-resource-binding-test> ${CMAKE_CURRENT_SOURCE_DIR}/tests-other/msl_resource_binding.spv)
 559                                 add_test(NAME spirv-cross-hlsl-resource-binding-test
 560                                                 COMMAND $<TARGET_FILE:spirv-cross-hlsl-resource-binding-test> ${CMAKE_CURRENT_SOURCE_DIR}/tests-other/hlsl_resource_binding.spv)
 561                                 add_test(NAME spirv-cross-msl-ycbcr-conversion-test
 562                                                 COMMAND $<TARGET_FILE:spirv-cross-msl-ycbcr-conversion-test> ${CMAKE_CURRENT_SOURCE_DIR}/tests-other/msl_ycbcr_conversion_test.spv)
 563                                 add_test(NAME spirv-cross-msl-ycbcr-conversion-test-2
 564                                                 COMMAND $<TARGET_FILE:spirv-cross-msl-ycbcr-conversion-test> ${CMAKE_CURRENT_SOURCE_DIR}/tests-other/msl_ycbcr_conversion_test_2.spv)
 565                                 add_test(NAME spirv-cross-typed-id-test
 566                                                 COMMAND $<TARGET_FILE:spirv-cross-typed-id-test>)
 567                                 add_test(NAME spirv-cross-test
 568                                                 COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/test_shaders.py --parallel
 569                                                 ${spirv-cross-externals}
 570                                                 ${CMAKE_CURRENT_SOURCE_DIR}/shaders
 571                                                 WORKING_DIRECTORY $<TARGET_FILE_DIR:spirv-cross>)
 572                                 add_test(NAME spirv-cross-test-no-opt
 573                                                 COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/test_shaders.py --parallel
 574                                                 ${spirv-cross-externals}
 575                                                 ${CMAKE_CURRENT_SOURCE_DIR}/shaders-no-opt
 576                                                 WORKING_DIRECTORY $<TARGET_FILE_DIR:spirv-cross>)
 577                                 add_test(NAME spirv-cross-test-metal
 578                                                 COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/test_shaders.py --metal --parallel
 579                                                 ${spirv-cross-externals}
 580                                                 ${CMAKE_CURRENT_SOURCE_DIR}/shaders-msl
 581                                                 WORKING_DIRECTORY $<TARGET_FILE_DIR:spirv-cross>)
 582                                 add_test(NAME spirv-cross-test-metal-no-opt
 583                                                 COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/test_shaders.py --metal --parallel
 584                                                 ${spirv-cross-externals}
 585                                                 ${CMAKE_CURRENT_SOURCE_DIR}/shaders-msl-no-opt
 586                                                 WORKING_DIRECTORY $<TARGET_FILE_DIR:spirv-cross>)
 587                                 add_test(NAME spirv-cross-test-hlsl
 588                                                 COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/test_shaders.py --hlsl --parallel
 589                                                 ${spirv-cross-externals}
 590                                                 ${CMAKE_CURRENT_SOURCE_DIR}/shaders-hlsl
 591                                                 WORKING_DIRECTORY $<TARGET_FILE_DIR:spirv-cross>)
 592                                 add_test(NAME spirv-cross-test-hlsl-no-opt
 593                                                 COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/test_shaders.py --hlsl --parallel
 594                                                 ${spirv-cross-externals}
 595                                                 ${CMAKE_CURRENT_SOURCE_DIR}/shaders-hlsl-no-opt
 596                                                 WORKING_DIRECTORY $<TARGET_FILE_DIR:spirv-cross>)
 597                                 add_test(NAME spirv-cross-test-opt
 598                                                 COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/test_shaders.py --opt --parallel
 599                                                 ${spirv-cross-externals}
 600                                                 ${CMAKE_CURRENT_SOURCE_DIR}/shaders
 601                                                 WORKING_DIRECTORY $<TARGET_FILE_DIR:spirv-cross>)
 602                                 add_test(NAME spirv-cross-test-metal-opt
 603                                                 COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/test_shaders.py --metal --opt --parallel
 604                                                 ${spirv-cross-externals}
 605                                                 ${CMAKE_CURRENT_SOURCE_DIR}/shaders-msl
 606                                                 WORKING_DIRECTORY $<TARGET_FILE_DIR:spirv-cross>)
 607                                 add_test(NAME spirv-cross-test-hlsl-opt
 608                                                 COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/test_shaders.py --hlsl --opt --parallel
 609                                                 ${spirv-cross-externals}
 610                                                 ${CMAKE_CURRENT_SOURCE_DIR}/shaders-hlsl
 611                                                 WORKING_DIRECTORY $<TARGET_FILE_DIR:spirv-cross>)
 612                                 add_test(NAME spirv-cross-test-reflection
 613                                                 COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/test_shaders.py --reflect --parallel
 614                                                 ${spirv-cross-externals}
 615                                                 ${CMAKE_CURRENT_SOURCE_DIR}/shaders-reflection
 616                                                 WORKING_DIRECTORY $<TARGET_FILE_DIR:spirv-cross>)
 617                                 add_test(NAME spirv-cross-test-ue4
 618                                                 COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/test_shaders.py --msl --parallel
 619                                                 ${spirv-cross-externals}
 620                                                 ${CMAKE_CURRENT_SOURCE_DIR}/shaders-ue4
 621                                                 WORKING_DIRECTORY $<TARGET_FILE_DIR:spirv-cross>)
 622                                 add_test(NAME spirv-cross-test-ue4-opt
 623                                                 COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/test_shaders.py --msl --opt --parallel
 624                                                 ${spirv-cross-externals}
 625                                                 ${CMAKE_CURRENT_SOURCE_DIR}/shaders-ue4
 626                                                 WORKING_DIRECTORY $<TARGET_FILE_DIR:spirv-cross>)
 627                                 add_test(NAME spirv-cross-test-ue4-no-opt
 628                                                 COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/test_shaders.py --msl --parallel
 629                                                 ${spirv-cross-externals}
 630                                                 ${CMAKE_CURRENT_SOURCE_DIR}/shaders-ue4-no-opt
 631                                                 WORKING_DIRECTORY $<TARGET_FILE_DIR:spirv-cross>)
 632                         endif()
 633                 elseif(NOT ${PYTHONINTERP_FOUND})
 634                         message(WARNING "SPIRV-Cross: Testing disabled. Could not find python3. If you have python3 installed try running "
 635                                         "cmake with -DPYTHON_EXECUTABLE:FILEPATH=/path/to/python3 to help it find the executable")
 636                 endif()
 637         endif()
 638 endif()