CMakeLists.txt

   1 # ~~~
   2 # Copyright 2018-2023 The Khronos Group Inc.
   3 # Copyright 2018-2023 Valve Corporation
   4 # Copyright 2018-2023 LunarG, Inc.
   5 #
   6 # SPDX-License-Identifier: Apache-2.0
   7 # ~~~
   8 cmake_minimum_required(VERSION 3.22.1)
   9
  10 # NOTE: Parsing the version like this is suboptimal but neccessary due to our release process:
  11 # https://github.com/KhronosGroup/Vulkan-Headers/pull/346
  12 #
  13 # As shown a more robust approach would be just to add basic test code to check the project version.
  14 function(vlk_get_header_version)
  15     set(vulkan_core_header_file "${CMAKE_CURRENT_SOURCE_DIR}/include/vulkan/vulkan_core.h")
  16     if (NOT EXISTS ${vulkan_core_header_file})
  17         message(FATAL_ERROR "Couldn't find vulkan_core.h!")
  18     endif()
  19
  20     file(READ ${vulkan_core_header_file} ver)
  21
  22     if (ver MATCHES "#define[ ]+VK_HEADER_VERSION_COMPLETE[ ]+VK_MAKE_API_VERSION\\([ ]*[0-9]+,[ ]*([0-9]+),[ ]*([0-9]+),[ ]*VK_HEADER_VERSION[ ]*\\)")
  23         set(MAJOR_VERSION "${CMAKE_MATCH_1}")
  24         set(MINOR_VERSION "${CMAKE_MATCH_2}")
  25     else()
  26         message(FATAL_ERROR "Couldn't get major/minor version")
  27     endif()
  28
  29     if (ver MATCHES "#define[ ]+VK_HEADER_VERSION[ ]+([0-9]+)")
  30         set(PATCH_VERSION "${CMAKE_MATCH_1}")
  31     else()
  32         message(FATAL_ERROR "Couldn't get the patch version")
  33     endif()
  34
  35     set(VK_VERSION_STRING "${MAJOR_VERSION}.${MINOR_VERSION}.${PATCH_VERSION}" PARENT_SCOPE)
  36 endfunction()
  37 vlk_get_header_version()
  38
  39 project(VULKAN_HEADERS LANGUAGES C CXX VERSION ${VK_VERSION_STRING})
  40
  41 add_library(Vulkan-Headers INTERFACE)
  42 add_library(Vulkan::Headers ALIAS Vulkan-Headers)
  43 target_include_directories(Vulkan-Headers INTERFACE $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>)
  44
  45 if ((CMAKE_CXX_COMPILER_ID STREQUAL "MSVC" AND (MSVC_VERSION GREATER_EQUAL "1941")) OR
  46     # clang-cl doesn't currently support modules
  47     (CMAKE_CXX_COMPILER_ID STREQUAL "Clang"
  48         AND CMAKE_CXX_COMPILER_VERSION VERSION_GREATER_EQUAL "16.0"
  49         AND (NOT CMAKE_C_COMPILER_FRONTEND_VARIANT MATCHES "MSVC")
  50         AND (NOT CMAKE_CXX_COMPILER_CLANG_SCAN_DEPS STREQUAL CMAKE_CXX_COMPILER_CLANG_SCAN_DEPS-NOTFOUND)) OR
  51     (CMAKE_CXX_COMPILER_ID STREQUAL "GNU" AND CMAKE_CXX_COMPILER_VERSION VERSION_GREATER_EQUAL "14.0"))
  52     set(COMPILER_SUPPORTS_CXX_MODULES TRUE)
  53 endif()
  54
  55 option(VULKAN_HEADERS_ENABLE_MODULE "Enables building of the Vulkan C++ module" OFF)
  56
  57 if (VULKAN_HEADERS_ENABLE_MODULE AND (NOT COMPILER_SUPPORTS_CXX_MODULES OR CMAKE_VERSION VERSION_LESS "3.28"))
  58     message(WARNING "Vulkan C++ module support is requested but was disabled due to lacking support on this platform")
  59 endif()
  60
  61 if (CMAKE_VERSION VERSION_GREATER_EQUAL "3.28" AND VULKAN_HEADERS_ENABLE_MODULE AND COMPILER_SUPPORTS_CXX_MODULES)
  62     add_library(Vulkan-Module)
  63     add_library(Vulkan::VulkanHppModule ALIAS Vulkan-Module)
  64     target_sources(Vulkan-Module
  65         PUBLIC
  66             FILE_SET module
  67                 TYPE CXX_MODULES
  68                 BASE_DIRS "${CMAKE_CURRENT_SOURCE_DIR}/include"
  69                 FILES "${CMAKE_CURRENT_SOURCE_DIR}/include/vulkan/vulkan.cppm"
  70     )
  71     target_compile_features(Vulkan-Module PUBLIC cxx_std_20)
  72     target_link_libraries(Vulkan-Module PUBLIC Vulkan-Headers)
  73 endif ()
  74
  75 option(VULKAN_HEADERS_ENABLE_TESTS "Test Vulkan-Headers" ${PROJECT_IS_TOP_LEVEL})
  76 option(VULKAN_HEADERS_ENABLE_INSTALL "Install Vulkan-Headers" ${PROJECT_IS_TOP_LEVEL})
  77
  78 if (VULKAN_HEADERS_ENABLE_TESTS)
  79     enable_testing() # This is only effective in the top level CMakeLists.txt file.
  80     add_subdirectory(tests)
  81 endif()
  82
  83 if (VULKAN_HEADERS_ENABLE_INSTALL)
  84     include(GNUInstallDirs)
  85     include(CMakePackageConfigHelpers)
  86
  87     install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/include/vk_video" DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
  88     install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/include/vulkan" DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
  89     # Preserve source permissions https://github.com/KhronosGroup/Vulkan-Headers/issues/336
  90     install(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/registry" DESTINATION "${CMAKE_INSTALL_DATADIR}/vulkan" USE_SOURCE_PERMISSIONS)
  91
  92     set_target_properties(Vulkan-Headers PROPERTIES EXPORT_NAME "Headers")
  93     install(TARGETS Vulkan-Headers EXPORT VulkanHeadersConfig INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
  94
  95     install(EXPORT VulkanHeadersConfig NAMESPACE "Vulkan::" DESTINATION "share/cmake/VulkanHeaders")
  96
  97     set(version_config "${CMAKE_CURRENT_BINARY_DIR}/generated/VulkanHeadersConfigVersion.cmake")
  98     write_basic_package_version_file("${version_config}" COMPATIBILITY SameMajorVersion ARCH_INDEPENDENT)
  99     install(FILES "${version_config}" DESTINATION "share/cmake/VulkanHeaders")
 100 endif()