unoidl/source/sourceprovider-scanner.l

   1 /* -*- Mode: C++; tab-width: 4; indent-tabs-mode: nil; c-basic-offset: 4 -*- */
   2 /*
   3  * This file is part of the LibreOffice project.
   4  *
   5  * This Source Code Form is subject to the terms of the Mozilla Public
   6  * License, v. 2.0. If a copy of the MPL was not distributed with this
   7  * file, You can obtain one at http://mozilla.org/MPL/2.0/.
   8  */
   9
  10 %option bison-bridge
  11 %option bison-locations
  12 %option extra-type="unoidl::detail::SourceProviderScannerData *"
  13 %option never-interactive
  14 %option nounistd
  15 %option noyywrap
  16 %option reentrant
  17 %option warn
  18 %option yylineno
  19
  20 %top {
  21
  22 #include "sal/config.h"
  23
  24 #include <algorithm>
  25 #include <cassert>
  26 #include <cstddef>
  27 #include <cstring>
  28
  29 }
  30
  31 %{
  32
  33 #include <rtl/math.h>
  34 #include <rtl/string.hxx>
  35 #include <rtl/ustring.hxx>
  36 #include <rtl/textenc.h>
  37 #include <sal/types.h>
  38 #include <unoidl/unoidl.hxx>
  39
  40 #include "sourceprovider-parser-requires.hxx"
  41 #include <sourceprovider-parser.hxx>
  42 #include "sourceprovider-scanner.hxx"
  43
  44 namespace unoidl { namespace detail {
  45
  46 static std::size_t sourceProviderScannerInput(
  47     SourceProviderScannerData * data, char * buffer, std::size_t size)
  48 {
  49     assert(data != nullptr);
  50     if (data->sourcePosition == data->sourceEnd) {
  51         return YY_NULL;
  52     }
  53     assert(data->sourcePosition < data->sourceEnd);
  54     size = std::min<std::size_t>(size, data->sourceEnd - data->sourcePosition);
  55     std::memcpy(buffer, data->sourcePosition, size);
  56     data->sourcePosition += size;
  57     return size;
  58 }
  59
  60 } }
  61
  62 #define YY_INPUT(buf, result, max_size) ((result) = \
  63     ::unoidl::detail::sourceProviderScannerInput(yyextra, (buf), (max_size)))
  64
  65 namespace {
  66
  67 int nonZeroIntegerLiteral(
  68     char const * text, std::size_t length, sal_Int16 radix, sal_uInt64 * value,
  69     unoidl::detail::SourceProviderScannerData * data)
  70 {
  71     assert(text != nullptr);
  72     assert(length != 0);
  73     assert(value != nullptr);
  74     assert(data != nullptr);
  75     std::size_t n = length;
  76     switch (text[length - 1]) {
  77     case 'L':
  78     case 'U':
  79     case 'l':
  80     case 'u':
  81         --n;
  82         break;
  83     default:
  84         break;
  85     }
  86     *value = OString(text, n).toUInt64(radix);
  87     if (*value == 0) {
  88         data->errorMessage = "out-of-range integer literal "
  89             + OUString(text, length, RTL_TEXTENCODING_ASCII_US);
  90         return TOK_ERROR;
  91     }
  92     return TOK_INTEGER;
  93 }
  94
  95 }
  96
  97 %}
  98
  99 %x comment1 comment2 doc docdepr
 100
 101 DIGIT [0-9]
 102 UPPER [A-Z]
 103 LOWER [a-z]
 104 ALPHA {UPPER}|{LOWER}
 105 ALNUM {DIGIT}|{ALPHA}
 106
 107 %%
 108
 109 [ \t\r]
 110 \n *yylloc = yylineno;
 111
 112 "//" BEGIN comment1;
 113 "#" BEGIN comment1; //TODO: only at start of line
 114 <comment1>.
 115 <comment1>\n *yylloc = yylineno; BEGIN INITIAL;
 116
 117 "/*" BEGIN comment2;
 118 "/**" BEGIN doc;
 119 "/***" BEGIN comment2;
 120
 121 <comment2,doc>"*/" BEGIN INITIAL;
 122 <docdepr>"*/" BEGIN INITIAL; return TOK_DEPRECATED;
 123
 124 <comment2,docdepr>.
 125 <comment2,doc,docdepr>\n *yylloc = yylineno;
 126 <comment2,doc,docdepr><<EOF>> {
 127     yyextra->errorMessage = "unterminated comment";
 128     return TOK_ERROR;
 129 }
 130
 131 <doc>[ \t\r]
 132 <doc>"@deprecated" BEGIN docdepr;
 133 <doc>"*"
 134 <doc>[^ \t\r\n*]+
 135
 136 [%&()*+,\-/:;<=>[\]^{|}~] return yytext[0];
 137
 138 "..." return TOK_ELLIPSIS;
 139 "::" return TOK_COLONS;
 140 "<<" return TOK_LEFTSHIFT;
 141 ">>" return TOK_RIGHTSHIFT;
 142
 143 "FALSE" return TOK_FALSE;
 144 "False" return TOK_FALSE;
 145 "TRUE" return TOK_TRUE;
 146 "True" return TOK_TRUE;
 147 "any" return TOK_ANY;
 148 "attribute" return TOK_ATTRIBUTE;
 149 "boolean" return TOK_BOOLEAN;
 150 "bound" return TOK_BOUND;
 151 "byte" return TOK_BYTE;
 152 "char" return TOK_CHAR;
 153 "const" return TOK_CONST;
 154 "constants" return TOK_CONSTANTS;
 155 "constrained" return TOK_CONSTRAINED;
 156 "double" return TOK_DOUBLE;
 157 "enum" return TOK_ENUM;
 158 "exception" return TOK_EXCEPTION;
 159 "float" return TOK_FLOAT;
 160 "get" return TOK_GET;
 161 "hyper" return TOK_HYPER;
 162 "in" return TOK_IN;
 163 "inout" return TOK_INOUT;
 164 "interface" return TOK_INTERFACE;
 165 "long" return TOK_LONG;
 166 "maybeambiguous" return TOK_MAYBEAMBIGUOUS;
 167 "maybedefault" return TOK_MAYBEDEFAULT;
 168 "maybevoid" return TOK_MAYBEVOID;
 169 "module" return TOK_MODULE;
 170 "optional" return TOK_OPTIONAL;
 171 "out" return TOK_OUT;
 172 "property" return TOK_PROPERTY;
 173 "published" return TOK_PUBLISHED;
 174 "raises" return TOK_RAISES;
 175 "readonly" return TOK_READONLY;
 176 "removable" return TOK_REMOVABLE;
 177 "sequence" return TOK_SEQUENCE;
 178 "service" return TOK_SERVICE;
 179 "set" return TOK_SET;
 180 "short" return TOK_SHORT;
 181 "singleton" return TOK_SINGLETON;
 182 "string" return TOK_STRING;
 183 "struct" return TOK_STRUCT;
 184 "transient" return TOK_TRANSIENT;
 185 "type" return TOK_TYPE;
 186 "typedef" return TOK_TYPEDEF;
 187 "unsigned" return TOK_UNSIGNED;
 188 "void" return TOK_VOID;
 189
 190 {UPPER}("_"?{ALNUM})*|{LOWER}{ALNUM}* {
 191     yylval->sval = new OString(yytext);
 192     return TOK_IDENTIFIER;
 193 }
 194
 195 ({ALPHA}|"_")({ALNUM}|"_")* {
 196 #if 1 //TODO
 197     yylval->sval=new OString(yytext);return TOK_IDENTIFIER;
 198 #else
 199     yyextra->errorMessage = "illegal identifier "
 200         + OUString(yytext, yyleng, RTL_TEXTENCODING_ASCII_US);
 201     return TOK_ERROR;
 202 #endif
 203 }
 204
 205 0+[LUlu]? |
 206 0[Xx]0+[LUlu]? {
 207     yylval->ival = 0;
 208     return TOK_INTEGER;
 209 }
 210
 211 0[0-7]+[LUlu]? {
 212     return nonZeroIntegerLiteral(yytext, yyleng, 8, &yylval->ival, yyextra);
 213 }
 214
 215 [1-9]{DIGIT}*[LUlu]? {
 216     return nonZeroIntegerLiteral(yytext, yyleng, 10, &yylval->ival, yyextra);
 217 }
 218
 219 0[Xx][0-9A-Fa-f]+[LUlu]? {
 220     return nonZeroIntegerLiteral(
 221         yytext + 2, yyleng - 2, 16, &yylval->ival, yyextra);
 222 }
 223
 224 {DIGIT}+[Ee][+\-]?{DIGIT}+[Ff]? |
 225 {DIGIT}*"."{DIGIT}+([Ee][+\-]?{DIGIT}+)?[Ff]? {
 226     rtl_math_ConversionStatus s;
 227     yylval->fval = rtl_math_stringToDouble(
 228         yytext, yytext + yyleng, '.', 0, &s, nullptr);
 229     if (s == rtl_math_ConversionStatus_OutOfRange) {
 230         yyextra->errorMessage = "out-of-range floating-point literal "
 231             + OUString(yytext, yyleng, RTL_TEXTENCODING_ASCII_US);
 232         return TOK_ERROR;
 233     }
 234     return TOK_FLOATING;
 235 }
 236
 237 {DIGIT}({ALNUM}|"_")* {
 238     yyextra->errorMessage = "illegal numeric literal "
 239         + OUString(yytext, yyleng, RTL_TEXTENCODING_ASCII_US);
 240     return TOK_ERROR;
 241 }
 242
 243 . {
 244     char c = yytext[0];
 245     yyextra->errorMessage = c >= ' ' && c <= '~'
 246         ? OUString("invalid character \"" + OUStringChar(c) + "\"")
 247         : OUString(
 248             "invalid byte x"
 249             + OUString::number(static_cast<unsigned char>(c), 16).toAsciiUpperCase());
 250     return TOK_ERROR;
 251 }
 252
 253 %%
 254
 255 /* vim:set shiftwidth=4 softtabstop=4 expandtab: */