sfx2/source/appl/shutdowniconaqua.mm

   1 /* -*- Mode: C++; tab-width: 4; indent-tabs-mode: nil; c-basic-offset: 4 -*- */
   2 /*
   3  * This file is part of the LibreOffice project.
   4  *
   5  * This Source Code Form is subject to the terms of the Mozilla Public
   6  * License, v. 2.0. If a copy of the MPL was not distributed with this
   7  * file, You can obtain one at http://mozilla.org/MPL/2.0/.
   8  *
   9  * This file incorporates work covered by the following license notice:
  10  *
  11  *   Licensed to the Apache Software Foundation (ASF) under one or more
  12  *   contributor license agreements. See the NOTICE file distributed
  13  *   with this work for additional information regarding copyright
  14  *   ownership. The ASF licenses this file to you under the Apache
  15  *   License, Version 2.0 (the "License"); you may not use this file
  16  *   except in compliance with the License. You may obtain a copy of
  17  *   the License at http://www.apache.org/licenses/LICENSE-2.0 .
  18  */
  19
  20
  21 #include <unotools/moduleoptions.hxx>
  22 #include <unotools/dynamicmenuoptions.hxx>
  23 #include <unotools/historyoptions.hxx>
  24 #include <rtl/ustring.hxx>
  25 #include <tools/urlobj.hxx>
  26 #include <osl/file.h>
  27 #include <comphelper/sequenceashashmap.hxx>
  28 #include <osl/mutex.hxx>
  29 #include <sfx2/app.hxx>
  30 #include <sal/macros.h>
  31 #include "app.hrc"
  32 #define USE_APP_SHORTCUTS
  33 #include "shutdownicon.hxx"
  34
  35 #include <com/sun/star/util/XStringWidth.hpp>
  36
  37 #include <cppuhelper/implbase1.hxx>
  38
  39 #include <set>
  40 #include <vector>
  41
  42 #include "premac.h"
  43 #include <objc/objc-runtime.h>
  44 #include <Cocoa/Cocoa.h>
  45 #include "postmac.h"
  46
  47 using namespace ::osl;
  48 using namespace ::com::sun::star::uno;
  49 using namespace ::com::sun::star::task;
  50 using namespace ::com::sun::star::lang;
  51 using namespace ::com::sun::star::beans;
  52 using namespace ::com::sun::star::util;
  53
  54 #define MI_OPEN                    1
  55 #define MI_WRITER                  2
  56 #define MI_CALC                    3
  57 #define MI_IMPRESS                 4
  58 #define MI_DRAW                    5
  59 #define MI_BASE                    6
  60 #define MI_MATH                    7
  61 #define MI_TEMPLATE                8
  62 #define MI_STARTMODULE             9
  63
  64 @interface QSMenuExecute : NSObject
  65 {
  66 }
  67 -(void)executeMenuItem: (NSMenuItem*)pItem;
  68 -(void)dockIconClicked: (NSObject*)pSender;
  69 @end
  70
  71 @implementation QSMenuExecute
  72 -(void)executeMenuItem: (NSMenuItem*)pItem
  73 {
  74     switch( [pItem tag] )
  75     {
  76     case MI_OPEN:
  77         ShutdownIcon::FileOpen();
  78         break;
  79     case MI_WRITER:
  80         ShutdownIcon::OpenURL( OUString(  WRITER_URL ), OUString( "_default" ) );
  81         break;
  82     case MI_CALC:
  83         ShutdownIcon::OpenURL( OUString( CALC_URL ), OUString( "_default" ) );
  84         break;
  85     case MI_IMPRESS:
  86         ShutdownIcon::OpenURL( OUString( IMPRESS_URL ), OUString( "_default" ) );
  87         break;
  88     case MI_DRAW:
  89         ShutdownIcon::OpenURL( OUString( DRAW_URL ), OUString( "_default" ) );
  90         break;
  91     case MI_BASE:
  92         ShutdownIcon::OpenURL( OUString( BASE_URL ), OUString( "_default" ) );
  93         break;
  94     case MI_MATH:
  95         ShutdownIcon::OpenURL( OUString( MATH_URL ), OUString( "_default" ) );
  96         break;
  97     case MI_TEMPLATE:
  98         ShutdownIcon::FromTemplate();
  99         break;
 100     case MI_STARTMODULE:
 101         ShutdownIcon::OpenURL( OUString( STARTMODULE_URL ), OUString( "_default" ) );
 102         break;
 103     default:
 104         break;
 105     }
 106 }
 107
 108 -(void)dockIconClicked: (NSObject*)pSender
 109 {
 110     (void)pSender;
 111     // start start module
 112     ShutdownIcon::OpenURL( OUString( STARTMODULE_URL ), OUString( "_default" ) );
 113 }
 114
 115 @end
 116
 117 bool ShutdownIcon::IsQuickstarterInstalled()
 118 {
 119     return true;
 120 }
 121
 122 static NSMenuItem* pDefMenu = nil, *pDockSubMenu = nil;
 123 static QSMenuExecute* pExecute = nil;
 124
 125 static std::set< OUString > aShortcuts;
 126
 127 static NSString* getAutoreleasedString( const rtl::OUString& rStr )
 128 {
 129     return [[[NSString alloc] initWithCharacters: rStr.getStr() length: rStr.getLength()] autorelease];
 130 }
 131
 132 struct RecentMenuEntry
 133 {
 134     rtl::OUString aURL;
 135     rtl::OUString aFilter;
 136     rtl::OUString aTitle;
 137     rtl::OUString aPassword;
 138 };
 139
 140 class RecentFilesStringLength : public ::cppu::WeakImplHelper1< ::com::sun::star::util::XStringWidth >
 141 {
 142     public:
 143         RecentFilesStringLength() {}
 144         virtual ~RecentFilesStringLength() {}
 145
 146         // XStringWidth
 147         sal_Int32 SAL_CALL queryStringWidth( const ::rtl::OUString& aString )
 148             throw (::com::sun::star::uno::RuntimeException) SAL_OVERRIDE
 149         {
 150             return aString.getLength();
 151         }
 152 };
 153
 154 @interface RecentMenuDelegate : NSObject
 155 {
 156     std::vector< RecentMenuEntry >* m_pRecentFilesItems;
 157 }
 158 -(id)init;
 159 -(void)dealloc;
 160 -(void)menuNeedsUpdate:(NSMenu *)menu;
 161 -(void)executeRecentEntry: (NSMenuItem*)item;
 162 @end
 163
 164 @implementation RecentMenuDelegate
 165 -(id)init
 166 {
 167     if( (self = [super init]) )
 168     {
 169         m_pRecentFilesItems = new std::vector< RecentMenuEntry >();
 170     }
 171     return self;
 172 }
 173
 174 -(void)dealloc
 175 {
 176     delete m_pRecentFilesItems;
 177     [super dealloc];
 178 }
 179
 180 -(void)menuNeedsUpdate:(NSMenu *)menu
 181 {
 182     // clear menu
 183     int nItems = [menu numberOfItems];
 184     while( nItems -- )
 185         [menu removeItemAtIndex: 0];
 186
 187     // update recent item list
 188     Sequence< Sequence< PropertyValue > > aHistoryList( SvtHistoryOptions().GetList( ePICKLIST ) );
 189
 190     int nPickListMenuItems = ( aHistoryList.getLength() > 99 ) ? 99 : aHistoryList.getLength();
 191
 192     m_pRecentFilesItems->clear();
 193     if( ( nPickListMenuItems > 0 ) )
 194     {
 195         for ( int i = 0; i < nPickListMenuItems; i++ )
 196         {
 197             Sequence< PropertyValue >& rPickListEntry = aHistoryList[i];
 198             RecentMenuEntry aRecentFile;
 199
 200             for ( int j = 0; j < rPickListEntry.getLength(); j++ )
 201             {
 202                 Any a = rPickListEntry[j].Value;
 203
 204                 if ( rPickListEntry[j].Name == HISTORY_PROPERTYNAME_URL )
 205                     a >>= aRecentFile.aURL;
 206                 else if ( rPickListEntry[j].Name == HISTORY_PROPERTYNAME_FILTER )
 207                     a >>= aRecentFile.aFilter;
 208                 else if ( rPickListEntry[j].Name == HISTORY_PROPERTYNAME_TITLE )
 209                     a >>= aRecentFile.aTitle;
 210                 else if ( rPickListEntry[j].Name == HISTORY_PROPERTYNAME_PASSWORD )
 211                     a >>= aRecentFile.aPassword;
 212             }
 213
 214             m_pRecentFilesItems->push_back( aRecentFile );
 215         }
 216     }
 217
 218     // insert new recent items
 219     for ( sal_uInt32 i = 0; i < m_pRecentFilesItems->size(); i++ )
 220     {
 221         rtl::OUString   aMenuTitle;
 222         INetURLObject   aURL( (*m_pRecentFilesItems)[i].aURL );
 223
 224         if ( aURL.GetProtocol() == INetProtocol::File )
 225         {
 226             // Do handle file URL differently => convert it to a system
 227             // path and abbreviate it with a special function:
 228             ::rtl::OUString aSystemPath( aURL.getFSysPath( INetURLObject::FSYS_DETECT ) );
 229             ::rtl::OUString aCompactedSystemPath;
 230
 231             oslFileError nError = osl_abbreviateSystemPath( aSystemPath.pData, &aCompactedSystemPath.pData, 46, NULL );
 232             if ( !nError )
 233                 aMenuTitle = aCompactedSystemPath;
 234             else
 235                 aMenuTitle = aSystemPath;
 236         }
 237         else
 238         {
 239             // Use INetURLObject to abbreviate all other URLs
 240             Reference< XStringWidth > xStringLength( new RecentFilesStringLength() );
 241             aMenuTitle = aURL.getAbbreviated( xStringLength, 46, INetURLObject::DECODE_UNAMBIGUOUS );
 242         }
 243
 244         NSMenuItem* pNewItem = [[NSMenuItem alloc] initWithTitle: getAutoreleasedString( aMenuTitle )
 245                                                    action: @selector(executeRecentEntry:)
 246                                                    keyEquivalent: @""];
 247         [pNewItem setTag: i];
 248         [pNewItem setTarget: self];
 249         [pNewItem setEnabled: YES];
 250         [menu addItem: pNewItem];
 251         [pNewItem autorelease];
 252     }
 253 }
 254
 255 -(void)executeRecentEntry: (NSMenuItem*)item
 256 {
 257     sal_Int32 nIndex = [item tag];
 258     if( ( nIndex >= 0 ) && ( nIndex < static_cast<sal_Int32>( m_pRecentFilesItems->size() ) ) )
 259     {
 260         const RecentMenuEntry& rRecentFile = (*m_pRecentFilesItems)[ nIndex ];
 261         int NUM_OF_PICKLIST_ARGS = 3;
 262         Sequence< PropertyValue > aArgsList( NUM_OF_PICKLIST_ARGS );
 263
 264         aArgsList[0].Name = "Referer";
 265         aArgsList[0].Value = makeAny( OUString( "private:user" ) );
 266
 267         // documents in the picklist will never be opened as templates
 268         aArgsList[1].Name = "AsTemplate";
 269         aArgsList[1].Value = makeAny( false );
 270
 271         ::rtl::OUString  aFilter( rRecentFile.aFilter );
 272         sal_Int32 nPos = aFilter.indexOf( '|' );
 273         if ( nPos >= 0 )
 274         {
 275             rtl::OUString aFilterOptions;
 276
 277             if ( nPos < ( aFilter.getLength() - 1 ) )
 278                 aFilterOptions = aFilter.copy( nPos+1 );
 279
 280             aArgsList[2].Name = "FilterOptions";
 281             aArgsList[2].Value = makeAny( aFilterOptions );
 282
 283             aFilter = aFilter.copy( 0, nPos-1 );
 284             aArgsList.realloc( ++NUM_OF_PICKLIST_ARGS );
 285         }
 286
 287         aArgsList[NUM_OF_PICKLIST_ARGS-1].Name = "FilterName";
 288         aArgsList[NUM_OF_PICKLIST_ARGS-1].Value = makeAny( aFilter );
 289
 290         ShutdownIcon::OpenURL( rRecentFile.aURL, OUString( "_default" ), aArgsList );
 291     }
 292 }
 293 @end
 294
 295 static RecentMenuDelegate* pRecentDelegate = nil;
 296
 297 static rtl::OUString getShortCut( const rtl::OUString& i_rTitle )
 298 {
 299     // create shortcut
 300     rtl::OUString aKeyEquiv;
 301     for( sal_Int32 nIndex = 0; nIndex < i_rTitle.getLength(); nIndex++ )
 302     {
 303         rtl::OUString aShortcut( i_rTitle.copy( nIndex, 1 ).toAsciiLowerCase() );
 304         if( aShortcuts.find( aShortcut ) == aShortcuts.end() )
 305         {
 306             aShortcuts.insert( aShortcut );
 307             aKeyEquiv = aShortcut;
 308             break;
 309         }
 310     }
 311
 312     return aKeyEquiv;
 313 }
 314
 315 static void appendMenuItem( NSMenu* i_pMenu, NSMenu* i_pDockMenu, const rtl::OUString& i_rTitle, int i_nTag, const rtl::OUString& i_rKeyEquiv )
 316 {
 317     if( ! i_rTitle.getLength() )
 318         return;
 319
 320     NSMenuItem* pItem = [[NSMenuItem alloc] initWithTitle: getAutoreleasedString( i_rTitle )
 321                                             action: @selector(executeMenuItem:)
 322                                             keyEquivalent: (i_rKeyEquiv.getLength() ? getAutoreleasedString( i_rKeyEquiv ) : @"")
 323                         ];
 324     [pItem setTag: i_nTag];
 325     [pItem setTarget: pExecute];
 326     [pItem setEnabled: YES];
 327     [i_pMenu addItem: pItem];
 328
 329     if( i_pDockMenu )
 330     {
 331         // create a similar entry in the dock menu
 332         pItem = [[NSMenuItem alloc] initWithTitle: getAutoreleasedString( i_rTitle )
 333                                     action: @selector(executeMenuItem:)
 334                                     keyEquivalent: @""
 335                             ];
 336         [pItem setTag: i_nTag];
 337         [pItem setTarget: pExecute];
 338         [pItem setEnabled: YES];
 339         [i_pDockMenu addItem: pItem];
 340     }
 341 }
 342
 343 static void appendRecentMenu( NSMenu* i_pMenu, NSMenu* i_pDockMenu, const OUString& i_rTitle )
 344 {
 345     if( ! pRecentDelegate )
 346         pRecentDelegate = [[RecentMenuDelegate alloc] init];
 347
 348     NSMenuItem* pItem = [i_pMenu addItemWithTitle: getAutoreleasedString( i_rTitle )
 349                                                    action: @selector(executeMenuItem:)
 350                                                    keyEquivalent: @""
 351                         ];
 352     [pItem setEnabled: YES];
 353     NSMenu* pRecentMenu = [[NSMenu alloc] initWithTitle: getAutoreleasedString( i_rTitle ) ];
 354
 355     // When compiling against 10.6 SDK, we get the warning:
 356     // class 'RecentMenuDelegate' does not implement the 'NSMenuDelegate' protocol
 357
 358     // No idea if that is a bogus warning, or if the way this is
 359     // implemented just is so weird that the compiler gets
 360     // confused. Anyway, to avoid warnings, instead of this:
 361     // [pRecentMenu setDelegate: pRecentDelegate];
 362     // do this:
 363     objc_msgSend(pRecentMenu, @selector(setDelegate:), pRecentDelegate);
 364
 365     [pRecentMenu setAutoenablesItems: NO];
 366     [pItem setSubmenu: pRecentMenu];
 367
 368     if( i_pDockMenu )
 369     {
 370         // create a similar entry in the dock menu
 371         pItem = [i_pDockMenu addItemWithTitle: getAutoreleasedString( i_rTitle )
 372                              action: @selector(executeMenuItem:)
 373                              keyEquivalent: @""
 374                         ];
 375         [pItem setEnabled: YES];
 376         pRecentMenu = [[NSMenu alloc] initWithTitle: getAutoreleasedString( i_rTitle ) ];
 377
 378         // See above
 379         // [pRecentMenu setDelegate: pRecentDelegate];
 380         objc_msgSend(pRecentMenu, @selector(setDelegate:), pRecentDelegate);
 381
 382         [pRecentMenu setAutoenablesItems: NO];
 383         [pItem setSubmenu: pRecentMenu];
 384     }
 385 }
 386
 387
 388 extern "C"
 389 {
 390
 391 void aqua_init_systray()
 392 {
 393     SolarMutexGuard aGuard;
 394
 395     ShutdownIcon *pShutdownIcon = ShutdownIcon::getInstance();
 396     if( ! pShutdownIcon )
 397         return;
 398
 399     // disable shutdown
 400     pShutdownIcon->SetVeto( true );
 401     ShutdownIcon::addTerminateListener();
 402
 403     if( ! pDefMenu )
 404     {
 405         if( [NSApp respondsToSelector: @selector(addFallbackMenuItem:)] )
 406         {
 407             aShortcuts.clear();
 408
 409             pExecute = [[QSMenuExecute alloc] init];
 410             pDefMenu = [[NSMenuItem alloc] initWithTitle: getAutoreleasedString( pShutdownIcon->GetResString( STR_QUICKSTART_FILE ) ) action: NULL keyEquivalent: @""];
 411             pDockSubMenu = [[NSMenuItem alloc] initWithTitle: getAutoreleasedString( pShutdownIcon->GetResString( STR_QUICKSTART_FILE ) ) action: NULL keyEquivalent: @""];
 412             NSMenu* pMenu = [[NSMenu alloc] initWithTitle: getAutoreleasedString( pShutdownIcon->GetResString( STR_QUICKSTART_FILE ) )];
 413             [pMenu setAutoenablesItems: NO];
 414             NSMenu* pDockMenu = [[NSMenu alloc] initWithTitle: getAutoreleasedString( pShutdownIcon->GetResString( STR_QUICKSTART_FILE ) )];
 415             [pDockMenu setAutoenablesItems: NO];
 416
 417             // collect the URLs of the entries in the File/New menu
 418             SvtModuleOptions    aModuleOptions;
 419             std::set< rtl::OUString > aFileNewAppsAvailable;
 420             SvtDynamicMenuOptions aOpt;
 421             Sequence < Sequence < PropertyValue > > aNewMenu = aOpt.GetMenu( E_NEWMENU );
 422             const rtl::OUString sURLKey( "URL" );
 423
 424             const Sequence< PropertyValue >* pNewMenu = aNewMenu.getConstArray();
 425             const Sequence< PropertyValue >* pNewMenuEnd = aNewMenu.getConstArray() + aNewMenu.getLength();
 426             for ( ; pNewMenu != pNewMenuEnd; ++pNewMenu )
 427             {
 428                 comphelper::SequenceAsHashMap aEntryItems( *pNewMenu );
 429                 rtl::OUString sURL( aEntryItems.getUnpackedValueOrDefault( sURLKey, rtl::OUString() ) );
 430                 if ( sURL.getLength() )
 431                     aFileNewAppsAvailable.insert( sURL );
 432             }
 433
 434             // describe the menu entries for launching the applications
 435             struct MenuEntryDescriptor
 436             {
 437                 SvtModuleOptions::EModule   eModuleIdentifier;
 438                 int                         nMenuTag;
 439                 const char*                 pAsciiURLDescription;
 440             }   aMenuItems[] =
 441             {
 442                 { SvtModuleOptions::EModule::WRITER,    MI_WRITER,  WRITER_URL },
 443                 { SvtModuleOptions::EModule::CALC,      MI_CALC,    CALC_URL },
 444                 { SvtModuleOptions::EModule::IMPRESS,   MI_IMPRESS, IMPRESS_WIZARD_URL },
 445                 { SvtModuleOptions::EModule::DRAW,      MI_DRAW,    DRAW_URL },
 446                 { SvtModuleOptions::EModule::DATABASE,  MI_BASE,    BASE_URL },
 447                 { SvtModuleOptions::EModule::MATH,      MI_MATH,    MATH_URL }
 448             };
 449
 450             // insert entry for startcenter
 451             if( aModuleOptions.IsModuleInstalled( SvtModuleOptions::EModule::STARTMODULE ) )
 452             {
 453                 appendMenuItem( pMenu, nil, pShutdownIcon->GetResString( STR_QUICKSTART_STARTCENTER ), MI_STARTMODULE, OUString( "n" ) );
 454                 if( [NSApp respondsToSelector: @selector(setDockIconClickHandler:)] )
 455                     [NSApp performSelector:@selector(setDockIconClickHandler:) withObject: pExecute];
 456                 else
 457                     OSL_FAIL( "setDockIconClickHandler selector failed on NSApp\n" );
 458
 459             }
 460
 461             // insert the menu entries for launching the applications
 462             for ( size_t i = 0; i < SAL_N_ELEMENTS( aMenuItems ); ++i )
 463             {
 464                 if ( !aModuleOptions.IsModuleInstalled( aMenuItems[i].eModuleIdentifier ) )
 465                     // the complete application is not even installed
 466                     continue;
 467
 468                 rtl::OUString sURL( ::rtl::OUString::createFromAscii( aMenuItems[i].pAsciiURLDescription ) );
 469
 470                 if ( aFileNewAppsAvailable.find( sURL ) == aFileNewAppsAvailable.end() )
 471                     // the application is installed, but the entry has been configured to *not* appear in the File/New
 472                     // menu => also let not appear it in the quickstarter
 473                     continue;
 474
 475                 rtl::OUString aKeyEquiv( getShortCut( ShutdownIcon::GetUrlDescription( sURL ) ) );
 476
 477                 appendMenuItem( pMenu, pDockMenu, ShutdownIcon::GetUrlDescription( sURL ), aMenuItems[i].nMenuTag, aKeyEquiv );
 478             }
 479
 480             // insert the remaining menu entries
 481
 482             // add recent menu
 483             appendRecentMenu( pMenu, pDockMenu, pShutdownIcon->GetResString( STR_QUICKSTART_RECENTDOC ) );
 484
 485             rtl::OUString aTitle( pShutdownIcon->GetResString( STR_QUICKSTART_FROMTEMPLATE ) );
 486             rtl::OUString aKeyEquiv( getShortCut( aTitle ) );
 487             appendMenuItem( pMenu, pDockMenu, aTitle, MI_TEMPLATE, aKeyEquiv );
 488             aTitle = pShutdownIcon->GetResString( STR_QUICKSTART_FILEOPEN );
 489             aKeyEquiv = getShortCut( aTitle );
 490             appendMenuItem( pMenu, pDockMenu, aTitle, MI_OPEN, aKeyEquiv );
 491
 492             [pDefMenu setSubmenu: pMenu];
 493             [NSApp performSelector:@selector(addFallbackMenuItem:) withObject: pDefMenu];
 494
 495             if( [NSApp respondsToSelector: @selector(addDockMenuItem:)] )
 496             {
 497                 [pDockSubMenu setSubmenu: pDockMenu];
 498                 // insert a separator to the dock menu
 499                 [NSApp performSelector:@selector(addDockMenuItem:) withObject: [NSMenuItem separatorItem]];
 500                 // and now add the submenu
 501                 [NSApp performSelector:@selector(addDockMenuItem:) withObject: pDockSubMenu];
 502             }
 503             else
 504                 OSL_FAIL( "addDockMenuItem selector failed on NSApp\n" );
 505         }
 506         else
 507             OSL_FAIL( "addFallbackMenuItem selector failed on NSApp\n" );
 508     }
 509 }
 510
 511 void SAL_DLLPUBLIC_EXPORT aqua_shutdown_systray()
 512 {
 513 }
 514
 515 }
 516
 517 /* vim:set shiftwidth=4 softtabstop=4 expandtab: */