solenv/bin/modules/installer/download.pm

   1 #
   2 # This file is part of the LibreOffice project.
   3 #
   4 # This Source Code Form is subject to the terms of the Mozilla Public
   5 # License, v. 2.0. If a copy of the MPL was not distributed with this
   6 # file, You can obtain one at http://mozilla.org/MPL/2.0/.
   7 #
   8 # This file incorporates work covered by the following license notice:
   9 #
  10 #   Licensed to the Apache Software Foundation (ASF) under one or more
  11 #   contributor license agreements. See the NOTICE file distributed
  12 #   with this work for additional information regarding copyright
  13 #   ownership. The ASF licenses this file to you under the Apache
  14 #   License, Version 2.0 (the "License"); you may not use this file
  15 #   except in compliance with the License. You may obtain a copy of
  16 #   the License at http://www.apache.org/licenses/LICENSE-2.0 .
  17 #
  18
  19 package installer::download;
  20
  21 use strict;
  22 use warnings;
  23
  24 use File::Spec;
  25 use installer::exiter;
  26 use installer::files;
  27 use installer::globals;
  28 use installer::logger;
  29 use installer::pathanalyzer;
  30 use installer::remover;
  31 use installer::systemactions;
  32
  33 BEGIN { # This is needed so that cygwin's perl evaluates ACLs
  34     # (needed for correctly evaluating the -x test.)
  35     if( $^O =~ /cygwin/i ) {
  36         require filetest; import filetest "access";
  37     }
  38 }
  39
  40 ##################################################################
  41 # Including the lowercase product name into the script template
  42 ##################################################################
  43
  44 sub put_productname_into_script
  45 {
  46     my ($scriptfile, $variableshashref) = @_;
  47
  48     my $productname = $variableshashref->{'PRODUCTNAME'};
  49     $productname = lc($productname);
  50     $productname =~ s/\.//g;    # openoffice.org -> openofficeorg
  51     $productname =~ s/\s*//g;
  52
  53     my $infoline = "Adding productname $productname into download shell script\n";
  54     push( @installer::globals::logfileinfo, $infoline);
  55
  56     for ( my $i = 0; $i <= $#{$scriptfile}; $i++ )
  57     {
  58         ${$scriptfile}[$i] =~ s/PRODUCTNAMEPLACEHOLDER/$productname/;
  59     }
  60 }
  61
  62 #########################################################
  63 # Including the linenumber into the script template
  64 #########################################################
  65
  66 sub put_linenumber_into_script
  67 {
  68     my ( $scriptfile ) = @_;
  69
  70     my $linenumber =  $#{$scriptfile} + 2;
  71
  72     my $infoline = "Adding linenumber $linenumber into download shell script\n";
  73     push( @installer::globals::logfileinfo, $infoline);
  74
  75     for ( my $i = 0; $i <= $#{$scriptfile}; $i++ )
  76     {
  77         ${$scriptfile}[$i] =~ s/LINENUMBERPLACEHOLDER/$linenumber/;
  78     }
  79 }
  80
  81 #########################################################
  82 # Determining the name of the new scriptfile
  83 #########################################################
  84
  85 sub determine_scriptfile_name
  86 {
  87     my ( $filename ) = @_;
  88
  89     $installer::globals::downloadfileextension = ".sh";
  90     $filename = $filename . $installer::globals::downloadfileextension;
  91     $installer::globals::downloadfilename = $filename;
  92
  93     my $infoline = "Setting download shell script file name to $filename\n";
  94     push( @installer::globals::logfileinfo, $infoline);
  95
  96     return $filename;
  97 }
  98
  99 #########################################################
 100 # Saving the script file in the installation directory
 101 #########################################################
 102
 103 sub save_script_file
 104 {
 105     my ($directory, $newscriptfilename, $scriptfile) = @_;
 106
 107     $newscriptfilename = $directory . $installer::globals::separator . $newscriptfilename;
 108     installer::files::save_file($newscriptfilename, $scriptfile);
 109
 110     my $infoline = "Saving script file $newscriptfilename\n";
 111     push( @installer::globals::logfileinfo, $infoline);
 112
 113     if ( ! $installer::globals::iswindowsbuild )
 114     {
 115         chmod 0775, $newscriptfilename;
 116     }
 117
 118     return $newscriptfilename;
 119 }
 120
 121 #########################################################
 122 # Including checksum and size into script file
 123 #########################################################
 124
 125 sub put_checksum_and_size_into_script
 126 {
 127     my ($scriptfile, $sumout) = @_;
 128
 129     my $checksum = "";
 130     my $size = "";
 131
 132     if  ( $sumout =~ /^\s*(\d+)\s+(\d+)\s*$/ )
 133     {
 134         $checksum = $1;
 135         $size = $2;
 136     }
 137     else
 138     {
 139         installer::exiter::exit_program("ERROR: Incorrect return value from /usr/bin/sum: $sumout", "put_checksum_and_size_into_script");
 140     }
 141
 142     my $infoline = "Adding checksum $checksum and size $size into download shell script\n";
 143     push( @installer::globals::logfileinfo, $infoline);
 144
 145     for ( my $i = 0; $i <= $#{$scriptfile}; $i++ )
 146     {
 147         ${$scriptfile}[$i] =~ s/CHECKSUMPLACEHOLDER/$checksum/;
 148         ${$scriptfile}[$i] =~ s/DISCSPACEPLACEHOLDER/$size/;
 149     }
 150
 151 }
 152
 153 #########################################################
 154 # Determining checksum and size of tar file
 155 #########################################################
 156
 157 sub call_sum
 158 {
 159     my ($filename) = @_;
 160
 161     my $systemcall = "/usr/bin/sum $filename |";
 162
 163     my $sumoutput = "";
 164
 165     open (SUM, "$systemcall");
 166     $sumoutput = <SUM>;
 167     close (SUM);
 168
 169     my $returnvalue = $?;   # $? contains the return value of the systemcall
 170
 171     my $infoline = "Systemcall: $systemcall\n";
 172     push( @installer::globals::logfileinfo, $infoline);
 173
 174     if ($returnvalue)
 175     {
 176         $infoline = "ERROR: Could not execute \"$systemcall\"!\n";
 177         push( @installer::globals::logfileinfo, $infoline);
 178     }
 179     else
 180     {
 181         $infoline = "Success: Executed \"$systemcall\" successfully!\n";
 182         push( @installer::globals::logfileinfo, $infoline);
 183     }
 184
 185     $sumoutput =~ s/\s+$filename\s$//;
 186     return $sumoutput;
 187 }
 188
 189 #########################################################
 190 # Searching for the getuid.so
 191 #########################################################
 192
 193 sub get_path_for_library
 194 {
 195     my $getuidlibrary = $ENV{'WORKDIR'} . '/LinkTarget/Library/libgetuid.so';
 196     if ( ! -e $getuidlibrary ) { installer::exiter::exit_program("File $getuidlibrary does not exist!", "get_path_for_library"); }
 197     return $getuidlibrary;
 198 }
 199
 200 #########################################################
 201 # Include the tar file into the script
 202 #########################################################
 203
 204 sub include_tar_into_script
 205 {
 206     my ($scriptfile, $temporary_tarfile) = @_;
 207
 208     my $systemcall = "cat $temporary_tarfile >> $scriptfile && rm $temporary_tarfile";
 209     my $returnvalue = system($systemcall);
 210
 211     my $infoline = "Systemcall: $systemcall\n";
 212     push( @installer::globals::logfileinfo, $infoline);
 213
 214     if ($returnvalue)
 215     {
 216         $infoline = "ERROR: Could not execute \"$systemcall\"!\n";
 217         push( @installer::globals::logfileinfo, $infoline);
 218     }
 219     else
 220     {
 221         $infoline = "Success: Executed \"$systemcall\" successfully!\n";
 222         push( @installer::globals::logfileinfo, $infoline);
 223     }
 224     return $returnvalue;
 225 }
 226
 227 #########################################################
 228 # Create a tar file from the binary package
 229 #########################################################
 230
 231 sub tar_package
 232 {
 233     my ( $installdir, $tarfilename, $getuidlibrary) = @_;
 234
 235     my $ldpreloadstring = "";
 236     if ( $getuidlibrary ne "" ) { $ldpreloadstring = "LD_PRELOAD=" . $getuidlibrary; }
 237
 238     my $systemcall = "cd $installdir; $ldpreloadstring tar -cf - * > $tarfilename";
 239
 240     my $returnvalue = system($systemcall);
 241
 242     my $infoline = "Systemcall: $systemcall\n";
 243     push( @installer::globals::logfileinfo, $infoline);
 244
 245     if ($returnvalue)
 246     {
 247         $infoline = "ERROR: Could not execute \"$systemcall\"!\n";
 248         push( @installer::globals::logfileinfo, $infoline);
 249     }
 250     else
 251     {
 252         $infoline = "Success: Executed \"$systemcall\" successfully!\n";
 253         push( @installer::globals::logfileinfo, $infoline);
 254     }
 255
 256     chmod 0775, $tarfilename;
 257
 258     return ( -s $tarfilename );
 259 }
 260
 261 #########################################################
 262 # Setting installation languages
 263 #########################################################
 264
 265 sub get_downloadname_language
 266 {
 267     my ($languagestringref) = @_;
 268
 269     my $languages = $$languagestringref;
 270
 271     if ( $installer::globals::added_english )
 272     {
 273         $languages =~ s/en-US_//;
 274         $languages =~ s/_en-US//;
 275     }
 276
 277     # do not list languages if there are too many
 278     if ( length ($languages) > $installer::globals::max_lang_length )
 279     {
 280         $languages = '';
 281     }
 282
 283     # do not list pure en-US, except for helppack and langpack
 284     if ( ( $languages eq "en-US" ) &&
 285          ( ! $installer::globals::languagepack ) &&
 286          ( ! $installer::globals::helppack ) )
 287     {
 288         $languages = '';
 289     }
 290
 291     return $languages;
 292 }
 293
 294 #########################################################
 295 # Setting download name
 296 #########################################################
 297
 298 sub get_downloadname_productname
 299 {
 300     my ($allvariables) = @_;
 301
 302     my $start = "";
 303
 304     if ( $allvariables->{'PRODUCTNAME'} eq "LibreOffice" ) { $start = "LibreOffice"; }
 305
 306     elsif ( $allvariables->{'PRODUCTNAME'} eq "LibreOfficeDev" ) { $start = "LibreOfficeDev"; }
 307
 308     elsif ( $allvariables->{'PRODUCTNAME'} eq "OxygenOffice" ) { $start = "OOOP"; }
 309
 310     elsif ( $allvariables->{'PRODUCTNAME'} eq "" ) { $start = "LibreOffice"; }
 311
 312     else  { $start = $allvariables->{'PRODUCTNAME'}; }
 313
 314     return $start;
 315 }
 316
 317 #########################################################
 318 # Setting download version
 319 #########################################################
 320
 321 sub get_download_version
 322 {
 323     my ($allvariables) = @_;
 324
 325     my $version = "";
 326
 327     $version = $allvariables->{'PRODUCTVERSION'};
 328     if (( $allvariables->{'PRODUCTEXTENSION'} ) && ( $allvariables->{'PRODUCTEXTENSION'} ne "" )) { $version = $version . $allvariables->{'PRODUCTEXTENSION'}; }
 329
 330     return $version;
 331 }
 332
 333 #################################################################
 334 # Setting the platform name for download
 335 #################################################################
 336
 337 sub get_download_platformname
 338 {
 339     my $platformname = "";
 340
 341     if ( $installer::globals::islinuxbuild )
 342     {
 343         $platformname = "Linux";
 344     }
 345     elsif ( $installer::globals::issolarisbuild )
 346     {
 347         $platformname = "Solaris";
 348     }
 349     elsif ( $installer::globals::iswindowsbuild )
 350     {
 351         $platformname = "Win";
 352     }
 353     elsif ( $installer::globals::isfreebsdbuild )
 354     {
 355         $platformname = "FreeBSD";
 356     }
 357     elsif ( $installer::globals::ismacbuild )
 358     {
 359         $platformname = "MacOS";
 360     }
 361     else
 362     {
 363         $platformname = $installer::globals::os;
 364     }
 365
 366     return $platformname;
 367 }
 368
 369 #########################################################
 370 # Setting the architecture for the download name
 371 #########################################################
 372
 373 sub get_download_architecture
 374 {
 375     my $arch = "";
 376
 377     if ( $installer::globals::issolarissparcbuild )
 378     {
 379         $arch = "Sparc";
 380     }
 381     elsif ( $installer::globals::issolarisx86build )
 382     {
 383         $arch = "x86";
 384     }
 385     elsif ( $installer::globals::iswindowsbuild )
 386     {
 387         if ( $installer::globals::iswin64build )
 388         {
 389             $arch = "x64";
 390         }
 391         else
 392         {
 393             $arch = "x86";
 394         }
 395     }
 396     elsif ( $installer::globals::cpuname eq 'INTEL' )
 397     {
 398         $arch = "x86";
 399     }
 400     elsif ( $installer::globals::cpuname eq 'POWERPC' )
 401     {
 402         $arch = "PPC";
 403     }
 404     elsif ( $installer::globals::cpuname eq 'POWERPC64' )
 405     {
 406         $arch = "PPC";
 407     }
 408     elsif ( $installer::globals::cpuname eq 'X86_64' )
 409     {
 410         $arch = "x86-64";
 411     }
 412
 413     return $arch;
 414 }
 415
 416 #########################################################
 417 # Setting the content type for the download name
 418 #########################################################
 419
 420 sub get_download_content
 421 {
 422     my ($allvariables) = @_;
 423
 424     my $content = "";
 425
 426     # content type included in the installer
 427     if ( $installer::globals::isrpmbuild )
 428     {
 429         $content = "rpm";
 430     }
 431     elsif ( $installer::globals::isdebbuild )
 432     {
 433         $content = "deb";
 434     }
 435     elsif ( $installer::globals::packageformat eq "archive" )
 436     {
 437         $content = "archive";
 438     }
 439
 440     return $content;
 441 }
 442
 443 #########################################################
 444 # Setting the functionality type for the download name
 445 #########################################################
 446
 447 sub get_download_functionality
 448 {
 449     my ($allvariables) = @_;
 450
 451     my $functionality = "";
 452
 453     if ( $installer::globals::languagepack )
 454     {
 455         $functionality = "langpack";
 456     }
 457     elsif ( $installer::globals::helppack )
 458     {
 459         $functionality = "helppack";
 460     }
 461     elsif ( $allvariables->{'POSTVERSIONEXTENSION'} eq "SDK" )
 462     {
 463         $functionality = "sdk";
 464     }
 465     elsif ( $allvariables->{'POSTVERSIONEXTENSION'} eq "TEST" )
 466     {
 467         $functionality = "test";
 468     }
 469     elsif ( $allvariables->{'PRODUCTNAME'} eq "URE" )
 470     {
 471         $functionality = "ure";
 472     }
 473
 474     return $functionality;
 475 }
 476
 477 ###############################################################################################
 478 # Setting the download file name
 479 # Syntax:
 480 # (PRODUCTNAME)_(VERSION)_(OS)_(ARCH)_(INSTALLTYPE)_(LANGUAGE).(FILEEXTENSION)
 481 ###############################################################################################
 482
 483 sub set_download_filename
 484 {
 485     my ($languagestringref, $allvariables) = @_;
 486
 487     my $start = get_downloadname_productname($allvariables);
 488     my $versionstring = get_download_version($allvariables);
 489     my $platform = get_download_platformname();
 490     my $architecture = get_download_architecture();
 491     my $content = get_download_content($allvariables);
 492     my $functionality = get_download_functionality($allvariables);
 493     my $language = get_downloadname_language($languagestringref);
 494
 495     # Setting the extension happens automatically
 496
 497     my $filename = $start . "_" . $versionstring . "_" . $platform . "_" . $architecture . "_" . $content . "_" . $functionality . "_" . $language;
 498
 499     # get rid of duplicit "_" delimiters when some strings are empty
 500     $filename =~ s/\_\_\_/\_/g;
 501     $filename =~ s/\_\_/\_/g;
 502     $filename =~ s/\_\s*$//;
 503
 504     $installer::globals::ooodownloadfilename = $filename;
 505
 506     return $filename;
 507 }
 508
 509
 510 #########################################################
 511 # Creating a tar.gz file
 512 #########################################################
 513
 514 sub create_tar_gz_file_from_directory
 515 {
 516     my ($installdir, $getuidlibrary, $downloaddir, $downloadfilename) = @_;
 517
 518     my $infoline = "";
 519
 520     my $packdir = $installdir;
 521     installer::pathanalyzer::make_absolute_filename_to_relative_filename(\$packdir);
 522     my $changedir = $installdir;
 523     installer::pathanalyzer::get_path_from_fullqualifiedname(\$changedir);
 524
 525     my $ldpreloadstring = "";
 526     if ( $getuidlibrary ne "" ) { $ldpreloadstring = "LD_PRELOAD=" . $getuidlibrary; }
 527
 528     $installer::globals::downloadfileextension = ".tar.gz";
 529     $installer::globals::downloadfilename = $downloadfilename . $installer::globals::downloadfileextension;
 530     my $targzname = $downloaddir . $installer::globals::separator . $installer::globals::downloadfilename;
 531
 532     # fdo#67060 - install script is for RPM only
 533     if ( -e "$installdir/install" && !$installer::globals::isrpmbuild )
 534     {
 535         unlink("$installdir/install");
 536     }
 537
 538     my $systemcall = "cd $changedir; $ldpreloadstring tar -cf - $packdir | gzip > $targzname";
 539
 540     my $returnvalue = system($systemcall);
 541
 542     $infoline = "Systemcall: $systemcall\n";
 543     push( @installer::globals::logfileinfo, $infoline);
 544
 545     if ($returnvalue)
 546     {
 547         $infoline = "ERROR: Could not execute \"$systemcall\"!\n";
 548         push( @installer::globals::logfileinfo, $infoline);
 549     }
 550     else
 551     {
 552         $infoline = "Success: Executed \"$systemcall\" successfully!\n";
 553         push( @installer::globals::logfileinfo, $infoline);
 554     }
 555
 556     return $targzname;
 557 }
 558
 559 #########################################################
 560 # Setting the variables in the download name
 561 #########################################################
 562
 563 sub resolve_variables_in_downloadname
 564 {
 565     my ($allvariables, $downloadname, $languagestringref) = @_;
 566
 567     # Typical name: soa-{productversion}-{extension}-bin-{os}-{languages}
 568
 569     my $productversion = "";
 570     if ( $allvariables->{'PRODUCTVERSION'} ) { $productversion = $allvariables->{'PRODUCTVERSION'}; }
 571     $downloadname =~ s/\{productversion\}/$productversion/;
 572
 573     my $packageversion = "";
 574     if ( $allvariables->{'PACKAGEVERSION'} ) { $packageversion = $allvariables->{'PACKAGEVERSION'}; }
 575     $downloadname =~ s/\{packageversion\}/$packageversion/;
 576
 577     my $extension = "";
 578     if ( $allvariables->{'PRODUCTEXTENSION'} ) { $extension = $allvariables->{'PRODUCTEXTENSION'}; }
 579     $extension = lc($extension);
 580     $downloadname =~ s/\{extension\}/$extension/;
 581
 582     my $os = "";
 583     if ( $installer::globals::iswindowsbuild ) { $os = "windows"; }
 584     elsif ( $installer::globals::issolarissparcbuild ) { $os = "solsparc"; }
 585     elsif ( $installer::globals::issolarisx86build ) { $os = "solia"; }
 586     elsif ( $installer::globals::islinuxbuild ) { $os = "linux"; }
 587     elsif ( $installer::globals::platformid eq 'macosx_x86_64' ) { $os = "macosxx"; }
 588     else { $os = ""; }
 589     $downloadname =~ s/\{os\}/$os/;
 590
 591     my $languages = $$languagestringref;
 592     $downloadname =~ s/\{languages\}/$languages/;
 593
 594     $downloadname =~ s/\-\-\-/\-/g;
 595     $downloadname =~ s/\-\-/\-/g;
 596     $downloadname =~ s/\-\s*$//;
 597
 598     return $downloadname;
 599 }
 600
 601 ##############################################################
 602 # Returning the complete block in all languages
 603 # for a specified string
 604 ##############################################################
 605
 606 sub get_language_block_from_language_file
 607 {
 608     my ($searchstring, $languagefile) = @_;
 609
 610     my @language_block = ();
 611
 612     for ( my $i = 0; $i <= $#{$languagefile}; $i++ )
 613     {
 614         if ( ${$languagefile}[$i] =~ /^\s*\[\s*$searchstring\s*\]\s*$/ )
 615         {
 616             my $counter = $i;
 617
 618             push(@language_block, ${$languagefile}[$counter]);
 619             $counter++;
 620
 621             while (( $counter <= $#{$languagefile} ) && (!( ${$languagefile}[$counter] =~ /^\s*\[/ )))
 622             {
 623                 push(@language_block, ${$languagefile}[$counter]);
 624                 $counter++;
 625             }
 626
 627             last;
 628         }
 629     }
 630
 631     return \@language_block;
 632 }
 633
 634 ##############################################################
 635 # Returning a specific language string from the block
 636 # of all translations
 637 ##############################################################
 638
 639 sub get_language_string_from_language_block
 640 {
 641     my ($language_block, $language) = @_;
 642
 643     my $newstring = "";
 644
 645     for ( my $i = 0; $i <= $#{$language_block}; $i++ )
 646     {
 647         if ( ${$language_block}[$i] =~ /^\s*$language\s*\=\s*\"(.*)\"\s*$/ )
 648         {
 649             $newstring = $1;
 650             last;
 651         }
 652     }
 653
 654     if ( $newstring eq "" )
 655     {
 656         $language = "en-US";    # defaulting to english
 657
 658         for ( my $i = 0; $i <= $#{$language_block}; $i++ )
 659         {
 660             if ( ${$language_block}[$i] =~ /^\s*$language\s*\=\s*\"(.*)\"\s*$/ )
 661             {
 662                 $newstring = $1;
 663                 last;
 664             }
 665         }
 666     }
 667
 668     return $newstring;
 669 }
 670
 671 ####################################################
 672 # Creating download installation sets
 673 ####################################################
 674
 675 sub create_download_sets
 676 {
 677     my ($installationdir, $includepatharrayref, $allvariableshashref, $downloadname, $languagestringref, $languagesarrayref) = @_;
 678
 679     my $infoline = "";
 680
 681     my $force = 1; # print this message even in 'quiet' mode
 682     installer::logger::print_message( "\n******************************************\n" );
 683     installer::logger::print_message( "... creating download installation set ...\n", $force );
 684     installer::logger::print_message( "******************************************\n" );
 685
 686     installer::logger::include_header_into_logfile("Creating download installation sets:");
 687
 688     my $firstdir = $installationdir;
 689     installer::pathanalyzer::get_path_from_fullqualifiedname(\$firstdir);
 690
 691     my $lastdir = $installationdir;
 692     installer::pathanalyzer::make_absolute_filename_to_relative_filename(\$lastdir);
 693
 694     if ( $installer::globals::iswindowsbuild && $lastdir =~ /\./ ) { $lastdir =~ s/\./_download_inprogress\./ }
 695     else { $lastdir = $lastdir . "_download_inprogress"; }
 696
 697     # removing existing directory "_native_packed_inprogress" and "_native_packed_witherror" and "_native_packed"
 698
 699     my $downloaddir = $firstdir . $lastdir;
 700
 701     if ( -d $downloaddir ) { installer::systemactions::remove_complete_directory($downloaddir); }
 702
 703     my $olddir = $downloaddir;
 704     $olddir =~ s/_inprogress/_witherror/;
 705     if ( -d $olddir ) { installer::systemactions::remove_complete_directory($olddir); }
 706
 707     $olddir = $downloaddir;
 708     $olddir =~ s/_inprogress//;
 709     if ( -d $olddir ) { installer::systemactions::remove_complete_directory($olddir); }
 710
 711     # creating the new directory
 712
 713     installer::systemactions::create_directory($downloaddir);
 714
 715     $installer::globals::saveinstalldir = $downloaddir;
 716
 717     # evaluating the name of the download file
 718
 719     if ( $allvariableshashref->{'OOODOWNLOADNAME'} ) { $downloadname = set_download_filename($languagestringref, $allvariableshashref); }
 720     else { $downloadname = resolve_variables_in_downloadname($allvariableshashref, $downloadname, $languagestringref); }
 721
 722     if ( ! $installer::globals::iswindowsbuild )    # Unix specific part
 723     {
 724
 725         # getting the path of the getuid.so (only required for Solaris and Linux)
 726         my $getuidlibrary = "";
 727         if (( $installer::globals::issolarisbuild ) || ( $installer::globals::islinuxbuild )) { $getuidlibrary = get_path_for_library(); }
 728
 729         if ( $allvariableshashref->{'OOODOWNLOADNAME'} )
 730         {
 731             my $downloadfile = create_tar_gz_file_from_directory($installationdir, $getuidlibrary, $downloaddir, $downloadname);
 732         }
 733         else
 734         {
 735             # find and read setup script template
 736             my $scriptfilename = $ENV{'SRCDIR'} . "/setup_native/scripts/downloadscript.sh";
 737
 738             if (! -f $scriptfilename) { installer::exiter::exit_program("ERROR: Could not find script file $scriptfilename!", "create_download_sets"); }
 739             my $scriptfile = installer::files::read_file($scriptfilename);
 740
 741             $infoline = "Found  script file $scriptfilename \n";
 742             push( @installer::globals::logfileinfo, $infoline);
 743
 744             # add product name into script template
 745             put_productname_into_script($scriptfile, $allvariableshashref);
 746
 747             # replace linenumber in script template
 748             put_linenumber_into_script($scriptfile);
 749
 750             # create tar file
 751             my $temporary_tarfile_name = $downloaddir . $installer::globals::separator . 'installset.tar';
 752             my $size = tar_package($installationdir, $temporary_tarfile_name, $getuidlibrary);
 753             installer::exiter::exit_program("ERROR: Could not create tar file $temporary_tarfile_name!", "create_download_sets") unless $size;
 754
 755             # calling sum to determine checksum and size of the tar file
 756             my $sumout = call_sum($temporary_tarfile_name);
 757
 758             # writing checksum and size into scriptfile
 759             put_checksum_and_size_into_script($scriptfile, $sumout);
 760
 761             # saving the script file
 762             my $newscriptfilename = determine_scriptfile_name($downloadname);
 763             $newscriptfilename = save_script_file($downloaddir, $newscriptfilename, $scriptfile);
 764
 765             installer::logger::print_message( "... including installation set into $newscriptfilename ... \n" );
 766             # Append tar file to script
 767             include_tar_into_script($newscriptfilename, $temporary_tarfile_name);
 768         }
 769     }
 770
 771     return $downloaddir;
 772 }
 773
 774 1;