vcl/opengl/areaScaleFastFragmentShader.glsl

   1 /* -*- Mode: C++; tab-width: 4; indent-tabs-mode: nil; c-basic-offset: 4 -*- */
   2 /*
   3  * This file is part of the LibreOffice project.
   4  *
   5  * This Source Code Form is subject to the terms of the Mozilla Public
   6  * License, v. 2.0. If a copy of the MPL was not distributed with this
   7  * file, You can obtain one at http://mozilla.org/MPL/2.0/.
   8  */
   9
  10 /* TODO Use textureOffset for newest version of GLSL */
  11
  12 uniform sampler2D sampler;
  13 uniform int xscale;
  14 uniform int yscale;
  15 uniform float xstep;
  16 uniform float ystep;
  17 uniform float ratio; // = 1.0/(xscale*yscale)
  18
  19 varying vec2 tex_coord;
  20
  21 // This mode makes the scaling work like maskedTextureFragmentShader.glsl
  22 // (instead of like plain textureVertexShader.glsl).
  23 #ifdef MASKED
  24 varying vec2 mask_coord;
  25 uniform sampler2D mask;
  26 #endif
  27
  28 /*
  29  Just make the resulting color the average of all the source pixels
  30  (which is an area (xscale)x(yscale) ).
  31 */
  32 void main(void)
  33 {
  34     vec4 sum = vec4( 0.0, 0.0, 0.0, 0.0 );
  35     vec2 offset = vec2( 0.0, 0.0 );
  36     for( int y = 0; y < yscale; ++y )
  37     {
  38         for( int x = 0; x < xscale; ++x )
  39         {
  40 #ifndef MASKED
  41             sum += texture2D( sampler, tex_coord.st + offset );
  42 #else
  43             vec4 texel;
  44             texel = texture2D( sampler, tex_coord.st + offset );
  45             texel.a = 1.0 - texture2D( mask, mask_coord.st + offset ).r;
  46             sum += texel;
  47 #endif
  48             offset.x += xstep;
  49         }
  50         offset.y += ystep;
  51         offset.x = 0.0;
  52     }
  53     sum *= ratio;
  54     gl_FragColor = sum;
  55 }
  56
  57 /* vim:set shiftwidth=4 softtabstop=4 expandtab: */