vcl/osx/OSXTransferable.cxx

   1 /* -*- Mode: C++; tab-width: 4; indent-tabs-mode: nil; c-basic-offset: 4 -*- */
   2 /*
   3  * This file is part of the LibreOffice project.
   4  *
   5  * This Source Code Form is subject to the terms of the Mozilla Public
   6  * License, v. 2.0. If a copy of the MPL was not distributed with this
   7  * file, You can obtain one at http://mozilla.org/MPL/2.0/.
   8  *
   9  * This file incorporates work covered by the following license notice:
  10  *
  11  *   Licensed to the Apache Software Foundation (ASF) under one or more
  12  *   contributor license agreements. See the NOTICE file distributed
  13  *   with this work for additional information regarding copyright
  14  *   ownership. The ASF licenses this file to you under the Apache
  15  *   License, Version 2.0 (the "License"); you may not use this file
  16  *   except in compliance with the License. You may obtain a copy of
  17  *   the License at http://www.apache.org/licenses/LICENSE-2.0 .
  18  */
  19
  20 #include <sal/types.h>
  21 #include <osl/diagnose.h>
  22
  23 #include "OSXTransferable.hxx"
  24
  25 #include "DataFlavorMapping.hxx"
  26
  27 using namespace std;
  28 using namespace osl;
  29 using namespace cppu;
  30 using namespace com::sun::star::uno;
  31 using namespace com::sun::star::datatransfer;
  32 using namespace com::sun::star::io;
  33 using namespace com::sun::star::lang;
  34 using namespace com::sun::star::container;
  35
  36 namespace // private
  37 {
  38     bool isValidFlavor( const DataFlavor& aFlavor )
  39     {
  40       size_t len = aFlavor.MimeType.getLength();
  41       Type dtype = aFlavor.DataType;
  42       return ((len > 0) && ((dtype == cppu::UnoType<Sequence<sal_Int8>>::get()) || (dtype == cppu::UnoType<OUString>::get())));
  43     }
  44
  45 bool cmpAllContentTypeParameter(const Reference<XMimeContentType> xLhs,
  46                                                const Reference<XMimeContentType> xRhs)
  47 {
  48   Sequence<OUString> xLhsFlavors = xLhs->getParameters();
  49   Sequence<OUString> xRhsFlavors = xRhs->getParameters();
  50
  51   // Stop here if the number of parameters is different already
  52   if (xLhsFlavors.getLength() != xRhsFlavors.getLength())
  53     return false;
  54
  55   try
  56     {
  57       OUString pLhs;
  58       OUString pRhs;
  59
  60       for (sal_Int32 i = 0; i < xLhsFlavors.getLength(); i++)
  61         {
  62           pLhs = xLhs->getParameterValue(xLhsFlavors[i]);
  63           pRhs = xRhs->getParameterValue(xLhsFlavors[i]);
  64
  65           if (!pLhs.equalsIgnoreAsciiCase(pRhs))
  66             {
  67               return false;
  68             }
  69         }
  70     }
  71   catch(IllegalArgumentException&)
  72     {
  73       return false;
  74     }
  75
  76   return true;
  77 }
  78
  79 } // namespace private
  80
  81 OSXTransferable::OSXTransferable(const Reference<XMimeContentTypeFactory> rXMimeCntFactory,
  82                                  DataFlavorMapperPtr_t pDataFlavorMapper,
  83                                  NSPasteboard* pasteboard) :
  84   mrXMimeCntFactory(rXMimeCntFactory),
  85   mDataFlavorMapper(pDataFlavorMapper),
  86   mPasteboard(pasteboard)
  87 {
  88   [mPasteboard retain];
  89
  90   initClipboardItemList();
  91 }
  92
  93 OSXTransferable::~OSXTransferable()
  94 {
  95   [mPasteboard release];
  96 }
  97
  98 Any SAL_CALL OSXTransferable::getTransferData( const DataFlavor& aFlavor )
  99   throw( UnsupportedFlavorException, IOException, RuntimeException, std::exception )
 100 {
 101   if (!isValidFlavor(aFlavor) || !isDataFlavorSupported(aFlavor))
 102     {
 103       throw UnsupportedFlavorException("AquaClipboard: Unsupported data flavor",
 104                                        static_cast<XTransferable*>(this));
 105     }
 106
 107   bool bInternal(false);
 108   NSString* sysFormat =
 109       (aFlavor.MimeType.startsWith("image/png"))
 110       ? DataFlavorMapper::openOfficeImageToSystemFlavor( mPasteboard )
 111       : mDataFlavorMapper->openOfficeToSystemFlavor(aFlavor, bInternal);
 112   DataProviderPtr_t dp;
 113
 114   if ([sysFormat caseInsensitiveCompare: NSFilenamesPboardType] == NSOrderedSame)
 115     {
 116       NSArray* sysData = [mPasteboard propertyListForType: sysFormat];
 117       dp = DataFlavorMapper::getDataProvider(sysFormat, sysData);
 118     }
 119   else
 120     {
 121       NSData* sysData = [mPasteboard dataForType: sysFormat];
 122       dp = DataFlavorMapper::getDataProvider(sysFormat, sysData);
 123     }
 124
 125   if (dp.get() == NULL)
 126     {
 127       throw UnsupportedFlavorException("AquaClipboard: Unsupported data flavor",
 128                                        static_cast<XTransferable*>(this));
 129     }
 130
 131   return dp->getOOoData();
 132 }
 133
 134 Sequence< DataFlavor > SAL_CALL OSXTransferable::getTransferDataFlavors(  )
 135     throw( RuntimeException, std::exception )
 136 {
 137   return mFlavorList;
 138 }
 139
 140 sal_Bool SAL_CALL OSXTransferable::isDataFlavorSupported(const DataFlavor& aFlavor)
 141     throw( RuntimeException, std::exception )
 142 {
 143     for (sal_Int32 i = 0; i < mFlavorList.getLength(); i++)
 144       if (compareDataFlavors(aFlavor, mFlavorList[i]))
 145         return true;
 146
 147     return false;
 148 }
 149
 150 void OSXTransferable::initClipboardItemList()
 151 {
 152   NSArray* pboardFormats = [mPasteboard types];
 153
 154   if (pboardFormats == NULL)
 155     {
 156       throw RuntimeException("AquaClipboard: Cannot get clipboard data",
 157                              static_cast<XTransferable*>(this));
 158     }
 159
 160   mFlavorList = mDataFlavorMapper->typesArrayToFlavorSequence(pboardFormats);
 161 }
 162
 163 /* Compares two DataFlavors. Returns true if both DataFlavor have the same media type
 164    and the number of parameter and all parameter values do match otherwise false
 165    is returned.
 166  */
 167 bool OSXTransferable::compareDataFlavors(const DataFlavor& lhs, const DataFlavor& rhs )
 168 {
 169     try
 170     {
 171         Reference<XMimeContentType> xLhs(mrXMimeCntFactory->createMimeContentType(lhs.MimeType));
 172         Reference<XMimeContentType> xRhs(mrXMimeCntFactory->createMimeContentType(rhs.MimeType));
 173
 174         if (!xLhs->getFullMediaType().equalsIgnoreAsciiCase(xRhs->getFullMediaType()) ||
 175             !cmpAllContentTypeParameter(xLhs, xRhs))
 176           {
 177             return false;
 178           }
 179     }
 180     catch( IllegalArgumentException& )
 181     {
 182         OSL_FAIL( "Invalid content type detected" );
 183         return false;
 184     }
 185
 186     return true;
 187 }
 188
 189 /* vim:set shiftwidth=4 softtabstop=4 expandtab: */