vcl/osx/saltimer.cxx

   1 /* -*- Mode: C++; tab-width: 4; indent-tabs-mode: nil; c-basic-offset: 4 -*- */
   2 /*
   3  * This file is part of the LibreOffice project.
   4  *
   5  * This Source Code Form is subject to the terms of the Mozilla Public
   6  * License, v. 2.0. If a copy of the MPL was not distributed with this
   7  * file, You can obtain one at http://mozilla.org/MPL/2.0/.
   8  *
   9  * This file incorporates work covered by the following license notice:
  10  *
  11  *   Licensed to the Apache Software Foundation (ASF) under one or more
  12  *   contributor license agreements. See the NOTICE file distributed
  13  *   with this work for additional information regarding copyright
  14  *   ownership. The ASF licenses this file to you under the Apache
  15  *   License, Version 2.0 (the "License"); you may not use this file
  16  *   except in compliance with the License. You may obtain a copy of
  17  *   the License at http://www.apache.org/licenses/LICENSE-2.0 .
  18  */
  19
  20 #include "osx/saltimer.h"
  21 #include "osx/salnstimer.h"
  22 #include "osx/saldata.hxx"
  23 #include "osx/salframe.h"
  24 #include "osx/salinst.h"
  25
  26 NSTimer* AquaSalTimer::pRunningTimer = nil;
  27 bool AquaSalTimer::bDispatchTimer = false;
  28
  29 void ImplSalStartTimer( sal_uLong nMS )
  30 {
  31     SalData* pSalData = GetSalData();
  32     if( pSalData->mpFirstInstance->isNSAppThread() )
  33     {
  34         AquaSalTimer::bDispatchTimer = true;
  35         NSTimeInterval aTI = double(nMS)/1000.0;
  36         if( AquaSalTimer::pRunningTimer != nil )
  37         {
  38             if( [AquaSalTimer::pRunningTimer timeInterval] == aTI )
  39                 // set new fire date
  40                 [AquaSalTimer::pRunningTimer setFireDate: [NSDate dateWithTimeIntervalSinceNow: aTI]];
  41             else
  42             {
  43                 [AquaSalTimer::pRunningTimer invalidate];
  44                 AquaSalTimer::pRunningTimer = nil;
  45             }
  46         }
  47         if( AquaSalTimer::pRunningTimer == nil )
  48         {
  49             AquaSalTimer::pRunningTimer = [NSTimer scheduledTimerWithTimeInterval: aTI
  50                                                    target: [[[TimerCallbackCaller alloc] init] autorelease]
  51                                                    selector: @selector(timerElapsed:)
  52                                                    userInfo: nil
  53                                                    repeats: YES];
  54             /* #i84055# add timer to tracking run loop mode,
  55                so they also elapse while e.g. life resize
  56             */
  57             [[NSRunLoop currentRunLoop] addTimer: AquaSalTimer::pRunningTimer forMode: NSEventTrackingRunLoopMode];
  58         }
  59     }
  60     else
  61     {
  62         SalData::ensureThreadAutoreleasePool();
  63         // post an event so we can get into the main thread
  64         NSEvent* pEvent = [NSEvent otherEventWithType: NSApplicationDefined
  65                                    location: NSZeroPoint
  66                                    modifierFlags: 0
  67                                    timestamp: [NSDate timeIntervalSinceReferenceDate]
  68                                    windowNumber: 0
  69                                    context: nil
  70                                    subtype: AquaSalInstance::AppStartTimerEvent
  71                                    data1: (int)nMS
  72                                    data2: 0 ];
  73         if( pEvent )
  74             [NSApp postEvent: pEvent atStart: YES];
  75     }
  76 }
  77
  78 void ImplSalStopTimer()
  79 {
  80     AquaSalTimer::bDispatchTimer = false;
  81 }
  82
  83 void AquaSalTimer::handleStartTimerEvent( NSEvent* pEvent )
  84 {
  85     ImplSVData* pSVData = ImplGetSVData();
  86     if( pSVData->mpSalTimer )
  87     {
  88         NSTimeInterval posted = [pEvent timestamp] + NSTimeInterval([pEvent data1])/1000.0;
  89         NSTimeInterval current = [NSDate timeIntervalSinceReferenceDate];
  90         if( (posted - current) <= 0.0 )
  91         {
  92             YIELD_GUARD;
  93             if( pSVData->mpSalTimer )
  94             {
  95                 // timer already elapsed since event posted
  96                 bool idle = true; // TODO
  97                 pSVData->mpSalTimer->CallCallback( idle );
  98             }
  99         }
 100         ImplSalStartTimer( sal_uLong( [pEvent data1] ) );
 101     }
 102
 103 }
 104
 105 AquaSalTimer::AquaSalTimer( )
 106 {
 107 }
 108
 109 AquaSalTimer::~AquaSalTimer()
 110 {
 111     ImplSalStopTimer();
 112 }
 113
 114 void AquaSalTimer::Start( sal_uLong nMS )
 115 {
 116     ImplSalStartTimer( nMS );
 117 }
 118
 119 void AquaSalTimer::Stop()
 120 {
 121     ImplSalStopTimer();
 122 }
 123
 124 /* vim:set shiftwidth=4 softtabstop=4 expandtab: */