vcl/ios/clipboard.cxx

   1 /* -*- Mode: ObjC; tab-width: 4; indent-tabs-mode: nil; c-basic-offset: 4; fill-column: 100 -*- */
   2 /*
   3  * This file is part of the LibreOffice project.
   4  *
   5  * This Source Code Form is subject to the terms of the Mozilla Public
   6  * License, v. 2.0. If a copy of the MPL was not distributed with this
   7  * file, You can obtain one at http://mozilla.org/MPL/2.0/.
   8  *
   9  * This file incorporates work covered by the following license notice:
  10  *
  11  *   Licensed to the Apache Software Foundation (ASF) under one or more
  12  *   contributor license agreements. See the NOTICE file distributed
  13  *   with this work for additional information regarding copyright
  14  *   ownership. The ASF licenses this file to you under the Apache
  15  *   License, Version 2.0 (the "License"); you may not use this file
  16  *   except in compliance with the License. You may obtain a copy of
  17  *   the License at http://www.apache.org/licenses/LICENSE-2.0 .
  18  */
  19
  20 #include "ios/iosinst.hxx"
  21
  22 #include "clipboard.hxx"
  23
  24 #include "DataFlavorMapping.hxx"
  25 #include "iOSTransferable.hxx"
  26 #include <com/sun/star/datatransfer/MimeContentTypeFactory.hpp>
  27 #include <com/sun/star/lang/IllegalArgumentException.hpp>
  28 #include <comphelper/processfactory.hxx>
  29 #include <cppuhelper/supportsservice.hxx>
  30
  31 iOSClipboard::iOSClipboard()
  32     : WeakComponentImplHelper<XSystemClipboard, XServiceInfo>(m_aMutex)
  33 {
  34     auto xContext = comphelper::getProcessComponentContext();
  35
  36     mrXMimeCntFactory = css::datatransfer::MimeContentTypeFactory::create(xContext);
  37
  38     mpDataFlavorMapper.reset(new DataFlavorMapper());
  39
  40     mPasteboard = [UIPasteboard generalPasteboard];
  41     assert(mPasteboard != nil);
  42 }
  43
  44 iOSClipboard::~iOSClipboard() {}
  45
  46 css::uno::Reference<css::datatransfer::XTransferable> SAL_CALL iOSClipboard::getContents()
  47 {
  48     osl::MutexGuard aGuard(m_aMutex);
  49
  50     return css::uno::Reference<css::datatransfer::XTransferable>(
  51         new iOSTransferable(mrXMimeCntFactory, mpDataFlavorMapper, mPasteboard));
  52 }
  53
  54 void SAL_CALL iOSClipboard::setContents(
  55     const css::uno::Reference<css::datatransfer::XTransferable>& xTransferable,
  56     const css::uno::Reference<css::datatransfer::clipboard::XClipboardOwner>& /*xClipboardOwner*/)
  57 {
  58     NSArray* types = xTransferable.is() ? mpDataFlavorMapper->flavorSequenceToTypesArray(
  59                                               xTransferable->getTransferDataFlavors())
  60                                         : [NSArray array];
  61
  62     osl::ClearableMutexGuard aGuard(m_aMutex);
  63
  64     NSMutableDictionary* dict = [NSMutableDictionary dictionaryWithCapacity:1];
  65     NSArray* array = @[ dict ];
  66
  67     for (sal_uInt32 i = 0; i < [types count]; ++i)
  68     {
  69         DataProviderPtr_t dp = mpDataFlavorMapper->getDataProvider(types[i], xTransferable);
  70
  71         if (dp.get() != nullptr)
  72         {
  73             NSData* pBoardData = (NSData*)dp->getSystemData();
  74             dict[types[i]] = pBoardData;
  75         }
  76     }
  77     [mPasteboard setItems:array options:@{}];
  78
  79     // We don't keep a copy of the clipboard contents around in-process, so fire the lost clipboard
  80     // ownership event right away.
  81     // fireLostClipboardOwnershipEvent(xClipboardOwner, xTransferable);
  82
  83     // fireClipboardChangedEvent(xTransferable);
  84 }
  85
  86 OUString SAL_CALL iOSClipboard::getName() { return OUString(); }
  87
  88 sal_Int8 SAL_CALL iOSClipboard::getRenderingCapabilities() { return 0; }
  89
  90 void SAL_CALL iOSClipboard::addClipboardListener(
  91     const css::uno::Reference<css::datatransfer::clipboard::XClipboardListener>& listener)
  92 {
  93     osl::MutexGuard aGuard(m_aMutex);
  94
  95     if (!listener.is())
  96         throw css::lang::IllegalArgumentException(
  97             "empty reference", static_cast<css::datatransfer::clipboard::XClipboardEx*>(this), 1);
  98
  99     mClipboardListeners.push_back(listener);
 100 }
 101
 102 void SAL_CALL iOSClipboard::removeClipboardListener(
 103     const css::uno::Reference<css::datatransfer::clipboard::XClipboardListener>& listener)
 104 {
 105     osl::MutexGuard aGuard(m_aMutex);
 106
 107     if (!listener.is())
 108         throw css::lang::IllegalArgumentException(
 109             "empty reference", static_cast<css::datatransfer::clipboard::XClipboardEx*>(this), 1);
 110
 111     mClipboardListeners.remove(listener);
 112 }
 113
 114 void iOSClipboard::fireClipboardChangedEvent(
 115     css::uno::Reference<css::datatransfer::XTransferable> xNewContents)
 116 {
 117     osl::ClearableMutexGuard aGuard(m_aMutex);
 118
 119     std::list<css::uno::Reference<css::datatransfer::clipboard::XClipboardListener>> listeners(
 120         mClipboardListeners);
 121     css::datatransfer::clipboard::ClipboardEvent aEvent;
 122
 123     if (!listeners.empty())
 124     {
 125         aEvent = css::datatransfer::clipboard::ClipboardEvent(static_cast<OWeakObject*>(this),
 126                                                               xNewContents);
 127     }
 128
 129     aGuard.clear();
 130
 131     while (!listeners.empty())
 132     {
 133         if (listeners.front().is())
 134         {
 135             try
 136             {
 137                 listeners.front()->changedContents(aEvent);
 138             }
 139             catch (const css::uno::RuntimeException&)
 140             {
 141             }
 142         }
 143         listeners.pop_front();
 144     }
 145 }
 146
 147 void iOSClipboard::fireLostClipboardOwnershipEvent(
 148     css::uno::Reference<css::datatransfer::clipboard::XClipboardOwner> const& oldOwner,
 149     css::uno::Reference<css::datatransfer::XTransferable> const& oldContent)
 150 {
 151     assert(oldOwner.is());
 152
 153     try
 154     {
 155         oldOwner->lostOwnership(static_cast<css::datatransfer::clipboard::XClipboardEx*>(this),
 156                                 oldContent);
 157     }
 158     catch (const css::uno::RuntimeException&)
 159     {
 160     }
 161 }
 162
 163 OUString SAL_CALL iOSClipboard::getImplementationName()
 164 {
 165     return OUString("com.sun.star.datatransfer.clipboard.iOSClipboard");
 166 }
 167
 168 sal_Bool SAL_CALL iOSClipboard::supportsService(const OUString& ServiceName)
 169 {
 170     return cppu::supportsService(this, ServiceName);
 171 }
 172
 173 css::uno::Sequence<OUString> SAL_CALL iOSClipboard::getSupportedServiceNames()
 174 {
 175     return { OUString("com.sun.star.datatransfer.clipboard.SystemClipboard") };
 176 }
 177
 178 css::uno::Reference<css::uno::XInterface>
 179 IosSalInstance::CreateClipboard(const css::uno::Sequence<css::uno::Any>&)
 180 {
 181     return css::uno::Reference<css::uno::XInterface>(
 182         static_cast<cppu::OWeakObject*>(new iOSClipboard()));
 183 }
 184
 185 /* vim:set shiftwidth=4 softtabstop=4 expandtab: */