slideshow/opengl/glitterVertexShader.glsl

   1 /* -*- Mode: C; tab-width: 4; indent-tabs-mode: nil; c-basic-offset: 4 -*- */
   2 /*
   3  * This file is part of the LibreOffice project.
   4  *
   5  * This Source Code Form is subject to the terms of the Mozilla Public
   6  * License, v. 2.0. If a copy of the MPL was not distributed with this
   7  * file, You can obtain one at http://mozilla.org/MPL/2.0/.
   8  */
   9
  10 #version 120
  11
  12 #define M_PI 3.1415926535897932384626433832795
  13
  14 attribute vec3 a_position;
  15 attribute vec3 a_normal;
  16
  17 uniform mat4 u_projectionMatrix;
  18 uniform mat4 u_modelViewMatrix;
  19 uniform mat4 u_sceneTransformMatrix;
  20 uniform mat4 u_primitiveTransformMatrix;
  21 uniform mat4 u_operationsTransformMatrix;
  22
  23 varying vec2 v_texturePosition;
  24 varying vec3 v_normal;
  25
  26 attribute vec3 center;
  27 uniform float time;
  28 uniform ivec2 numTiles;
  29 uniform sampler2D permTexture;
  30 varying float angle;
  31
  32 #if __VERSION__ < 140
  33 mat4 inverse(mat4 m)
  34 {
  35     float a00 = m[0][0], a01 = m[0][1], a02 = m[0][2], a03 = m[0][3];
  36     float a10 = m[1][0], a11 = m[1][1], a12 = m[1][2], a13 = m[1][3];
  37     float a20 = m[2][0], a21 = m[2][1], a22 = m[2][2], a23 = m[2][3];
  38     float a30 = m[3][0], a31 = m[3][1], a32 = m[3][2], a33 = m[3][3];
  39
  40     float b00 = a00 * a11 - a01 * a10;
  41     float b01 = a00 * a12 - a02 * a10;
  42     float b02 = a00 * a13 - a03 * a10;
  43     float b03 = a01 * a12 - a02 * a11;
  44     float b04 = a01 * a13 - a03 * a11;
  45     float b05 = a02 * a13 - a03 * a12;
  46     float b06 = a20 * a31 - a21 * a30;
  47     float b07 = a20 * a32 - a22 * a30;
  48     float b08 = a20 * a33 - a23 * a30;
  49     float b09 = a21 * a32 - a22 * a31;
  50     float b10 = a21 * a33 - a23 * a31;
  51     float b11 = a22 * a33 - a23 * a32;
  52
  53     float det = b00 * b11 - b01 * b10 + b02 * b09 + b03 * b08 - b04 * b07 + b05 * b06;
  54
  55     return mat4(
  56         a11 * b11 - a12 * b10 + a13 * b09,
  57         a02 * b10 - a01 * b11 - a03 * b09,
  58         a31 * b05 - a32 * b04 + a33 * b03,
  59         a22 * b04 - a21 * b05 - a23 * b03,
  60         a12 * b08 - a10 * b11 - a13 * b07,
  61         a00 * b11 - a02 * b08 + a03 * b07,
  62         a32 * b02 - a30 * b05 - a33 * b01,
  63         a20 * b05 - a22 * b02 + a23 * b01,
  64         a10 * b10 - a11 * b08 + a13 * b06,
  65         a01 * b08 - a00 * b10 - a03 * b06,
  66         a30 * b04 - a31 * b02 + a33 * b00,
  67         a21 * b02 - a20 * b04 - a23 * b00,
  68         a11 * b07 - a10 * b09 - a12 * b06,
  69         a00 * b09 - a01 * b07 + a02 * b06,
  70         a31 * b01 - a30 * b03 - a32 * b00,
  71         a20 * b03 - a21 * b01 + a22 * b00) / det;
  72 }
  73 #endif
  74
  75 float snoise(vec2 p)
  76 {
  77     return texture2D(permTexture, p).r;
  78 }
  79
  80 mat4 translationMatrix(vec3 axis)
  81 {
  82     return mat4(1.0,    0.0,    0.0,    0.0,
  83                 0.0,    1.0,    0.0,    0.0,
  84                 0.0,    0.0,    1.0,    0.0,
  85                 axis.x, axis.y, axis.z, 1.0);
  86 }
  87
  88 mat4 rotationMatrix(vec3 axis, float angle)
  89 {
  90     axis = normalize(axis);
  91     float s = sin(angle);
  92     float c = cos(angle);
  93     float oc = 1.0 - c;
  94
  95     return mat4(oc * axis.x * axis.x + c,           oc * axis.x * axis.y - axis.z * s,  oc * axis.z * axis.x + axis.y * s,  0.0,
  96                 oc * axis.x * axis.y + axis.z * s,  oc * axis.y * axis.y + c,           oc * axis.y * axis.z - axis.x * s,  0.0,
  97                 oc * axis.z * axis.x - axis.y * s,  oc * axis.y * axis.z + axis.x * s,  oc * axis.z * axis.z + c,           0.0,
  98                 0.0,                                0.0,                                0.0,                                1.0);
  99 }
 100
 101 void main( void )
 102 {
 103     vec2 pos = (center.xy + 1.0) / 2.0;
 104
 105     // 0..1 pseudo-random value used to randomize the tile’s start time.
 106     float fuzz = snoise(pos);
 107
 108     float startTime = pos.x * 0.5 + fuzz * 0.25;
 109     float endTime = startTime + 0.25;
 110
 111     // Scale the transition time to minimize the time a tile will stay black.
 112     float transitionTime = clamp((time - startTime) / (endTime - startTime), 0.0, 1.0);
 113     if (transitionTime < 0.5)
 114         transitionTime = transitionTime / 2.0;
 115     else
 116         transitionTime = (transitionTime / 2.0) + 0.5;
 117     angle = transitionTime * M_PI * 2.0;
 118
 119     mat4 modelViewMatrix = u_modelViewMatrix * u_operationsTransformMatrix * u_sceneTransformMatrix * u_primitiveTransformMatrix;
 120     mat4 transformMatrix = translationMatrix(center) * rotationMatrix(vec3(0.0, 1.0, 0.0), angle) * translationMatrix(-center);
 121
 122     mat3 normalMatrix = mat3(transpose(inverse(transformMatrix)));
 123     gl_Position = u_projectionMatrix * modelViewMatrix * transformMatrix * vec4(a_position, 1.0);
 124     v_texturePosition = vec2((a_position.x + 1.0) / 2.0, (1.0 - a_position.y) / 2.0);
 125     v_normal = normalize(normalMatrix * a_normal);
 126 }
 127
 128 /* vim:set shiftwidth=4 softtabstop=4 expandtab: */