slideshow/opengl/rippleFragmentShader.glsl

   1 /* -*- Mode: C; tab-width: 4; indent-tabs-mode: nil; c-basic-offset: 4 -*- */
   2 /*
   3  * This file is part of the LibreOffice project.
   4  *
   5  * This Source Code Form is subject to the terms of the Mozilla Public
   6  * License, v. 2.0. If a copy of the MPL was not distributed with this
   7  * file, You can obtain one at http://mozilla.org/MPL/2.0/.
   8  */
   9
  10 #version 120
  11
  12 #define M_PI 3.1415926535897932384626433832795
  13
  14 uniform sampler2D leavingSlideTexture;
  15 uniform sampler2D enteringSlideTexture;
  16 uniform float time;
  17 uniform vec2 center;
  18 uniform float slideRatio;
  19
  20 varying vec2 v_texturePosition;
  21
  22 // This function returns the distance between two points, taking into account the slide ratio.
  23 float betterDistance(vec2 p1, vec2 p2)
  24 {
  25     p1.x *= slideRatio;
  26     p2.x *= slideRatio;
  27     return distance(p1, p2);
  28 }
  29
  30 void main()
  31 {
  32     const float w = 0.5;
  33     const float v = 0.1;
  34
  35     // Distance from this fragment to the center, in slide coordinates.
  36     float dist = betterDistance(center, v_texturePosition);
  37
  38     // We want the ripple to span all of the slide at the end of the transition.
  39     float t = time * (sqrt(2.0) * (slideRatio < 1.0 ? 1.0 / slideRatio : slideRatio));
  40
  41     // Interpolate the distance to the center in function of the time.
  42     float mixed = smoothstep(t*w-v, t*w+v, dist);
  43
  44     // Get the displacement offset from the current pixel, for fragments that have been touched by the ripple already.
  45     vec2 offset = (v_texturePosition - center) * (sin(dist * 64.0 - time * 16.0) + 0.5) / 32.0;
  46     vec2 wavyTexCoord = mix(v_texturePosition + offset, v_texturePosition, time);
  47
  48     // Get the final position we will sample from.
  49     vec2 pos = mix(wavyTexCoord, v_texturePosition, mixed);
  50
  51     // Sample from the textures and mix that together.
  52     vec4 leaving = texture2D(leavingSlideTexture, pos);
  53     vec4 entering = texture2D(enteringSlideTexture, pos);
  54     gl_FragColor = mix(entering, leaving, mixed);
  55 }
  56
  57 /* vim:set shiftwidth=4 softtabstop=4 expandtab: */