avmedia/source/macavf/framegrabber.mm

   1 /* -*- Mode: C++; tab-width: 4; indent-tabs-mode: nil; c-basic-offset: 4 -*- */
   2 /*
   3  * This file is part of the LibreOffice project.
   4  *
   5  * This Source Code Form is subject to the terms of the Mozilla Public
   6  * License, v. 2.0. If a copy of the MPL was not distributed with this
   7  * file, You can obtain one at http://mozilla.org/MPL/2.0/.
   8  *
   9  * This file incorporates work covered by the following license notice:
  10  *
  11  *   Licensed to the Apache Software Foundation (ASF) under one or more
  12  *   contributor license agreements. See the NOTICE file distributed
  13  *   with this work for additional information regarding copyright
  14  *   ownership. The ASF licenses this file to you under the Apache
  15  *   License, Version 2.0 (the "License"); you may not use this file
  16  *   except in compliance with the License. You may obtain a copy of
  17  *   the License at http://www.apache.org/licenses/LICENSE-2.0 .
  18  */
  19
  20 #include "framegrabber.hxx"
  21 #include "player.hxx"
  22
  23 #include <tools/stream.hxx>
  24 #include <vcl/graph.hxx>
  25 #include <vcl/cvtgrf.hxx>
  26 #include <unotools/localfilehelper.hxx>
  27
  28 using namespace ::com::sun::star;
  29
  30 namespace avmedia { namespace macavf {
  31
  32 // ----------------
  33 // - FrameGrabber -
  34 // ----------------
  35
  36 FrameGrabber::FrameGrabber( const uno::Reference< lang::XMultiServiceFactory >& /*rxMgr*/ )
  37 :   mpImageGen( NULL )
  38 {}
  39
  40 // ------------------------------------------------------------------------------
  41
  42 FrameGrabber::~FrameGrabber()
  43 {
  44     if( mpImageGen )
  45         CFRelease( mpImageGen );
  46 }
  47
  48 // ------------------------------------------------------------------------------
  49
  50 bool FrameGrabber::create( const ::rtl::OUString& rURL )
  51 {
  52     NSString* pNSStr = [NSString stringWithCharacters:rURL.getStr() length:rURL.getLength()];
  53     NSURL* pNSURL = [NSURL URLWithString: [pNSStr stringByAddingPercentEscapesUsingEncoding:NSUTF8StringEncoding]];
  54     AVAsset* pMovie = [AVURLAsset URLAssetWithURL:pNSURL options:nil];
  55     if( !pMovie )
  56     {
  57         OSL_TRACE( "AVGrabber::create() cannot load url=\"%s\"", [pNSStr UTF8String] );
  58         return false;
  59     }
  60
  61     return create( pMovie );
  62 }
  63
  64 // ------------------------------------------------------------------------------
  65
  66 bool FrameGrabber::create( AVAsset* pMovie )
  67 {
  68     if( [[pMovie tracksWithMediaType:AVMediaTypeVideo] count] == 0)
  69     {
  70         OSL_TRACE( "AVGrabber::create() found no video content!" );
  71         return false;
  72     }
  73
  74     mpImageGen = [AVAssetImageGenerator assetImageGeneratorWithAsset:pMovie];
  75     CFRetain( mpImageGen );
  76     return true;
  77 }
  78
  79 // ------------------------------------------------------------------------------
  80
  81 uno::Reference< graphic::XGraphic > SAL_CALL FrameGrabber::grabFrame( double fMediaTime )
  82     throw (uno::RuntimeException)
  83 {
  84     uno::Reference< graphic::XGraphic > xRet;
  85     if( !mpImageGen )
  86         return xRet;
  87     OSL_TRACE( "AVPlayer::grabFrame( %.3fsec)", fMediaTime );
  88
  89     // get the requested image from the movie
  90     CGImage* pCGImage = [mpImageGen copyCGImageAtTime:CMTimeMakeWithSeconds(fMediaTime,1000) actualTime:NULL error:NULL];
  91
  92     // convert the image to a TIFF-formatted byte-array
  93     CFMutableDataRef pCFData = CFDataCreateMutable( kCFAllocatorDefault, 0 );
  94     CGImageDestination* pCGImgDest = CGImageDestinationCreateWithData( pCFData, kUTTypeTIFF, 1, 0 );
  95     CGImageDestinationAddImage( pCGImgDest, pCGImage, NULL );
  96     CGImageDestinationFinalize( pCGImgDest );
  97     CFRelease( pCGImgDest );
  98     const long nBitmapLen = CFDataGetLength( pCFData );
  99     void* pBitmapBytes = (void*)CFDataGetBytePtr( pCFData );
 100
 101     // convert the image into the return-value type which is a graphic::XGraphic
 102     SvMemoryStream aMemStm( pBitmapBytes, nBitmapLen, StreamMode::READ | StreamMode::WRITE );
 103     Graphic aGraphic;
 104     if( GraphicConverter::Import( aMemStm, aGraphic, CVT_TIF ) == ERRCODE_NONE )
 105         xRet = aGraphic.GetXGraphic();
 106
 107     // clean up resources
 108     CFRelease( pCFData );
 109     return xRet;
 110 }
 111
 112 // ------------------------------------------------------------------------------
 113
 114 ::rtl::OUString SAL_CALL FrameGrabber::getImplementationName(  )
 115     throw (uno::RuntimeException)
 116 {
 117     return ::rtl::OUString( RTL_CONSTASCII_USTRINGPARAM( AVMEDIA_MACAVF_FRAMEGRABBER_IMPLEMENTATIONNAME ) );
 118 }
 119
 120 // ------------------------------------------------------------------------------
 121
 122 sal_Bool SAL_CALL FrameGrabber::supportsService( const ::rtl::OUString& ServiceName )
 123     throw (uno::RuntimeException)
 124 {
 125     return ServiceName.equalsAsciiL( RTL_CONSTASCII_STRINGPARAM ( AVMEDIA_MACAVF_FRAMEGRABBER_SERVICENAME ) );
 126 }
 127
 128 // ------------------------------------------------------------------------------
 129
 130 uno::Sequence< ::rtl::OUString > SAL_CALL FrameGrabber::getSupportedServiceNames(  )
 131     throw (uno::RuntimeException)
 132 {
 133     uno::Sequence< ::rtl::OUString > aRet(1);
 134     aRet[0] = ::rtl::OUString( RTL_CONSTASCII_USTRINGPARAM ( AVMEDIA_MACAVF_FRAMEGRABBER_SERVICENAME ) );
 135
 136     return aRet;
 137 }
 138
 139 } // namespace macavf
 140 } // namespace avmedia
 141
 142 /* vim:set shiftwidth=4 softtabstop=4 expandtab: */