chart2/opengl/shape3DFragmentShader.glsl

   1 /* -*- Mode: C++; tab-width: 4; indent-tabs-mode: nil; c-basic-offset: 4 -*- */
   2 /*
   3  * This file is part of the LibreOffice project.
   4  *
   5  * This Source Code Form is subject to the terms of the Mozilla Public
   6  * License, v. 2.0. If a copy of the MPL was not distributed with this
   7  * file, You can obtain one at http://mozilla.org/MPL/2.0/.
   8  */
   9
  10 #version 330 core
  11 #define MAX_LIGHT_NUM 8
  12
  13 in vec3 positionWorldspace;
  14 in vec3 normalCameraspace;
  15 uniform mat4 V;
  16 out vec4 actualColor;
  17 struct MaterialParameters
  18 {
  19     vec4 ambient;
  20     vec4 diffuse;
  21     vec4 specular;
  22     vec4 materialColor;
  23
  24     int twoSidesLighting;
  25     float shininess;
  26     float pad;
  27     float pad1;
  28 };
  29
  30 layout(std140) uniform GlobalMaterialParameters
  31 {
  32     MaterialParameters matralParameter;
  33 }Material;
  34
  35 struct LightSource
  36 {
  37     vec4   lightColor;
  38     vec4   positionWorldspace;
  39     float  lightPower;
  40     float  pad1;
  41     float  pad2;
  42     float  pad3;
  43 };
  44
  45 layout(std140) uniform GlobalLights
  46 {
  47     int         lightNum;
  48     vec4        ambient;
  49     LightSource light[MAX_LIGHT_NUM];
  50 } Lights;
  51
  52 void main()
  53 {
  54     vec3 colorTotal = vec3(0.0f, 0.0f, 0.0f);
  55
  56     vec3 vertexPositionCameraspace = (V * vec4(positionWorldspace,1)).xyz;
  57
  58     vec3 MaterialDiffuseColor = Material.matralParameter.materialColor.rgb;
  59
  60     vec3 normalDirectionCameraspace = normalCameraspace;
  61     vec3 eyeDirectionCameraspace = normalize(vec3(0, 0, 0) - vertexPositionCameraspace);
  62     float attenuation = 1.0;
  63     int i = 0;
  64     vec3 lightDirectionCameraspace;
  65     vec3 vertexToLightSource;
  66
  67     vec3 lightAmbient = Lights.ambient.rgb *
  68                         MaterialDiffuseColor *
  69                         Material.matralParameter.ambient.rgb
  70                         * 5.0;
  71
  72     if ((Material.matralParameter.twoSidesLighting == 1) && (!gl_FrontFacing))
  73     {
  74         normalDirectionCameraspace = -normalDirectionCameraspace;
  75     }
  76     for (i = 0; i < Lights.lightNum; i++)
  77     {
  78         float  LightPower = Lights.light[i].lightPower;
  79         lightDirectionCameraspace = normalize((V * Lights.light[i].positionWorldspace).xyz);
  80
  81         float cosTheta = clamp(dot(normalDirectionCameraspace,lightDirectionCameraspace), 0,1);
  82         vec3 lightDiffuse = LightPower *
  83                             attenuation *
  84                             Lights.light[i].lightColor.rgb *
  85                             MaterialDiffuseColor *
  86                             Material.matralParameter.diffuse.rgb *
  87                             cosTheta;
  88
  89         vec3 specularReflection;
  90         if (dot(normalDirectionCameraspace, lightDirectionCameraspace) < 0)
  91         {
  92             specularReflection = vec3(0.0, 0.0, 0.0);
  93         }
  94         else
  95         {
  96             vec3 R = reflect(-lightDirectionCameraspace,normalDirectionCameraspace);
  97             float cosAlpha = clamp(dot(eyeDirectionCameraspace, R), 0,1);
  98             specularReflection = attenuation *
  99                                  LightPower *
 100                                  Lights.light[i].lightColor.rgb *
 101                                  Material.matralParameter.specular.rgb *
 102                                  MaterialDiffuseColor *
 103                                  pow(max(0.0, cosAlpha), Material.matralParameter.shininess);
 104         }
 105         colorTotal += lightDiffuse + specularReflection;
 106
 107     }
 108     colorTotal += lightAmbient;
 109     actualColor = vec4(colorTotal, 1.0);
 110 }
 111
 112 /* vim:set shiftwidth=4 softtabstop=4 expandtab: */