chart2/opengl/shape3DFragmentShaderBatch.glsl

   1 /* -*- Mode: C++; tab-width: 4; indent-tabs-mode: nil; c-basic-offset: 4 -*- */
   2 /*
   3  * This file is part of the LibreOffice project.
   4  *
   5  * This Source Code Form is subject to the terms of the Mozilla Public
   6  * License, v. 2.0. If a copy of the MPL was not distributed with this
   7  * file, You can obtain one at http://mozilla.org/MPL/2.0/.
   8  */
   9
  10 #version 330 core
  11 #define MAX_LIGHT_NUM 8
  12
  13 in vec3 positionWorldspace;
  14 in vec3 normalCameraspace;
  15 in vec4 fragBarColor;
  16 uniform mat4 V;
  17 out vec4 actualColor;
  18 struct MaterialParameters
  19 {
  20     vec4 ambient;
  21     vec4 diffuse;
  22     vec4 specular;
  23     vec4 materialColor;
  24
  25     int twoSidesLighting;
  26     float shininess;
  27     float pad;
  28     float pad1;
  29 };
  30
  31 layout(std140) uniform GlobalMaterialParameters
  32 {
  33     MaterialParameters matralParameter;
  34 }Material;
  35
  36 struct LightSource
  37 {
  38     vec4   lightColor;
  39     vec4   positionWorldspace;
  40     float  lightPower;
  41     float  pad1;
  42     float  pad2;
  43     float  pad3;
  44 };
  45
  46 layout(std140) uniform GlobalLights
  47 {
  48     int         lightNum;
  49     vec4        ambient;
  50     LightSource light[MAX_LIGHT_NUM];
  51 } Lights;
  52
  53 void main()
  54 {
  55     vec3 colorTotal = vec3(0.0f, 0.0f, 0.0f);
  56
  57     vec3 vertexPositionCameraspace = (V * vec4(positionWorldspace,1)).xyz;
  58
  59     vec3 MaterialDiffuseColor = fragBarColor.rgb;
  60
  61     vec3 normalDirectionCameraspace = normalCameraspace;
  62     vec3 eyeDirectionCameraspace = normalize(vec3(0, 0, 0) - vertexPositionCameraspace);
  63     float attenuation = 1.0;
  64     int i = 0;
  65     vec3 lightDirectionCameraspace;
  66     vec3 vertexToLightSource;
  67
  68     vec3 lightAmbient = Lights.ambient.rgb *
  69                         MaterialDiffuseColor *
  70                         Material.matralParameter.ambient.rgb;
  71
  72     for (i = 0; i < Lights.lightNum; i++)
  73     {
  74         float  LightPower = Lights.light[i].lightPower;
  75         lightDirectionCameraspace = normalize((V * Lights.light[i].positionWorldspace).xyz);
  76
  77         float cosTheta = clamp(dot(normalDirectionCameraspace,lightDirectionCameraspace), 0,1);
  78         vec3 lightDiffuse = LightPower *
  79                             attenuation *
  80                             Lights.light[i].lightColor.rgb *
  81                             MaterialDiffuseColor *
  82                             Material.matralParameter.diffuse.rgb *
  83                             cosTheta;
  84
  85         vec3 specularReflection;
  86         if (dot(normalDirectionCameraspace, lightDirectionCameraspace) < 0)
  87         {
  88             specularReflection = vec3(0.0, 0.0, 0.0);
  89         }
  90         else
  91         {
  92             vec3 R = reflect(-lightDirectionCameraspace,normalDirectionCameraspace);
  93             float cosAlpha = clamp(dot(eyeDirectionCameraspace, R), 0,1);
  94             specularReflection = attenuation *
  95                                  LightPower *
  96                                  Lights.light[i].lightColor.rgb *
  97                                  Material.matralParameter.specular.rgb *
  98                                  MaterialDiffuseColor *
  99                                  pow(max(0.0, cosAlpha), Material.matralParameter.shininess);
 100         }
 101         colorTotal += lightDiffuse + specularReflection;
 102
 103     }
 104     colorTotal += lightAmbient;
 105     actualColor = vec4(colorTotal, 1.0);
 106 }
 107
 108 /* vim:set shiftwidth=4 softtabstop=4 expandtab: */