chart2/opengl/shape3DFragmentShaderBatchScroll.glsl

   1 /* -*- Mode: C++; tab-width: 4; indent-tabs-mode: nil; c-basic-offset: 4 -*- */
   2 /*
   3  * This file is part of the LibreOffice project.
   4  *
   5  * This Source Code Form is subject to the terms of the Mozilla Public
   6  * License, v. 2.0. If a copy of the MPL was not distributed with this
   7  * file, You can obtain one at http://mozilla.org/MPL/2.0/.
   8  */
   9
  10 #version 330 core
  11 #define MAX_LIGHT_NUM 8
  12
  13 in vec3 positionWorldspace;
  14 in vec3 normalCameraspace;
  15 in vec4 fragBarColor;
  16 uniform mat4 V;
  17 uniform int undraw;
  18 uniform float minCoordX;
  19 out vec4 actualColor;
  20 struct MaterialParameters
  21 {
  22     vec4 ambient;
  23     vec4 diffuse;
  24     vec4 specular;
  25     vec4 materialColor;
  26
  27     int twoSidesLighting;
  28     float shininess;
  29     float pad;
  30     float pad1;
  31 };
  32
  33 layout(std140) uniform GlobalMaterialParameters
  34 {
  35     MaterialParameters matralParameter;
  36 }Material;
  37
  38 struct LightSource
  39 {
  40     vec4   lightColor;
  41     vec4   positionWorldspace;
  42     float  lightPower;
  43     float  pad1;
  44     float  pad2;
  45     float  pad3;
  46 };
  47
  48 layout(std140) uniform GlobalLights
  49 {
  50     int         lightNum;
  51     vec4        ambient;
  52     LightSource light[MAX_LIGHT_NUM];
  53 } Lights;
  54
  55 void main()
  56 {
  57         if ((positionWorldspace.x <= minCoordX) && (undraw == 1))
  58                 discard;
  59     vec3 colorTotal = vec3(0.0f, 0.0f, 0.0f);
  60
  61     vec3 vertexPositionCameraspace = (V * vec4(positionWorldspace,1)).xyz;
  62
  63     vec3 MaterialDiffuseColor = fragBarColor.rgb;
  64
  65     vec3 normalDirectionCameraspace = normalCameraspace;
  66     vec3 eyeDirectionCameraspace = normalize(vec3(0, 0, 0) - vertexPositionCameraspace);
  67     float attenuation = 1.0;
  68     int i = 0;
  69     vec3 lightDirectionCameraspace;
  70     vec3 vertexToLightSource;
  71
  72     vec3 lightAmbient = Lights.ambient.rgb *
  73                         MaterialDiffuseColor *
  74                         Material.matralParameter.ambient.rgb;
  75
  76     for (i = 0; i < Lights.lightNum; i++)
  77     {
  78         float  LightPower = Lights.light[i].lightPower;
  79         lightDirectionCameraspace = normalize((V * Lights.light[i].positionWorldspace).xyz);
  80
  81         float cosTheta = clamp(dot(normalDirectionCameraspace,lightDirectionCameraspace), 0,1);
  82         vec3 lightDiffuse = LightPower *
  83                             attenuation *
  84                             Lights.light[i].lightColor.rgb *
  85                             MaterialDiffuseColor *
  86                             Material.matralParameter.diffuse.rgb *
  87                             cosTheta;
  88
  89         vec3 specularReflection;
  90         if (dot(normalDirectionCameraspace, lightDirectionCameraspace) < 0)
  91         {
  92             specularReflection = vec3(0.0, 0.0, 0.0);
  93         }
  94         else
  95         {
  96             vec3 R = reflect(-lightDirectionCameraspace,normalDirectionCameraspace);
  97             float cosAlpha = clamp(dot(eyeDirectionCameraspace, R), 0,1);
  98             specularReflection = attenuation *
  99                                  LightPower *
 100                                  Lights.light[i].lightColor.rgb *
 101                                  Material.matralParameter.specular.rgb *
 102                                  MaterialDiffuseColor *
 103                                  pow(max(0.0, cosAlpha), Material.matralParameter.shininess);
 104         }
 105         colorTotal += lightDiffuse + specularReflection;
 106
 107     }
 108     colorTotal += lightAmbient;
 109     actualColor = vec4(colorTotal, 1.0);
 110 }
 111
 112 /* vim:set shiftwidth=4 softtabstop=4 expandtab: */