l10ntools/source/cfglex.l

   1 %{
   2 /*
   3  * This file is part of the LibreOffice project.
   4  *
   5  * This Source Code Form is subject to the terms of the Mozilla Public
   6  * License, v. 2.0. If a copy of the MPL was not distributed with this
   7  * file, You can obtain one at http://mozilla.org/MPL/2.0/.
   8  *
   9  * This file incorporates work covered by the following license notice:
  10  *
  11  *   Licensed to the Apache Software Foundation (ASF) under one or more
  12  *   contributor license agreements. See the NOTICE file distributed
  13  *   with this work for additional information regarding copyright
  14  *   ownership. The ASF licenses this file to you under the Apache
  15  *   License, Version 2.0 (the "License"); you may not use this file
  16  *   except in compliance with the License. You may obtain a copy of
  17  *   the License at http://www.apache.org/licenses/LICENSE-2.0 .
  18  */
  19
  20 /*
  21  * lexer for parsing cfg source files
  22  */
  23
  24 #include "sal/config.h"
  25
  26 /* enlarge token buffer to tokenize whole strings */
  27 #undef YYLMAX
  28 #define YYLMAX 64000
  29
  30 /* to enable debug output define LEXDEBUG */
  31 #define LEXDEBUG                1
  32 #ifdef LEXDEBUG
  33 #define OUTPUT  fprintf
  34 #else
  35 #define OUTPUT(Par1,Par2);
  36 #endif
  37
  38 /* table of possible token ids */
  39 #include "tokens.h"
  40 #include <stdlib.h>
  41 #include <stdio.h>
  42
  43 #include "sal/main.h"
  44
  45 #include "cfglex.hxx"
  46
  47 #if __GNUC__
  48 #pragma GCC diagnostic ignored "-Wunused-function"
  49 #pragma GCC diagnostic ignored "-Wunused-label"
  50 #pragma GCC diagnostic ignored "-Wunused-but-set-variable"
  51 #elif defined _MSC_VER
  52 #pragma warning(push, 1)
  53 #endif
  54 #define YY_NO_UNISTD_H
  55
  56 int yycolumn = 1;
  57 #define YY_USER_ACTION yycolumn += yyleng;
  58
  59 int bText=0;
  60 %}
  61
  62 %option yylineno
  63 %option never-interactive
  64
  65 %p 24000
  66 %e 1200
  67 %n 500
  68
  69 %%
  70
  71 \<[^\>]*"xml:lang="\""x-no-translate"\"[^\<]*\/\>       {
  72         bText = 0;
  73         workOnTokenSet( CFG_TOKEN_NO_TRANSLATE, yytext );
  74 }
  75
  76 \<.*\/\> {
  77         bText = 0;
  78         workOnTokenSet( ANYTOKEN, yytext );
  79 }
  80
  81 \<[^\>]*"xml:lang="\".*\"[^\<]*\>       {
  82         bText = 1;
  83         workOnTokenSet( CFG_TEXT_START, yytext );
  84 }
  85
  86
  87 \<[^\/\!][^\>]*\>       {
  88         bText = 0;
  89         workOnTokenSet( CFG_TAG, yytext );
  90 }
  91
  92 "<!"DOCTYPE[^\>]*\>     {
  93         bText = 0;
  94         workOnTokenSet( CFG_TAG, yytext );
  95 }
  96
  97
  98 \<\!\-\-        {
  99         char c1 = 0, c2 = 0;
 100         int c3 = yyinput();
 101         char pChar[2];
 102         pChar[1] = 0x00;
 103         pChar[0] = c3;
 104
 105         workOnTokenSet( COMMENT, yytext );
 106         workOnTokenSet( COMMENT, pChar );
 107
 108         for(;;) {
 109                 if ( c3 == EOF )
 110                         break;
 111                 if ( c1 == '-' && c2 == '-' && c3 == '>' )
 112                         break;
 113                 c1 = c2;
 114                 c2 = c3;
 115                 c3 = yyinput();
 116
 117                 pChar[0] = c3;
 118                 workOnTokenSet( COMMENT, pChar );
 119         }
 120 }
 121
 122 \<\/[^\>]*\> {
 123         bText = 0;
 124         workOnTokenSet( CFG_CLOSETAG, yytext );
 125 }
 126
 127 \<[^\>\!]*\> {
 128         bText = 0;
 129         if ( yytext[ 1 ] == '!' && yytext[ 2 ] == '-' && yytext[ 3 ] == '-' )
 130                 workOnTokenSet( COMMENT, yytext );
 131         else
 132                 workOnTokenSet( CFG_UNKNOWNTAG, yytext );
 133 }
 134
 135 .|\n {
 136     yycolumn = 1;
 137         if ( bText == 1 )
 138                 workOnTokenSet( CFG_TEXTCHAR, yytext );
 139         else
 140                 workOnTokenSet( UNKNOWNCHAR, yytext );
 141 }
 142
 143
 144 %%
 145
 146 /*****************************************************************************/
 147 int     yywrap(void)
 148 /*****************************************************************************/
 149 {
 150         return 1;
 151 }
 152
 153 /*****************************************************************************/
 154 void YYWarning( const char *s )
 155 /*****************************************************************************/
 156 {
 157         /* write warning to stderr */
 158         fprintf( stderr,
 159                 "Warning: \"%s\" in line %d, column %d: \"%s\"\n", s, yylineno, yycolumn, yytext  );
 160 }
 161
 162 /*****************************************************************************/
 163 void yyerror ( const char *s )
 164 /*****************************************************************************/
 165 {
 166         /* write error to stderr */
 167         fprintf( stderr,
 168                 "Error: \"%s\" in line %d, column %d: \"%s\"\n", s, yylineno, yycolumn, yytext  );
 169         exit(EXIT_FAILURE);
 170 }
 171
 172 SAL_IMPLEMENT_MAIN_WITH_ARGS(argc, argv) {
 173     yyin = init(argc, argv);
 174     yylex();
 175     return EXIT_SUCCESS;
 176 }