officecfg/registry/cppheader.xsl

   1 <?xml version="1.0" encoding="UTF-8"?>
   2 <!--
   3  * This file is part of the LibreOffice project.
   4  *
   5  * This Source Code Form is subject to the terms of the Mozilla Public
   6  * License, v. 2.0. If a copy of the MPL was not distributed with this
   7  * file, You can obtain one at http://mozilla.org/MPL/2.0/.
   8  *
   9 -->
  10
  11 <!-- Generate a .hxx file with type-safe C++ abstractions (based on
  12      comphelper/configuration.hxx) for all the <prop> and <set> elements in an
  13      .xcs file.
  14
  15      Takes up to three parameters ns1, ns2, ns3 that represent the .xcs file's
  16      nesting within the org/openoffice hierarchy (e.g., for
  17      officecfg/registry/schema/org/openoffice/Office/Common.xcs, ns1 would be
  18      "Office", ns2 would be "Common", and ns3 would remain unset.
  19
  20      TODO: Does not yet handle <node-ref> indirections (as, e.g., used in
  21      officecfg/registry/schema/org/openoffice/Office/Common.xcs as
  22      "ApplicationControlLayout").  Also, the available abstractions can still be
  23      improved (e.g., for extensible groups or for set element types).
  24 -->
  25
  26 <xsl:stylesheet
  27     version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  28      xmlns:oor="http://openoffice.org/2001/registry">
  29   <xsl:param name="ns1"/>
  30   <xsl:param name="ns2"/>
  31   <xsl:param name="ns3"/>
  32   <xsl:output method="text"/>
  33
  34   <xsl:template match="/oor:component-schema">
  35     <xsl:apply-templates select="component">
  36       <xsl:with-param name="path">
  37         <xsl:text>/</xsl:text>
  38         <xsl:value-of select="@oor:package"/>
  39         <xsl:text>.</xsl:text>
  40         <xsl:value-of select="@oor:name"/>
  41       </xsl:with-param>
  42     </xsl:apply-templates>
  43   </xsl:template>
  44
  45   <xsl:template match="component">
  46     <xsl:param name="path"/>
  47     <xsl:text>#ifndef INCLUDED_OFFICECFG_</xsl:text>
  48     <xsl:value-of
  49         select="translate($ns1, 'abcdefghijklmnopqrstuvwxyz', 'ABCDEFGHIJKLMNOPQRSTUVWXYZ')"/>
  50     <xsl:if test="$ns2">
  51       <xsl:text>_</xsl:text>
  52       <xsl:value-of
  53           select="translate($ns2, 'abcdefghijklmnopqrstuvwxyz', 'ABCDEFGHIJKLMNOPQRSTUVWXYZ')"/>
  54       <xsl:if test="$ns3">
  55         <xsl:text>_</xsl:text>
  56         <xsl:value-of
  57             select="translate($ns3, 'abcdefghijklmnopqrstuvwxyz', 'ABCDEFGHIJKLMNOPQRSTUVWXYZ')"/>
  58       </xsl:if>
  59     </xsl:if>
  60     <xsl:text>_HXX&#xA;</xsl:text>
  61     <xsl:text>#define INCLUDED_OFFICECFG_</xsl:text>
  62     <xsl:value-of
  63         select="translate($ns1, 'abcdefghijklmnopqrstuvwxyz', 'ABCDEFGHIJKLMNOPQRSTUVWXYZ')"/>
  64     <xsl:if test="$ns2">
  65       <xsl:text>_</xsl:text>
  66       <xsl:value-of
  67           select="translate($ns2, 'abcdefghijklmnopqrstuvwxyz', 'ABCDEFGHIJKLMNOPQRSTUVWXYZ')"/>
  68       <xsl:if test="$ns3">
  69         <xsl:text>_</xsl:text>
  70         <xsl:value-of
  71             select="translate($ns3, 'abcdefghijklmnopqrstuvwxyz', 'ABCDEFGHIJKLMNOPQRSTUVWXYZ')"/>
  72       </xsl:if>
  73     </xsl:if>
  74     <xsl:text>_HXX&#xA;</xsl:text>
  75     <xsl:text>&#xA;</xsl:text>
  76     <xsl:text>#include "sal/config.h"&#xA;</xsl:text>
  77     <xsl:text>&#xA;</xsl:text>
  78     <xsl:if test=".//prop or .//set">
  79       <xsl:if
  80           test=".//prop[count(@oor:nillable) = 0 or @oor:nillable = 'true']">
  81         <xsl:text>#include "boost/optional.hpp"&#xA;</xsl:text>
  82       </xsl:if>
  83       <xsl:if test=".//prop/@oor:type = 'oor:any'">
  84         <xsl:text>#include "com/sun/star/uno/Any.hxx"&#xA;</xsl:text>
  85       </xsl:if>
  86       <xsl:if test=".//prop/@oor:type = 'xs:hexBinary' or .//prop/@oor:type = 'oor:boolean-list' or .//prop/@oor:type = 'oor:short-list' or .//prop/@oor:type = 'oor:int-list' or .//prop/@oor:type = 'oor:long-list' or .//prop/@oor:type = 'oor:double-list' or .//prop/@oor:type = 'oor:string-list'">
  87         <xsl:text>#include "com/sun/star/uno/Sequence.hxx"&#xA;</xsl:text>
  88       </xsl:if>
  89       <xsl:text>#include "rtl/ustring.h"&#xA;</xsl:text>
  90       <xsl:text>#include "rtl/ustring.hxx"&#xA;</xsl:text>
  91       <xsl:if test=".//prop/@oor:type = 'xs:short' or .//prop/@oor:type = 'xs:int' or .//prop/@oor:type = 'xs:long' or .//prop/@oor:type = 'xs:hexBinary'">
  92         <xsl:text>#include "sal/types.h"&#xA;</xsl:text>
  93       </xsl:if>
  94       <xsl:text>#include "comphelper/configuration.hxx"&#xA;</xsl:text>
  95       <xsl:text>&#xA;</xsl:text>
  96       <xsl:text>namespace officecfg { namespace </xsl:text>
  97       <xsl:value-of select="$ns1"/>
  98       <xsl:if test="$ns2">
  99         <xsl:text> { namespace </xsl:text>
 100         <xsl:value-of select="$ns2"/>
 101         <xsl:if test="$ns3">
 102           <xsl:text> { namespace </xsl:text>
 103           <xsl:value-of select="$ns3"/>
 104         </xsl:if>
 105       </xsl:if>
 106       <xsl:text> {&#xA;</xsl:text>
 107       <xsl:text>&#xA;</xsl:text>
 108       <xsl:apply-templates select="group|set|prop">
 109         <xsl:with-param name="path" select="$path"/>
 110       </xsl:apply-templates>
 111       <xsl:if test="$ns2">
 112         <xsl:text>} </xsl:text>
 113         <xsl:if test="$ns3">
 114           <xsl:text>} </xsl:text>
 115         </xsl:if>
 116       </xsl:if>
 117       <xsl:text>} }&#xA;</xsl:text>
 118       <xsl:text>&#xA;</xsl:text>
 119     </xsl:if>
 120     <xsl:text>#endif&#xA;</xsl:text>
 121   </xsl:template>
 122
 123   <xsl:template match="group">
 124     <xsl:param name="path"/>
 125     <xsl:if test=".//prop or .//set">
 126       <xsl:variable name="name" select="translate(@oor:name, '-.', '__')"/>
 127       <xsl:text>struct </xsl:text>
 128       <xsl:value-of select="$name"/>
 129       <xsl:text>: public comphelper::ConfigurationGroup&lt; </xsl:text>
 130       <xsl:value-of select="$name"/>
 131       <xsl:text>&gt; {&#xA;</xsl:text>
 132       <xsl:text>    static rtl::OUString path() { return rtl::OUString(<!--
 133       -->"</xsl:text>
 134       <xsl:value-of select="$path"/>
 135       <xsl:text>/</xsl:text>
 136       <xsl:value-of select="@oor:name"/>
 137       <xsl:text>"); }&#xA;</xsl:text>
 138       <xsl:text>&#xA;</xsl:text>
 139       <xsl:apply-templates select="group|set|prop">
 140         <xsl:with-param name="path">
 141           <xsl:value-of select="$path"/>
 142           <xsl:text>/</xsl:text>
 143           <xsl:value-of select="@oor:name"/>
 144         </xsl:with-param>
 145       </xsl:apply-templates>
 146       <xsl:text>private:&#xA;</xsl:text>
 147       <xsl:text>    </xsl:text>
 148       <xsl:value-of select="$name"/>
 149       <xsl:text>(); // not defined&#xA;</xsl:text>
 150       <xsl:text>    ~</xsl:text>
 151       <xsl:value-of select="$name"/>
 152       <xsl:text>(); // not defined&#xA;</xsl:text>
 153       <xsl:text>};&#xA;</xsl:text>
 154       <xsl:text>&#xA;</xsl:text>
 155     </xsl:if>
 156   </xsl:template>
 157
 158   <xsl:template match="set">
 159     <xsl:param name="path"/>
 160     <xsl:variable name="name" select="translate(@oor:name, '-.', '__')"/>
 161     <xsl:text>struct </xsl:text>
 162     <xsl:value-of select="$name"/>
 163     <xsl:text>: public comphelper::ConfigurationSet&lt; </xsl:text>
 164     <xsl:value-of select="$name"/>
 165     <xsl:text>&gt; {&#xA;</xsl:text>
 166     <xsl:text>    static rtl::OUString path() { return rtl::OUString(<!--
 167     -->"</xsl:text>
 168     <xsl:value-of select="$path"/>
 169     <xsl:text>/</xsl:text>
 170     <xsl:value-of select="@oor:name"/>
 171     <xsl:text>"); }&#xA;</xsl:text>
 172     <xsl:text>private:&#xA;</xsl:text>
 173     <xsl:text>    </xsl:text>
 174     <xsl:value-of select="$name"/>
 175     <xsl:text>(); // not defined&#xA;</xsl:text>
 176     <xsl:text>    ~</xsl:text>
 177     <xsl:value-of select="$name"/>
 178     <xsl:text>(); // not defined&#xA;</xsl:text>
 179     <xsl:text>};&#xA;</xsl:text>
 180     <xsl:text>&#xA;</xsl:text>
 181   </xsl:template>
 182
 183   <xsl:template match="prop">
 184     <xsl:param name="path"/>
 185     <xsl:variable name="name" select="translate(@oor:name, '-.', '__')"/>
 186     <xsl:text>struct </xsl:text>
 187     <xsl:value-of select="$name"/>
 188     <xsl:text>: public comphelper::</xsl:text>
 189     <xsl:choose>
 190       <xsl:when test="@oor:localized = 'true'">
 191         <xsl:text>ConfigurationLocalizedProperty</xsl:text>
 192       </xsl:when>
 193       <xsl:otherwise>
 194         <xsl:text>ConfigurationProperty</xsl:text>
 195       </xsl:otherwise>
 196     </xsl:choose>
 197     <xsl:text>&lt;</xsl:text>
 198     <xsl:value-of select="$name"/>
 199     <xsl:text>, </xsl:text>
 200     <xsl:if test="not(@oor:nillable = 'false')">
 201       <xsl:text>boost::optional&lt;</xsl:text>
 202     </xsl:if>
 203     <xsl:choose>
 204       <xsl:when test="@oor:type='oor:any'">
 205         <xsl:text>com::sun::star::uno::Any</xsl:text>
 206       </xsl:when>
 207       <xsl:when test="@oor:type='xs:boolean'">
 208         <xsl:text>bool</xsl:text>
 209       </xsl:when>
 210       <xsl:when test="@oor:type='xs:short'">
 211         <xsl:text>sal_Int16</xsl:text>
 212       </xsl:when>
 213       <xsl:when test="@oor:type='xs:int'">
 214         <xsl:text>sal_Int32</xsl:text>
 215       </xsl:when>
 216       <xsl:when test="@oor:type='xs:long'">
 217         <xsl:text>sal_Int64</xsl:text>
 218       </xsl:when>
 219       <xsl:when test="@oor:type='xs:double'">
 220         <xsl:text>double</xsl:text>
 221       </xsl:when>
 222       <xsl:when test="@oor:type='xs:string'">
 223         <xsl:text>rtl::OUString</xsl:text>
 224       </xsl:when>
 225       <xsl:when test="@oor:type='xs:hexBinary'">
 226         <xsl:text>com::sun::star::uno::Sequence&lt;sal_Int8&gt; </xsl:text>
 227       </xsl:when>
 228       <xsl:when test="@oor:type='oor:boolean-list'">
 229         <xsl:text>com::sun::star::uno::Sequence&lt;bool&gt; </xsl:text>
 230       </xsl:when>
 231       <xsl:when test="@oor:type='oor:short-list'">
 232         <xsl:text>com::sun::star::uno::Sequence&lt;sal_Int16&gt; </xsl:text>
 233       </xsl:when>
 234       <xsl:when test="@oor:type='oor:int-list'">
 235         <xsl:text>com::sun::star::uno::Sequence&lt;sal_Int32&gt; </xsl:text>
 236       </xsl:when>
 237       <xsl:when test="@oor:type='oor:long-list'">
 238         <xsl:text>com::sun::star::uno::Sequence&lt;sal_Int64&gt; </xsl:text>
 239       </xsl:when>
 240       <xsl:when test="@oor:type='oor:double-list'">
 241         <xsl:text>com::sun::star::uno::Sequence&lt;double&gt; </xsl:text>
 242       </xsl:when>
 243       <xsl:when test="@oor:type='oor:string-list'">
 244         <xsl:text>com::sun::star::uno::Sequence&lt;rtl::OUString&gt; </xsl:text>
 245       </xsl:when>
 246       <xsl:when test="@oor:type='oor:hexBinary-list'">
 247         <xsl:text>com::sun::star::uno::Sequence&lt;<!--
 248         -->com::sun::star::uno::Sequence&lt;sal_Int8&gt; &gt; </xsl:text>
 249       </xsl:when>
 250     </xsl:choose>
 251     <xsl:if test="not(@oor:nillable = 'false')">
 252       <xsl:text>&gt; </xsl:text>
 253     </xsl:if>
 254     <xsl:text>&gt; {&#xA;</xsl:text>
 255     <xsl:text>    static rtl::OUString path() { return rtl::OUString(<!--
 256     -->"</xsl:text>
 257     <xsl:value-of select="$path"/>
 258     <xsl:text>/</xsl:text>
 259     <xsl:value-of select="@oor:name"/>
 260     <xsl:text>"); }&#xA;</xsl:text>
 261     <xsl:text>private:&#xA;</xsl:text>
 262     <xsl:text>    </xsl:text>
 263     <xsl:value-of select="$name"/>
 264     <xsl:text>(); // not defined&#xA;</xsl:text>
 265     <xsl:text>    ~</xsl:text>
 266     <xsl:value-of select="$name"/>
 267     <xsl:text>(); // not defined&#xA;</xsl:text>
 268     <xsl:text>};&#xA;</xsl:text>
 269     <xsl:text>&#xA;</xsl:text>
 270   </xsl:template>
 271 </xsl:stylesheet>