vcl/osx/a11ywrappercombobox.mm

   1 /* -*- Mode: C++; tab-width: 4; indent-tabs-mode: nil; c-basic-offset: 4 -*- */
   2 /*
   3  * This file is part of the LibreOffice project.
   4  *
   5  * This Source Code Form is subject to the terms of the Mozilla Public
   6  * License, v. 2.0. If a copy of the MPL was not distributed with this
   7  * file, You can obtain one at http://mozilla.org/MPL/2.0/.
   8  *
   9  * This file incorporates work covered by the following license notice:
  10  *
  11  *   Licensed to the Apache Software Foundation (ASF) under one or more
  12  *   contributor license agreements. See the NOTICE file distributed
  13  *   with this work for additional information regarding copyright
  14  *   ownership. The ASF licenses this file to you under the Apache
  15  *   License, Version 2.0 (the "License"); you may not use this file
  16  *   except in compliance with the License. You may obtain a copy of
  17  *   the License at http://www.apache.org/licenses/LICENSE-2.0 .
  18  */
  19
  20
  21 #include <vcl/svapp.hxx>
  22 #include <osx/salinst.h>
  23
  24 #include "a11ywrappercombobox.h"
  25 #include "a11yrolehelper.h"
  26
  27 #include <com/sun/star/accessibility/AccessibleStateType.hpp>
  28
  29 using namespace ::com::sun::star::accessibility;
  30 using namespace ::com::sun::star::uno;
  31
  32 // Wrapper for AXCombobox role
  33
  34 @implementation AquaA11yWrapperComboBox : AquaA11yWrapper
  35
  36 #pragma mark -
  37 #pragma mark Specialized Init Method
  38
  39 -(id)initWithAccessibleContext: (Reference < XAccessibleContext >) rxAccessibleContext {
  40     self = [ super initWithAccessibleContext: rxAccessibleContext ];
  41     if ( self != nil )
  42     {
  43         textArea = nil;
  44     }
  45     return self;
  46 }
  47
  48 #pragma mark -
  49 #pragma mark Private Helper Method
  50
  51 -(AquaA11yWrapper *)textArea {
  52     // FIXME: May cause problems when stored. Then get dynamically each time (bad performance!)
  53     if ( textArea == nil ) {
  54         NSAutoreleasePool * pool = [ [ NSAutoreleasePool alloc ] init ];
  55         NSArray * elementChildren = [ super childrenAttribute ];
  56         if ( [ elementChildren count ] > 0 ) {
  57             NSEnumerator * enumerator = [ elementChildren objectEnumerator ];
  58             id child;
  59             while ( ( child = [ enumerator nextObject ] ) ) {
  60                 AquaA11yWrapper * element = static_cast<AquaA11yWrapper *>(child);
  61                 if ( [ [ AquaA11yRoleHelper getNativeRoleFrom: [ element accessibleContext ] ] isEqualToString: NSAccessibilityTextAreaRole ] ) {
  62                     textArea = element;
  63                     break;
  64                 }
  65             }
  66         }
  67         [ pool release ];
  68     }
  69     return textArea;
  70 }
  71
  72 #pragma mark -
  73 #pragma mark Wrapped Attributes From Contained Text Area
  74
  75 -(id)valueAttribute {
  76     if ( [ self textArea ] != nil ) {
  77         return [ [ self textArea ] valueAttribute ];
  78     }
  79     return @"";
  80 }
  81
  82 -(id)numberOfCharactersAttribute {
  83     if ( [ self textArea ] != nil ) {
  84         return [ [ self textArea ] numberOfCharactersAttribute ];
  85     }
  86     return [ NSNumber numberWithInt: 0 ];
  87 }
  88
  89 -(id)selectedTextAttribute {
  90     if ( [ self textArea ] != nil ) {
  91         return [ [ self textArea ] selectedTextAttribute ];
  92     }
  93     return @"";
  94 }
  95
  96 -(id)selectedTextRangeAttribute {
  97     if ( [ self textArea ] != nil ) {
  98         return [ [ self textArea ] selectedTextRangeAttribute ];
  99     }
 100     return [ NSValue valueWithRange: NSMakeRange ( 0, 0 ) ];
 101 }
 102
 103 -(id)visibleCharacterRangeAttribute {
 104     if ( [ self textArea ] != nil ) {
 105         return [ [ self textArea ] visibleCharacterRangeAttribute ];
 106     }
 107     return [ NSValue valueWithRange: NSMakeRange ( 0, 0 ) ];
 108 }
 109
 110 #pragma mark -
 111 #pragma mark Accessibility Protocol
 112
 113 -(BOOL)accessibilityIsAttributeSettable:(NSString *)attribute {
 114     // Related: tdf#148453 Acquire solar mutex during native accessibility calls
 115     SolarMutexGuard aGuard;
 116     if ( mIsDisposed )
 117         return NO;
 118
 119     if ( [ self textArea ] != nil && (
 120          [ attribute isEqualToString: NSAccessibilitySelectedTextAttribute ]
 121       || [ attribute isEqualToString: NSAccessibilitySelectedTextRangeAttribute ]
 122       || [ attribute isEqualToString: NSAccessibilityVisibleCharacterRangeAttribute ] ) ) {
 123         return [ [ self textArea ] accessibilityIsAttributeSettable: attribute ];
 124     }
 125     return [ super accessibilityIsAttributeSettable: attribute ];
 126 }
 127
 128 -(void)accessibilitySetValue:(id)value forAttribute:(NSString *)attribute {
 129     // Related: tdf#148453 Acquire solar mutex during native accessibility calls
 130     SolarMutexGuard aGuard;
 131     if ( mIsDisposed )
 132         return;
 133
 134     if ( [ self textArea ] != nil && (
 135          [ attribute isEqualToString: NSAccessibilitySelectedTextAttribute ]
 136       || [ attribute isEqualToString: NSAccessibilitySelectedTextRangeAttribute ]
 137       || [ attribute isEqualToString: NSAccessibilityVisibleCharacterRangeAttribute ] ) ) {
 138         return [ [ self textArea ] accessibilitySetValue: value forAttribute: attribute ];
 139     }
 140     return [ super accessibilitySetValue: value forAttribute: attribute ];
 141 }
 142
 143 -(NSArray *)accessibilityAttributeNames {
 144     // Related: tdf#148453 Acquire solar mutex during native accessibility calls
 145     SolarMutexGuard aGuard;
 146     if ( mIsDisposed )
 147         return [ NSArray array ];
 148
 149     // Default Attributes
 150     NSMutableArray * attributeNames = [ NSMutableArray arrayWithArray: [ super accessibilityAttributeNames ] ];
 151     // Special Attributes and removing unwanted attributes depending on role
 152     [ attributeNames removeObjectsInArray: [ NSArray arrayWithObjects:
 153             NSAccessibilityTitleAttribute,
 154             NSAccessibilityChildrenAttribute,
 155             nil ]
 156     ];
 157     [ attributeNames addObjectsFromArray: [ NSArray arrayWithObjects:
 158             NSAccessibilityExpandedAttribute,
 159             NSAccessibilityValueAttribute,
 160             NSAccessibilityNumberOfCharactersAttribute,
 161             NSAccessibilitySelectedTextAttribute,
 162             NSAccessibilitySelectedTextRangeAttribute,
 163             NSAccessibilityVisibleCharacterRangeAttribute,
 164             nil ]
 165     ];
 166     return attributeNames;
 167 }
 168
 169 @end
 170
 171 /* vim:set shiftwidth=4 softtabstop=4 expandtab: */