sfx2/source/appl/shutdowniconaqua.mm

   1 /* -*- Mode: C++; tab-width: 4; indent-tabs-mode: nil; c-basic-offset: 4 -*- */
   2 /*
   3  * This file is part of the LibreOffice project.
   4  *
   5  * This Source Code Form is subject to the terms of the Mozilla Public
   6  * License, v. 2.0. If a copy of the MPL was not distributed with this
   7  * file, You can obtain one at http://mozilla.org/MPL/2.0/.
   8  *
   9  * This file incorporates work covered by the following license notice:
  10  *
  11  *   Licensed to the Apache Software Foundation (ASF) under one or more
  12  *   contributor license agreements. See the NOTICE file distributed
  13  *   with this work for additional information regarding copyright
  14  *   ownership. The ASF licenses this file to you under the Apache
  15  *   License, Version 2.0 (the "License"); you may not use this file
  16  *   except in compliance with the License. You may obtain a copy of
  17  *   the License at http://www.apache.org/licenses/LICENSE-2.0 .
  18  */
  19
  20
  21 #include <unotools/moduleoptions.hxx>
  22 #include <unotools/dynamicmenuoptions.hxx>
  23 #include <unotools/historyoptions.hxx>
  24 #include <rtl/ustring.hxx>
  25 #include <tools/urlobj.hxx>
  26 #include <osl/file.h>
  27 #include <comphelper/sequenceashashmap.hxx>
  28 #include <sfx2/app.hxx>
  29 #include <sal/macros.h>
  30 #include <sfx2/sfxresid.hxx>
  31 #include <sfx2/strings.hrc>
  32 #include <vcl/svapp.hxx>
  33 #include "shutdownicon.hxx"
  34
  35 #include <com/sun/star/util/XStringWidth.hpp>
  36
  37 #include <cppuhelper/implbase.hxx>
  38
  39 #include <set>
  40 #include <vector>
  41
  42 #include <premac.h>
  43 #include <objc/objc-runtime.h>
  44 #include <Cocoa/Cocoa.h>
  45 #include <postmac.h>
  46
  47 #define MI_OPEN                    1
  48 #define MI_WRITER                  2
  49 #define MI_CALC                    3
  50 #define MI_IMPRESS                 4
  51 #define MI_DRAW                    5
  52 #define MI_BASE                    6
  53 #define MI_MATH                    7
  54 #define MI_TEMPLATE                8
  55 #define MI_STARTMODULE             9
  56
  57 @interface QSMenuExecute : NSObject
  58 {
  59 }
  60 -(void)executeMenuItem: (NSMenuItem*)pItem;
  61 -(void)dockIconClicked: (NSObject*)pSender;
  62 @end
  63
  64 @implementation QSMenuExecute
  65 -(void)executeMenuItem: (NSMenuItem*)pItem
  66 {
  67     switch( [pItem tag] )
  68     {
  69     case MI_OPEN:
  70         ShutdownIcon::FileOpen();
  71         break;
  72     case MI_WRITER:
  73         ShutdownIcon::OpenURL( WRITER_URL, "_default" );
  74         break;
  75     case MI_CALC:
  76         ShutdownIcon::OpenURL( CALC_URL, "_default" );
  77         break;
  78     case MI_IMPRESS:
  79         ShutdownIcon::OpenURL( IMPRESS_URL, "_default" );
  80         break;
  81     case MI_DRAW:
  82         ShutdownIcon::OpenURL( DRAW_URL, "_default" );
  83         break;
  84     case MI_BASE:
  85         ShutdownIcon::OpenURL( BASE_URL, "_default" );
  86         break;
  87     case MI_MATH:
  88         ShutdownIcon::OpenURL( MATH_URL, "_default" );
  89         break;
  90     case MI_TEMPLATE:
  91         ShutdownIcon::FromTemplate();
  92         break;
  93     case MI_STARTMODULE:
  94         ShutdownIcon::OpenURL( STARTMODULE_URL, "_default" );
  95         break;
  96     default:
  97         break;
  98     }
  99 }
 100
 101 -(void)dockIconClicked: (NSObject*)pSender
 102 {
 103     (void)pSender;
 104     // start module
 105     ShutdownIcon::OpenURL( STARTMODULE_URL, "_default" );
 106 }
 107
 108 @end
 109
 110 bool ShutdownIcon::IsQuickstarterInstalled()
 111 {
 112     return true;
 113 }
 114
 115 static NSMenuItem* pDefMenu = nil, *pDockSubMenu = nil;
 116 static QSMenuExecute* pExecute = nil;
 117
 118 static std::set< OUString > aShortcuts;
 119
 120 static NSString* getAutoreleasedString( const OUString& rStr )
 121 {
 122     return [[[NSString alloc] initWithCharacters: reinterpret_cast<unichar const *>(rStr.getStr()) length: rStr.getLength()] autorelease];
 123 }
 124
 125 namespace {
 126
 127 struct RecentMenuEntry
 128 {
 129     OUString aURL;
 130     OUString aFilter;
 131     OUString aTitle;
 132     OUString aPassword;
 133 };
 134
 135 class RecentFilesStringLength : public ::cppu::WeakImplHelper< css::util::XStringWidth >
 136 {
 137     public:
 138         RecentFilesStringLength() {}
 139
 140         // XStringWidth
 141         sal_Int32 SAL_CALL queryStringWidth( const OUString& aString ) override
 142         {
 143             return aString.getLength();
 144         }
 145 };
 146
 147 }
 148
 149 @interface RecentMenuDelegate : NSObject <NSMenuDelegate>
 150 {
 151     std::vector< RecentMenuEntry >* m_pRecentFilesItems;
 152 }
 153 -(id)init;
 154 -(void)dealloc;
 155 -(void)menuNeedsUpdate:(NSMenu *)menu;
 156 -(void)executeRecentEntry: (NSMenuItem*)item;
 157 @end
 158
 159 @implementation RecentMenuDelegate
 160 -(id)init
 161 {
 162     if( (self = [super init]) )
 163     {
 164         m_pRecentFilesItems = new std::vector< RecentMenuEntry >();
 165     }
 166     return self;
 167 }
 168
 169 -(void)dealloc
 170 {
 171     delete m_pRecentFilesItems;
 172     [super dealloc];
 173 }
 174
 175 -(void)menuNeedsUpdate:(NSMenu *)menu
 176 {
 177     // clear menu
 178     int nItems = [menu numberOfItems];
 179     while( nItems -- )
 180         [menu removeItemAtIndex: 0];
 181
 182     // update recent item list
 183     std::vector< SvtHistoryOptions::HistoryItem > aHistoryList( SvtHistoryOptions::GetList( EHistoryType::PickList ) );
 184
 185     int nPickListMenuItems = ( aHistoryList.size() > 99 ) ? 99 : aHistoryList.size();
 186
 187     m_pRecentFilesItems->clear();
 188     if( nPickListMenuItems > 0 )
 189     {
 190         for ( int i = 0; i < nPickListMenuItems; i++ )
 191         {
 192             const SvtHistoryOptions::HistoryItem & rPickListEntry = aHistoryList[i];
 193             RecentMenuEntry aRecentFile;
 194             aRecentFile.aURL = rPickListEntry.sURL;
 195             aRecentFile.aFilter = rPickListEntry.sFilter;
 196             aRecentFile.aTitle = rPickListEntry.sTitle;
 197             aRecentFile.aPassword = rPickListEntry.sPassword;
 198             m_pRecentFilesItems->push_back( aRecentFile );
 199         }
 200     }
 201
 202     // insert new recent items
 203     for ( std::vector<RecentMenuEntry>::size_type i = 0; i < m_pRecentFilesItems->size(); i++ )
 204     {
 205         OUString   aMenuTitle;
 206         INetURLObject   aURL( (*m_pRecentFilesItems)[i].aURL );
 207
 208         if ( aURL.GetProtocol() == INetProtocol::File )
 209         {
 210             // Do handle file URL differently => convert it to a system
 211             // path and abbreviate it with a special function:
 212             OUString aSystemPath( aURL.getFSysPath( FSysStyle::Detect ) );
 213             OUString aCompactedSystemPath;
 214
 215             oslFileError nError = osl_abbreviateSystemPath( aSystemPath.pData, &aCompactedSystemPath.pData, 46, nullptr );
 216             if ( !nError )
 217                 aMenuTitle = aCompactedSystemPath;
 218             else
 219                 aMenuTitle = aSystemPath;
 220         }
 221         else
 222         {
 223             // Use INetURLObject to abbreviate all other URLs
 224             css::uno::Reference< css::util::XStringWidth > xStringLength( new RecentFilesStringLength() );
 225             aMenuTitle = aURL.getAbbreviated( xStringLength, 46, INetURLObject::DecodeMechanism::Unambiguous );
 226         }
 227
 228         NSMenuItem* pNewItem = [[NSMenuItem alloc] initWithTitle: getAutoreleasedString( aMenuTitle )
 229                                                    action: @selector(executeRecentEntry:)
 230                                                    keyEquivalent: @""];
 231         [pNewItem setTag: i];
 232         [pNewItem setTarget: self];
 233         [pNewItem setEnabled: YES];
 234         [menu addItem: pNewItem];
 235         [pNewItem autorelease];
 236     }
 237 }
 238
 239 -(void)executeRecentEntry: (NSMenuItem*)item
 240 {
 241     sal_Int32 nIndex = [item tag];
 242     if( ( nIndex >= 0 ) && ( nIndex < static_cast<sal_Int32>( m_pRecentFilesItems->size() ) ) )
 243     {
 244         const RecentMenuEntry& rRecentFile = (*m_pRecentFilesItems)[ nIndex ];
 245         int NUM_OF_PICKLIST_ARGS = 3;
 246         css::uno::Sequence< css::beans::PropertyValue > aArgsList( NUM_OF_PICKLIST_ARGS );
 247         css::beans::PropertyValue* pArgsList = aArgsList.getArray();
 248
 249         pArgsList[0].Name = "Referer";
 250         pArgsList[0].Value <<= OUString( "private:user" );
 251
 252         // documents in the picklist will never be opened as templates
 253         pArgsList[1].Name = "AsTemplate";
 254         pArgsList[1].Value <<= false;
 255
 256         OUString  aFilter( rRecentFile.aFilter );
 257         sal_Int32 nPos = aFilter.indexOf( '|' );
 258         if ( nPos >= 0 )
 259         {
 260             OUString aFilterOptions;
 261
 262             if ( nPos < ( aFilter.getLength() - 1 ) )
 263                 aFilterOptions = aFilter.copy( nPos+1 );
 264
 265             pArgsList[2].Name = "FilterOptions";
 266             pArgsList[2].Value <<= aFilterOptions;
 267
 268             aFilter = aFilter.copy( 0, nPos-1 );
 269             aArgsList.realloc( ++NUM_OF_PICKLIST_ARGS );
 270             pArgsList = aArgsList.getArray();
 271         }
 272
 273         pArgsList[NUM_OF_PICKLIST_ARGS-1].Name = "FilterName";
 274         pArgsList[NUM_OF_PICKLIST_ARGS-1].Value <<= aFilter;
 275
 276         ShutdownIcon::OpenURL( rRecentFile.aURL, "_default", aArgsList );
 277     }
 278 }
 279 @end
 280
 281 static RecentMenuDelegate* pRecentDelegate = nil;
 282
 283 static OUString getShortCut( const OUString& i_rTitle )
 284 {
 285     // create shortcut
 286     OUString aKeyEquiv;
 287     for( sal_Int32 nIndex = 0; nIndex < i_rTitle.getLength(); nIndex++ )
 288     {
 289         OUString aShortcut( i_rTitle.copy( nIndex, 1 ).toAsciiLowerCase() );
 290         if( aShortcuts.find( aShortcut ) == aShortcuts.end() )
 291         {
 292             aShortcuts.insert( aShortcut );
 293             aKeyEquiv = aShortcut;
 294             break;
 295         }
 296     }
 297
 298     return aKeyEquiv;
 299 }
 300
 301 static void appendMenuItem( NSMenu* i_pMenu, NSMenu* i_pDockMenu, const OUString& i_rTitle, int i_nTag, const OUString& i_rKeyEquiv )
 302 {
 303     if( ! i_rTitle.getLength() )
 304         return;
 305
 306     NSMenuItem* pItem = [[NSMenuItem alloc] initWithTitle: getAutoreleasedString( i_rTitle )
 307                                             action: @selector(executeMenuItem:)
 308                                             keyEquivalent: (i_rKeyEquiv.getLength() ? getAutoreleasedString( i_rKeyEquiv ) : @"")
 309                         ];
 310     [pItem setTag: i_nTag];
 311     [pItem setTarget: pExecute];
 312     [pItem setEnabled: YES];
 313     [i_pMenu addItem: pItem];
 314
 315     if( i_pDockMenu )
 316     {
 317         // create a similar entry in the dock menu
 318         pItem = [[NSMenuItem alloc] initWithTitle: getAutoreleasedString( i_rTitle )
 319                                     action: @selector(executeMenuItem:)
 320                                     keyEquivalent: @""
 321                             ];
 322         [pItem setTag: i_nTag];
 323         [pItem setTarget: pExecute];
 324         [pItem setEnabled: YES];
 325         [i_pDockMenu addItem: pItem];
 326     }
 327 }
 328
 329 static void appendRecentMenu( NSMenu* i_pMenu, NSMenu* i_pDockMenu, const OUString& i_rTitle )
 330 {
 331     if( ! pRecentDelegate )
 332         pRecentDelegate = [[RecentMenuDelegate alloc] init];
 333
 334     NSMenuItem* pItem = [i_pMenu addItemWithTitle: getAutoreleasedString( i_rTitle )
 335                                                    action: @selector(executeMenuItem:)
 336                                                    keyEquivalent: @""
 337                         ];
 338     [pItem setEnabled: YES];
 339     NSMenu* pRecentMenu = [[NSMenu alloc] initWithTitle: getAutoreleasedString( i_rTitle ) ];
 340
 341     [pRecentMenu setDelegate: pRecentDelegate];
 342
 343     [pRecentMenu setAutoenablesItems: NO];
 344     [pItem setSubmenu: pRecentMenu];
 345
 346     if( i_pDockMenu )
 347     {
 348         // create a similar entry in the dock menu
 349         pItem = [i_pDockMenu addItemWithTitle: getAutoreleasedString( i_rTitle )
 350                              action: @selector(executeMenuItem:)
 351                              keyEquivalent: @""
 352                         ];
 353         [pItem setEnabled: YES];
 354         pRecentMenu = [[NSMenu alloc] initWithTitle: getAutoreleasedString( i_rTitle ) ];
 355
 356         [pRecentMenu setDelegate: pRecentDelegate];
 357
 358         [pRecentMenu setAutoenablesItems: NO];
 359         [pItem setSubmenu: pRecentMenu];
 360     }
 361 }
 362
 363
 364 extern "C"
 365 {
 366
 367 void aqua_init_systray()
 368 {
 369     SolarMutexGuard aGuard;
 370
 371     ShutdownIcon *pShutdownIcon = ShutdownIcon::getInstance();
 372     if( ! pShutdownIcon )
 373         return;
 374
 375     // disable shutdown
 376     pShutdownIcon->SetVeto( true );
 377     ShutdownIcon::addTerminateListener();
 378
 379     if( ! pDefMenu )
 380     {
 381         if( [NSApp respondsToSelector: @selector(addFallbackMenuItem:)] )
 382         {
 383             aShortcuts.clear();
 384
 385             pExecute = [[QSMenuExecute alloc] init];
 386             pDefMenu = [[NSMenuItem alloc] initWithTitle: getAutoreleasedString( SfxResId(STR_QUICKSTART_FILE) ) action: nullptr keyEquivalent: @""];
 387             pDockSubMenu = [[NSMenuItem alloc] initWithTitle: getAutoreleasedString( SfxResId(STR_QUICKSTART_FILE) ) action: nullptr keyEquivalent: @""];
 388             NSMenu* pMenu = [[NSMenu alloc] initWithTitle: getAutoreleasedString( SfxResId(STR_QUICKSTART_FILE) )];
 389             [pMenu setAutoenablesItems: NO];
 390             NSMenu* pDockMenu = [[NSMenu alloc] initWithTitle: getAutoreleasedString( SfxResId(STR_QUICKSTART_FILE) )];
 391             [pDockMenu setAutoenablesItems: NO];
 392
 393             // collect the URLs of the entries in the File/New menu
 394             SvtModuleOptions    aModuleOptions;
 395             std::set< OUString > aFileNewAppsAvailable;
 396             std::vector < SvtDynMenuEntry > const aNewMenu = SvtDynamicMenuOptions::GetMenu( EDynamicMenuType::NewMenu );
 397
 398             for ( SvtDynMenuEntry const & newMenuProp : aNewMenu )
 399             {
 400                 if ( !newMenuProp.sURL.isEmpty() )
 401                     aFileNewAppsAvailable.insert( newMenuProp.sURL );
 402             }
 403
 404             // describe the menu entries for launching the applications
 405             struct MenuEntryDescriptor
 406             {
 407                 SvtModuleOptions::EModule   eModuleIdentifier;
 408                 int                         nMenuTag;
 409                 const char*                 pAsciiURLDescription;
 410             }   aMenuItems[] =
 411             {
 412                 { SvtModuleOptions::EModule::WRITER,    MI_WRITER,  WRITER_URL },
 413                 { SvtModuleOptions::EModule::CALC,      MI_CALC,    CALC_URL },
 414                 { SvtModuleOptions::EModule::IMPRESS,   MI_IMPRESS, IMPRESS_WIZARD_URL },
 415                 { SvtModuleOptions::EModule::DRAW,      MI_DRAW,    DRAW_URL },
 416                 { SvtModuleOptions::EModule::DATABASE,  MI_BASE,    BASE_URL },
 417                 { SvtModuleOptions::EModule::MATH,      MI_MATH,    MATH_URL }
 418             };
 419
 420             // insert entry for startcenter
 421             if( aModuleOptions.IsModuleInstalled( SvtModuleOptions::EModule::STARTMODULE ) )
 422             {
 423                 appendMenuItem( pMenu, nil, SfxResId(STR_QUICKSTART_STARTCENTER), MI_STARTMODULE, "n" );
 424                 if( [NSApp respondsToSelector: @selector(setDockIconClickHandler:)] )
 425                     [NSApp performSelector:@selector(setDockIconClickHandler:) withObject: pExecute];
 426                 else
 427                     OSL_FAIL( "setDockIconClickHandler selector failed on NSApp" );
 428
 429             }
 430
 431             // insert the menu entries for launching the applications
 432             for ( size_t i = 0; i < SAL_N_ELEMENTS( aMenuItems ); ++i )
 433             {
 434                 if ( !aModuleOptions.IsModuleInstalled( aMenuItems[i].eModuleIdentifier ) )
 435                     // the complete application is not even installed
 436                     continue;
 437
 438                 OUString sURL( OUString::createFromAscii( aMenuItems[i].pAsciiURLDescription ) );
 439
 440                 if ( aFileNewAppsAvailable.find( sURL ) == aFileNewAppsAvailable.end() )
 441                     // the application is installed, but the entry has been configured to *not* appear in the File/New
 442                     // menu => also let not appear it in the quickstarter
 443                     continue;
 444
 445                 OUString aKeyEquiv( getShortCut( ShutdownIcon::GetUrlDescription( sURL ) ) );
 446
 447                 appendMenuItem( pMenu, pDockMenu, ShutdownIcon::GetUrlDescription( sURL ), aMenuItems[i].nMenuTag, aKeyEquiv );
 448             }
 449
 450             // insert the remaining menu entries
 451
 452             // add recent menu
 453             appendRecentMenu( pMenu, pDockMenu, SfxResId(STR_QUICKSTART_RECENTDOC) );
 454
 455             OUString aTitle( SfxResId(STR_QUICKSTART_FROMTEMPLATE) );
 456             OUString aKeyEquiv( getShortCut( aTitle ) );
 457             appendMenuItem( pMenu, pDockMenu, aTitle, MI_TEMPLATE, aKeyEquiv );
 458             aTitle = SfxResId(STR_QUICKSTART_FILEOPEN);
 459             aKeyEquiv = getShortCut( aTitle );
 460             appendMenuItem( pMenu, pDockMenu, aTitle, MI_OPEN, aKeyEquiv );
 461
 462             [pDefMenu setSubmenu: pMenu];
 463             [NSApp performSelector:@selector(addFallbackMenuItem:) withObject: pDefMenu];
 464
 465             if( [NSApp respondsToSelector: @selector(addDockMenuItem:)] )
 466             {
 467                 [pDockSubMenu setSubmenu: pDockMenu];
 468                 // add the submenu
 469                 [NSApp performSelector:@selector(addDockMenuItem:) withObject: pDockSubMenu];
 470             }
 471             else
 472                 OSL_FAIL( "addDockMenuItem selector failed on NSApp" );
 473         }
 474         else
 475             OSL_FAIL( "addFallbackMenuItem selector failed on NSApp" );
 476     }
 477 }
 478
 479 void SAL_DLLPUBLIC_EXPORT aqua_shutdown_systray()
 480 {
 481 }
 482
 483 }
 484
 485 /* vim:set shiftwidth=4 softtabstop=4 expandtab: */