bridges/source/cpp_uno/gcc3_linux_mips64/call.s

   1 /*
   2  * This file is part of the LibreOffice project.
   3  *
   4  * This Source Code Form is subject to the terms of the Mozilla Public
   5  * License, v. 2.0. If a copy of the MPL was not distributed with this
   6  * file, You can obtain one at http://mozilla.org/MPL/2.0/.
   7  *
   8  * This file incorporates work covered by the following license notice:
   9  *
  10  *   Licensed to the Apache Software Foundation (ASF) under one or more
  11  *   contributor license agreements. See the NOTICE file distributed
  12  *   with this work for additional information regarding copyright
  13  *   ownership. The ASF licenses this file to you under the Apache
  14  *   License, Version 2.0 (the "License"); you may not use this file
  15  *   except in compliance with the License. You may obtain a copy of
  16  *   the License at http://www.apache.org/licenses/LICENSE-2.0 .
  17  */
  18
  19         .text
  20         .globl  privateSnippetExecutor
  21 .LFB0 = .
  22         .cfi_startproc
  23         .cfi_personality 0x80,DW.ref.__gxx_personality_v0
  24         .cfi_lsda 0,.LLSDA0
  25         .ent    privateSnippetExecutor
  26         .type   privateSnippetExecutor, @function
  27 privateSnippetExecutor:
  28         .set    noreorder
  29         daddiu  $sp,$sp,-160
  30         .cfi_def_cfa_offset 160
  31         sd      $ra,152($sp)
  32         .cfi_offset 31, -8
  33 .LEHB0 = .
  34         // Save the float point registers
  35         sdc1    $f12,80($sp)
  36         sdc1    $f13,88($sp)
  37         sdc1    $f14,96($sp)
  38         sdc1    $f15,104($sp)
  39         sdc1    $f16,112($sp)
  40         sdc1    $f17,120($sp)
  41         sdc1    $f18,128($sp)
  42         sdc1    $f19,136($sp)
  43         // Save the general purpose registers
  44         sd      $a0,16($sp)
  45         sd      $a1,24($sp)
  46         sd      $a2,32($sp)
  47         sd      $a3,40($sp)
  48         sd      $a4,48($sp)
  49         sd      $a5,56($sp)
  50         sd      $a6,64($sp)
  51         sd      $a7,72($sp)
  52         // Load arguments
  53         // a0=index
  54         move    $a0,$v0
  55         // a1=offset
  56         move    $a1,$v1
  57         // a2=gpregptr
  58         daddiu  $a2,$sp,16
  59         // a3=fpregptr
  60         daddiu  $a3,$sp,80
  61         // a4=ovrflw
  62         daddiu  $a4,$sp,160
  63         // Call cpp_vtable_call
  64         jalr    $t9
  65         // a5=retregptr
  66         move    $a5,$sp
  67
  68 .LEHE0 = .
  69         // Perform return value
  70         li      $v1,10
  71         beq     $v0,$v1,.Lfloat
  72         li      $v1,11
  73         beq     $v0,$v1,.Lfloat
  74         ldc1    $f0,0($sp)
  75         ldc1    $f2,8($sp)
  76         ld      $v0,0($sp)
  77         b       .Lfinish
  78         ld      $v1,8($sp)
  79 .Lfloat:
  80         ldc1    $f0,0($sp)
  81         ldc1    $f2,8($sp)
  82
  83 .Lfinish:
  84         ld      $ra,152($sp)
  85         .cfi_restore 31
  86         jr      $ra
  87         daddiu  $sp,$sp,160
  88         .cfi_def_cfa_offset 0
  89
  90         .set    reorder
  91         .end    privateSnippetExecutor
  92         .cfi_endproc
  93 .LFE0:
  94         .globl  __gxx_personality_v0
  95         .section        .gcc_except_table,"aw",@progbits
  96         .align  3
  97 .LLSDA0:
  98         .byte   0xff
  99         .byte   0x80
 100         .uleb128 .LLSDATT0-.LLSDATTD0
 101 .LLSDATTD0:
 102         .byte   0x1
 103         .uleb128 .LLSDACSE0-.LLSDACSB0
 104 .LLSDACSB0:
 105         .uleb128 .LEHB0-.LFB0
 106         .uleb128 .LEHE0-.LEHB0
 107         .uleb128 0
 108         .uleb128 0
 109 .LLSDACSE0:
 110         .byte   0x7f
 111         .byte   0
 112         .align  3
 113         .8byte  DW.ref._ZTIi
 114 .LLSDATT0:
 115         .byte   0x1
 116         .byte   0
 117         .text
 118         .size   privateSnippetExecutor, .-privateSnippetExecutor
 119         .hidden DW.ref._ZTIi
 120         .weak   DW.ref._ZTIi
 121         .section        .data.DW.ref._ZTIi,"awG",@progbits,DW.ref._ZTIi,comdat
 122         .align  3
 123         .type   DW.ref._ZTIi, @object
 124         .size   DW.ref._ZTIi, 8
 125 DW.ref._ZTIi:
 126         .dword  _ZTIi
 127         .hidden DW.ref.__gxx_personality_v0
 128         .weak   DW.ref.__gxx_personality_v0
 129         .section        .data.DW.ref.__gxx_personality_v0,"awG",@progbits,DW.ref.__gxx_personality_v0,comdat
 130         .align  3
 131         .type   DW.ref.__gxx_personality_v0, @object
 132         .size   DW.ref.__gxx_personality_v0, 8
 133 DW.ref.__gxx_personality_v0:
 134         .dword  __gxx_personality_v0