bridges/source/cpp_uno/gcc3_linux_x86-64/call.s

   1 /*
   2  * This file is part of the LibreOffice project.
   3  *
   4  * This Source Code Form is subject to the terms of the Mozilla Public
   5  * License, v. 2.0. If a copy of the MPL was not distributed with this
   6  * file, You can obtain one at http://mozilla.org/MPL/2.0/.
   7  *
   8  * This file incorporates work covered by the following license notice:
   9  *
  10  *   Licensed to the Apache Software Foundation (ASF) under one or more
  11  *   contributor license agreements. See the NOTICE file distributed
  12  *   with this work for additional information regarding copyright
  13  *   ownership. The ASF licenses this file to you under the Apache
  14  *   License, Version 2.0 (the "License"); you may not use this file
  15  *   except in compliance with the License. You may obtain a copy of
  16  *   the License at http://www.apache.org/licenses/LICENSE-2.0 .
  17  */
  18
  19         .text
  20         .align 2
  21 .globl privateSnippetExecutor
  22         .type   privateSnippetExecutor, @function
  23 privateSnippetExecutor:
  24 .LFB3:
  25 #if defined(END_BRANCH_INS_SUPPORT)
  26         endbr64
  27 #endif
  28         pushq   %rbp
  29 .LCFI0:
  30         movq    %rsp, %rbp
  31 .LCFI1:
  32         subq    $160, %rsp
  33 .LCFI2:
  34         movq    %r10, -152(%rbp)                # Save (nVtableOffset << 32) + nFunctionIndex
  35
  36         movq    %rdi, -112(%rbp)                # Save GP registers
  37         movq    %rsi, -104(%rbp)
  38         movq    %rdx, -96(%rbp)
  39         movq    %rcx, -88(%rbp)
  40         movq    %r8 , -80(%rbp)
  41         movq    %r9 , -72(%rbp)
  42
  43         movsd   %xmm0, -64(%rbp)                # Save FP registers
  44         movsd   %xmm1, -56(%rbp)
  45         movsd   %xmm2, -48(%rbp)
  46         movsd   %xmm3, -40(%rbp)
  47         movsd   %xmm4, -32(%rbp)
  48         movsd   %xmm5, -24(%rbp)
  49         movsd   %xmm6, -16(%rbp)
  50         movsd   %xmm7, -8(%rbp)
  51
  52         leaq    -144(%rbp), %r9                 # 6th param: sal_uInt64 * pRegisterReturn
  53         leaq    16(%rbp), %r8                   # 5rd param: void ** ovrflw
  54         leaq    -64(%rbp), %rcx                 # 4th param: void ** fpreg
  55         leaq    -112(%rbp), %rdx                # 3rd param: void ** gpreg
  56         movl    -148(%rbp), %esi                # 2nd param: sal_int32 nVtableOffset
  57         movl    -152(%rbp), %edi                # 1st param: sal_int32 nFunctionIndex
  58
  59         call    cpp_vtable_call
  60
  61         testl   %eax, %eax
  62         je      .Lfpint
  63         jg      .Lintfp
  64
  65         movq    -144(%rbp), %rax                # Potential return value (general case)
  66         movq    -136(%rbp), %rdx                # Potential return value (general case)
  67         movq    -144(%rbp), %xmm0               # Potential return value (general case)
  68         movq    -136(%rbp), %xmm1               # Potential return value (general case)
  69         jmp     .Lfinish
  70 .Lfpint:
  71         movq    -144(%rbp), %xmm0               # Return value (special fp and integer case)
  72         movq    -136(%rbp), %rax                # Return value (special fp and integer case)
  73         jmp     .Lfinish
  74 .Lintfp:
  75         movq    -144(%rbp), %rax                # Return value (special integer and fp case)
  76         movq    -136(%rbp), %xmm0               # Return value (special integer and fp case)
  77
  78 .Lfinish:
  79         leave
  80         ret
  81 .LFE3:
  82         .size   privateSnippetExecutor, .-privateSnippetExecutor
  83         # see http://refspecs.linuxfoundation.org/LSB_3.0.0/LSB-Core-generic/LSB-Core-generic/ehframechpt.html
  84         # for details of the .eh_frame, the "Common Information Entry" and "Frame Description Entry" formats
  85         # and http://mentorembedded.github.io/cxx-abi/exceptions.pdf for more info
  86         .section        .eh_frame,"a",@unwind
  87 .Lframe1:
  88         .long   .LECIE1-.LSCIE1         # CIE Length
  89 .LSCIE1:
  90         .long   0x0                     # CIE ID
  91         .byte   0x1                     # CIE Version
  92         .string "zR"                    # CIE Augmentation String
  93         .uleb128 0x1                    # CIE Code Alignment Factor
  94         .sleb128 -8                     # CIE Data Alignment Factor
  95         .byte   0x10                    # CIE Return Address Register: pseudo "Return Address RA"
  96         .uleb128 0x1                    # CIE Augmentation Data Length
  97         .byte   0x1b                    # CIE Augmentation Data
  98                                         # CIE Initial Instructions:
  99         .byte   0xc                     #  DW_CFA_def_cfa %rsp +8
 100         .uleb128 0x7
 101         .uleb128 0x8
 102         .byte   0x90                    #  DW_CFA_offset (pseudo "Return Address RA") +1 (i.e., -8)
 103         .uleb128 0x1
 104         .align 8
 105 .LECIE1:
 106 .LSFDE1:
 107         .long   .LEFDE1-.LASFDE1        # FDE Length
 108 .LASFDE1:
 109         .long   .LASFDE1-.Lframe1       # FDE CIE Pointer
 110         .long   .LFB3-.                 # FDE PC Begin
 111         .long   .LFE3-.LFB3             # FDE PC Range
 112         .uleb128 0x0                    # FDE Augmentation Data Length
 113                                         # FDE Call Frame Instructions:
 114         .byte   0x4                     #  DW_CFA_advance_loc4 .LCFI0
 115         .long   .LCFI0-.LFB3
 116         .byte   0xe                     #  DW_CFA_def_cfa_offset +16
 117         .uleb128 0x10
 118         .byte   0x86                    #  DW_CFA_offset %rbp +2 (i.e., -16)
 119         .uleb128 0x2
 120         .byte   0x4                     #  DW_CFA_advance_loc4 .LCFI1
 121         .long   .LCFI1-.LCFI0
 122         .byte   0xd                     #  DW_CFA_def_cfa_register %rbp
 123         .uleb128 0x6
 124         .align 8
 125 .LEFDE1:
 126         .section        .note.GNU-stack,"",@progbits
 127         .section        .note.gnu.property,"a"
 128         .p2align 3
 129         .long    1f - 0f
 130         .long    4f - 1f
 131         .long    5
 132 0:
 133         .string  "GNU"
 134 1:
 135         .p2align 3
 136         .long    0xc0000002
 137         .long    3f - 2f
 138 2:
 139         .long    0x3
 140 3:
 141         .p2align 3
 142 4: