i18npool/source/breakiterator/data/dict_word.txt

   1 #
   2 # Copyright (C) 2016 and later: Unicode, Inc. and others.
   3 # License & terms of use: http://www.unicode.org/copyright.html
   4 # Copyright (C) 2002-2016, International Business Machines Corporation
   5 # and others. All Rights Reserved.
   6 #
   7 # file:  word.txt
   8 #
   9 # ICU Word Break Rules
  10 #      See Unicode Standard Annex #29.
  11 #      These rules are based on UAX #29 Revision 34 for Unicode Version 12.0
  12 #
  13 # Note:  Updates to word.txt will usually need to be merged into
  14 #        word_POSIX.txt also.
  15
  16 ##############################################################################
  17 #
  18 #  Character class definitions from TR 29
  19 #
  20 ##############################################################################
  21
  22 ### BEGIN CUSTOMIZATION
  23 ### This file contains LibreOffice-specific rule customizations.
  24 ###
  25 ### To aid future maintainability:
  26 ### - The change location should be bracketed by comments of this form.
  27 ### - The original rule should be commented out, and the modified rule placed alongside.
  28 ### - By doing this, maintainers can more easily compare to an upstream baseline.
  29 ###
  30 ### END CUSTOMIZATION
  31
  32 !!chain;
  33 !!quoted_literals_only;
  34
  35
  36 #
  37 #  Character Class Definitions.
  38 #
  39
  40 $Han                = [:Han:];
  41
  42 $CR                 = [\p{Word_Break = CR}];
  43 $LF                 = [\p{Word_Break = LF}];
  44 $Newline            = [\p{Word_Break = Newline}];
  45 $Extend             = [\p{Word_Break = Extend}-$Han];
  46 $ZWJ                = [\p{Word_Break = ZWJ}];
  47 $Regional_Indicator = [\p{Word_Break = Regional_Indicator}];
  48 $Format             = [\p{Word_Break = Format}];
  49 $Katakana           = [\p{Word_Break = Katakana}];
  50 $Hebrew_Letter      = [\p{Word_Break = Hebrew_Letter}];
  51 $ALetter            = [\p{Word_Break = ALetter}];
  52 $Single_Quote       = [\p{Word_Break = Single_Quote}];
  53 $MidNumLet          = [\p{Word_Break = MidNumLet}];
  54 $MidNum             = [\p{Word_Break = MidNum}];
  55 $Numeric            = [\p{Word_Break = Numeric}];
  56 $ExtendNumLet       = [\p{Word_Break = ExtendNumLet}-[:name = NARROW NO-BREAK SPACE:]];
  57 $WSegSpace          = [\p{Word_Break = WSegSpace}];
  58 $Extended_Pict      = [\p{Extended_Pictographic}];
  59
  60 ### BEGIN CUSTOMIZATION
  61 ### Unknown issue number: Dictionary words can contain hyphens
  62 ### tdf#49885: Sync custom BreakIterator rules with ICU originals
  63 ### - ICU is now more permissive about punctuation inside words.
  64 ### - For compatibility, exclude certain characters that were previously excluded.
  65
  66 $IncludedML         = [:name = HYPHEN-MINUS:];
  67 $ExcludedML         = [[:name = COLON:]
  68                        [:name = GREEK ANO TELEIA:]
  69                        [:name = PRESENTATION FORM FOR VERTICAL COLON:]
  70                        [:name = SMALL COLON:]
  71                        [:name = FULLWIDTH COLON:]];
  72
  73 ### tdf#162514: For spell checking, abbreviations may end with a period.
  74 $PostPeriod         = [:name = FULL STOP:];
  75
  76 # $MidLetter          = [\p{Word_Break = MidLetter}];
  77 $MidLetter          = [[\p{Word_Break = MidLetter}]-$ExcludedML $IncludedML];
  78
  79 ### tdf#46950: Right double-quotes are also used as substitutes for Hebrew gershaim
  80 # $Double_Quote       = [\p{Word_Break = Double_Quote}];
  81 $Double_Quote       = [[\p{Word_Break = Double_Quote}][:name= RIGHT DOUBLE QUOTATION MARK:]];
  82
  83 ### END CUSTOMIZATION
  84
  85 $Hiragana           = [:Hiragana:];
  86 $Ideographic        = [\p{Ideographic}];
  87
  88
  89 #   Dictionary character set, for triggering language-based break engines. Currently
  90 #   limited to LineBreak=Complex_Context. Note that this set only works in Unicode
  91 #   5.0 or later as the definition of Complex_Context was corrected to include all
  92 #   characters requiring dictionary break.
  93
  94 $Control        = [\p{Grapheme_Cluster_Break = Control}];
  95 $HangulSyllable = [\uac00-\ud7a3];
  96 $ComplexContext = [:LineBreak = Complex_Context:];
  97 $KanaKanji      = [$Han $Hiragana $Katakana];
  98 $dictionaryCJK  = [$KanaKanji $HangulSyllable];
  99 $dictionary     = [$ComplexContext $dictionaryCJK];
 100
 101 # TODO: check if handling of katakana in dictionary makes rules incorrect/void
 102
 103 # leave CJK scripts out of ALetterPlus
 104 $ALetterPlus  = [$ALetter-$dictionaryCJK [$ComplexContext-$Extend-$Control]];
 105
 106
 107 ## -------------------------------------------------
 108
 109 # Rule 3 - CR x LF
 110 #
 111 $CR $LF;
 112
 113 # Rule 3c   Do not break within emoji zwj sequences.
 114 #             ZWJ ×  \p{Extended_Pictographic}.  Precedes WB4, so no intervening Extend chars allowed.
 115 #
 116 $ZWJ $Extended_Pict;
 117
 118 # Rule 3d - Keep horizontal whitespace together.
 119 #
 120 $WSegSpace $WSegSpace;
 121
 122 # Rule 4 - ignore Format and Extend characters, except when they appear at the beginning
 123 #          of a region of Text.
 124
 125 $ExFm  = [$Extend $Format $ZWJ];
 126
 127 ^$ExFm+;            # This rule fires only when there are format or extend characters at the
 128                     # start of text, or immediately following another boundary. It groups them, in
 129                     # the event there are more than one.
 130
 131 [^$CR $LF $Newline $ExFm] $ExFm*;   # This rule rule attaches trailing format/extends to words,
 132                                     # with no special rule status value.
 133
 134 $Numeric $ExFm* {100};              # This group of rules also attach trailing format/extends, but
 135 $ALetterPlus $ExFm* {200};          # with rule status set based on the word's final base character.
 136 $HangulSyllable {200};
 137 $Hebrew_Letter $ExFm* {200};
 138 $Katakana $ExFm* {400};             # note:  these status values override those from rule 5
 139 $Hiragana $ExFm* {400};             #        by virtue of being numerically larger.
 140 $Ideographic $ExFm* {400};          #
 141
 142 #
 143 # rule 5
 144 #    Do not break between most letters.
 145 #
 146
 147 ### BEGIN CUSTOMIZATION
 148 ### tdf#162514: For spell checking, abbreviations may end with a period.
 149
 150 # ($ALetterPlus | $Hebrew_Letter) $ExFm* ($ALetterPlus | $Hebrew_Letter);
 151 ($ALetterPlus | $Hebrew_Letter) $ExFm* ($ALetterPlus | $Hebrew_Letter) ($PostPeriod)?;
 152
 153 ### END CUSTOMIZATION
 154
 155 # rule 6 and 7
 156
 157 ### BEGIN CUSTOMIZATION
 158 ### tdf#162514: For spell checking, abbreviations may end with a period.
 159
 160 # ($ALetterPlus | $Hebrew_Letter)  $ExFm* ($MidLetter | $MidNumLet | $Single_Quote) $ExFm* ($ALetterPlus | $Hebrew_Letter) {200};
 161 ($ALetterPlus | $Hebrew_Letter)  $ExFm* ($MidLetter | $MidNumLet | $Single_Quote) $ExFm* ($ALetterPlus | $Hebrew_Letter) ($PostPeriod)? {200};
 162
 163 ### END CUSTOMIZATION
 164
 165 # rule 7a
 166 $Hebrew_Letter $ExFm* $Single_Quote {200};
 167
 168 # rule 7b and 7c
 169 $Hebrew_Letter $ExFm* $Double_Quote $ExFm* $Hebrew_Letter;
 170
 171 # rule 8
 172
 173 $Numeric $ExFm* $Numeric;
 174
 175 # rule 9
 176
 177 ($ALetterPlus | $Hebrew_Letter)  $ExFm* $Numeric;
 178
 179 # rule 10
 180
 181 $Numeric $ExFm* ($ALetterPlus | $Hebrew_Letter);
 182
 183 # rule 11 and 12
 184
 185 $Numeric $ExFm* ($MidNum | $MidNumLet | $Single_Quote) $ExFm* $Numeric;
 186
 187 # rule 13
 188 # to be consistent with $KanaKanji $KanaKanhi, changed
 189 # from 300 to 400.
 190 # See also TestRuleStatus in intltest/rbbiapts.cpp
 191 $Katakana $ExFm*  $Katakana {400};
 192
 193 # rule 13a/b
 194
 195 $ALetterPlus   $ExFm* $ExtendNumLet {200};    #  (13a)
 196 $Hebrew_Letter $ExFm* $ExtendNumLet {200};    #  (13a)
 197 $Numeric       $ExFm* $ExtendNumLet {100};    #  (13a)
 198 $Katakana      $ExFm* $ExtendNumLet {400};    #  (13a)
 199 $ExtendNumLet  $ExFm* $ExtendNumLet {200};    #  (13a)
 200
 201 $ExtendNumLet  $ExFm* $ALetterPlus  {200};    #  (13b)
 202 $ExtendNumLet  $ExFm* $Hebrew_Letter {200};    #  (13b)
 203 $ExtendNumLet  $ExFm* $Numeric      {100};    #  (13b)
 204 $ExtendNumLet  $ExFm* $Katakana     {400};    #  (13b)
 205
 206 # rules 15 - 17
 207 #    Pairs of Regional Indicators stay together.
 208 #    With incoming rule chaining disabled by ^, this rule will match exactly two of them.
 209 #    No other rule begins with a Regional_Indicator, so chaining cannot extend the match.
 210 #
 211 ^$Regional_Indicator $ExFm* $Regional_Indicator;
 212
 213 # special handling for CJK characters: chain for later dictionary segmentation
 214 $HangulSyllable $HangulSyllable {200};
 215 $KanaKanji $KanaKanji {400}; # different rule status if both kana and kanji found
 216
 217 # Rule 999
 218 #     Match a single code point if no other rule applies.
 219 .;