vcl/osx/a11ytextwrapper.mm

   1 /* -*- Mode: C++; tab-width: 4; indent-tabs-mode: nil; c-basic-offset: 4 -*- */
   2 /*
   3  * This file is part of the LibreOffice project.
   4  *
   5  * This Source Code Form is subject to the terms of the Mozilla Public
   6  * License, v. 2.0. If a copy of the MPL was not distributed with this
   7  * file, You can obtain one at http://mozilla.org/MPL/2.0/.
   8  *
   9  * This file incorporates work covered by the following license notice:
  10  *
  11  *   Licensed to the Apache Software Foundation (ASF) under one or more
  12  *   contributor license agreements. See the NOTICE file distributed
  13  *   with this work for additional information regarding copyright
  14  *   ownership. The ASF licenses this file to you under the Apache
  15  *   License, Version 2.0 (the "License"); you may not use this file
  16  *   except in compliance with the License. You may obtain a copy of
  17  *   the License at http://www.apache.org/licenses/LICENSE-2.0 .
  18  */
  19
  20
  21 #include <osx/salinst.h>
  22 #include <quartz/utils.h>
  23 #include "a11ytextwrapper.h"
  24 #include "a11ytextattributeswrapper.h"
  25 #include "a11yutil.h"
  26
  27 #include <com/sun/star/accessibility/AccessibleTextType.hpp>
  28 #include <com/sun/star/awt/Rectangle.hpp>
  29 #include <com/sun/star/lang/IllegalArgumentException.hpp>
  30 #include <com/sun/star/lang/IndexOutOfBoundsException.hpp>
  31
  32 using namespace ::com::sun::star::accessibility;
  33 using namespace ::com::sun::star::awt;
  34 using namespace ::com::sun::star::lang;
  35 using namespace ::com::sun::star::uno;
  36
  37 // Wrapper for XAccessibleText, XAccessibleEditableText and XAccessibleMultiLineText
  38
  39 @implementation AquaA11yTextWrapper : NSObject
  40
  41 +(id)valueAttributeForElement:(AquaA11yWrapper *)wrapper {
  42     // Related tdf#158914: explicitly call autorelease selector
  43     // CreateNSString() is not a getter. It expects the caller to
  44     // release the returned string.
  45     return [ CreateNSString ( [ wrapper accessibleText ] -> getText() ) autorelease ];
  46 }
  47
  48 +(void)setValueAttributeForElement:(AquaA11yWrapper *)wrapper to:(id)value
  49 {
  50     // TODO
  51     (void)wrapper;
  52     (void)value;
  53 }
  54
  55 +(id)numberOfCharactersAttributeForElement:(AquaA11yWrapper *)wrapper {
  56     return [ NSNumber numberWithLong: [ wrapper accessibleText ] -> getCharacterCount() ];
  57 }
  58
  59 +(id)selectedTextAttributeForElement:(AquaA11yWrapper *)wrapper {
  60     // Related tdf#158914: explicitly call autorelease selector
  61     // CreateNSString() is not a getter. It expects the caller to
  62     // release the returned string.
  63     return [ CreateNSString ( [ wrapper accessibleText ] -> getSelectedText() ) autorelease ];
  64 }
  65
  66 +(void)setSelectedTextAttributeForElement:(AquaA11yWrapper *)wrapper to:(id)value {
  67     if ( [ wrapper accessibleEditableText ] ) {
  68         NSAutoreleasePool * pool = [ [ NSAutoreleasePool alloc ] init ];
  69         OUString newText = GetOUString ( static_cast<NSString *>(value) );
  70         NSRange selectedTextRange = [ [ AquaA11yTextWrapper selectedTextRangeAttributeForElement: wrapper ] rangeValue ];
  71         try {
  72             [ wrapper accessibleEditableText ] -> replaceText ( selectedTextRange.location, selectedTextRange.location + selectedTextRange.length, newText );
  73         } catch ( const Exception & ) {
  74             // empty
  75         }
  76         [ pool release ];
  77     }
  78 }
  79
  80 +(id)selectedTextRangeAttributeForElement:(AquaA11yWrapper *)wrapper {
  81     sal_Int32 start = [ wrapper accessibleText ] -> getSelectionStart();
  82     sal_Int32 end = [ wrapper accessibleText ] -> getSelectionEnd();
  83     if ( start != end ) {
  84         return [ NSValue valueWithRange: NSMakeRange ( start, end - start ) ]; // true selection
  85     } else {
  86         sal_Int32 caretPos = [ wrapper accessibleText ] -> getCaretPosition();
  87         if ( caretPos < 0 || caretPos > [ wrapper accessibleText ] -> getCharacterCount() ) {
  88             return nil;
  89         }
  90         return [ NSValue valueWithRange: NSMakeRange ( caretPos, 0 ) ]; // insertion point
  91     }
  92 }
  93
  94 +(void)setSelectedTextRangeAttributeForElement:(AquaA11yWrapper *)wrapper to:(id)value {
  95     NSRange range = [ value rangeValue ];
  96     try {
  97         [ wrapper accessibleText ] -> setSelection ( range.location, range.location + range.length );
  98     } catch ( const Exception & ) {
  99         // empty
 100     }
 101 }
 102
 103 +(id)visibleCharacterRangeAttributeForElement:(AquaA11yWrapper *)wrapper {
 104     // the OOo a11y API returns only the visible portion...
 105     return [ NSValue valueWithRange: NSMakeRange ( 0, [ wrapper accessibleText ] -> getCharacterCount() ) ];
 106 }
 107
 108 +(void)setVisibleCharacterRangeAttributeForElement:(AquaA11yWrapper *)wrapper to:(id)value
 109 {
 110     // do nothing
 111     (void)wrapper;
 112     (void)value;
 113 }
 114
 115 +(id)sharedTextUIElementsAttributeForElement:(AquaA11yWrapper *)wrapper
 116 {
 117     return [NSArray arrayWithObject:wrapper];
 118 }
 119
 120 +(id)sharedCharacterRangeAttributeForElement:(AquaA11yWrapper *)wrapper
 121 {
 122     return [ NSValue valueWithRange: NSMakeRange ( 0, [wrapper accessibleText]->getCharacterCount() ) ];
 123 }
 124
 125 +(void)addAttributeNamesTo:(NSMutableArray *)attributeNames {
 126     [ attributeNames addObjectsFromArray: [ AquaA11yTextWrapper specialAttributeNames ] ];
 127 }
 128
 129 +(NSArray *)specialAttributeNames {
 130     return [ NSArray arrayWithObjects:
 131             NSAccessibilityValueAttribute,
 132             NSAccessibilityNumberOfCharactersAttribute,
 133             NSAccessibilitySelectedTextAttribute,
 134             NSAccessibilitySelectedTextRangeAttribute,
 135             NSAccessibilityVisibleCharacterRangeAttribute,
 136             NSAccessibilitySharedTextUIElementsAttribute,
 137             NSAccessibilitySharedCharacterRangeAttribute,
 138             nil ];
 139 }
 140
 141 +(void)addParameterizedAttributeNamesTo:(NSMutableArray *)attributeNames {
 142     [ attributeNames addObjectsFromArray: [ AquaA11yTextWrapper specialParameterizedAttributeNames ] ];
 143 }
 144
 145 +(NSArray *)specialParameterizedAttributeNames {
 146     return [ NSArray arrayWithObjects:
 147             NSAccessibilityStringForRangeParameterizedAttribute,
 148             NSAccessibilityAttributedStringForRangeParameterizedAttribute,
 149             NSAccessibilityRangeForIndexParameterizedAttribute,
 150             NSAccessibilityRangeForPositionParameterizedAttribute,
 151             NSAccessibilityBoundsForRangeParameterizedAttribute,
 152             NSAccessibilityStyleRangeForIndexParameterizedAttribute,
 153             NSAccessibilityRTFForRangeParameterizedAttribute,
 154             NSAccessibilityLineForIndexParameterizedAttribute,
 155             NSAccessibilityRangeForLineParameterizedAttribute,
 156             nil ];
 157 }
 158
 159 +(id)lineForIndexAttributeForElement:(AquaA11yWrapper *)wrapper forParameter:(id)index {
 160     NSNumber * lineNumber = nil;
 161     try {
 162         sal_Int32 line = [ wrapper accessibleMultiLineText ] -> getLineNumberAtIndex ( static_cast<sal_Int32>([ index intValue ]) );
 163         lineNumber = [ NSNumber numberWithInt: line ];
 164     } catch ( IndexOutOfBoundsException & ) {
 165         // empty
 166     }
 167     return lineNumber;
 168 }
 169
 170 +(id)rangeForLineAttributeForElement:(AquaA11yWrapper *)wrapper forParameter:(id)line {
 171     NSValue * range = nil;
 172     try {
 173         TextSegment textSegment = [ wrapper accessibleMultiLineText ] -> getTextAtLineNumber ( [ line intValue ] );
 174         range = [ NSValue valueWithRange: NSMakeRange ( textSegment.SegmentStart, textSegment.SegmentEnd - textSegment.SegmentStart ) ];
 175     } catch ( IndexOutOfBoundsException & ) {
 176         // empty
 177     }
 178     return range;
 179 }
 180
 181 +(id)stringForRangeAttributeForElement:(AquaA11yWrapper *)wrapper forParameter:(id)range {
 182     int loc = [ range rangeValue ].location;
 183     int len = [ range rangeValue ].length;
 184     NSMutableString * textRange = [ NSMutableString string ];
 185     try {
 186         // Related tdf#158914: explicitly call autorelease selector
 187         // CreateNSString() is not a getter. It expects the caller to
 188         // release the returned string.
 189         [ textRange appendString: [ CreateNSString ( [ wrapper accessibleText ] -> getTextRange ( loc, loc + len ) ) autorelease ] ];
 190     } catch ( IndexOutOfBoundsException & ) {
 191         // empty
 192     }
 193     return textRange;
 194 }
 195
 196 +(id)attributedStringForRangeAttributeForElement:(AquaA11yWrapper *)wrapper forParameter:(id)range {
 197     return [ AquaA11yTextAttributesWrapper createAttributedStringForElement: wrapper inOrigRange: range ];
 198 }
 199
 200 +(id)rangeForIndexAttributeForElement:(AquaA11yWrapper *)wrapper forParameter:(id)index {
 201     NSValue * range = nil;
 202     try {
 203         TextSegment textSegment = [ wrapper accessibleText ] -> getTextBeforeIndex ( [ index intValue ], AccessibleTextType::GLYPH );
 204         range = [ NSValue valueWithRange: NSMakeRange ( textSegment.SegmentStart, textSegment.SegmentEnd - textSegment.SegmentStart ) ];
 205     } catch ( IndexOutOfBoundsException & ) {
 206         // empty
 207     } catch ( IllegalArgumentException & ) {
 208         // empty
 209     }
 210     return range;
 211 }
 212
 213 +(id)rangeForPositionAttributeForElement:(AquaA11yWrapper *)wrapper forParameter:(id)point {
 214     NSValue * value = nil;
 215     css::awt::Point aPoint( [ AquaA11yUtil nsPointToVclPoint: point ]);
 216     const css::awt::Point screenPos = [ wrapper accessibleComponent ] -> getLocationOnScreen();
 217     aPoint.X -= screenPos.X;
 218     aPoint.Y -= screenPos.Y;
 219     sal_Int32 index = [ wrapper accessibleText ] -> getIndexAtPoint( aPoint );
 220     if ( index > -1 ) {
 221         value = [ AquaA11yTextWrapper rangeForIndexAttributeForElement: wrapper forParameter: [ NSNumber numberWithLong: index ] ];
 222     }
 223     return value;
 224 }
 225
 226 +(id)boundsForRangeAttributeForElement:(AquaA11yWrapper *)wrapper forParameter:(id)range {
 227     NSValue * rect = nil;
 228     try {
 229         // TODO: this is ugly!!!
 230         // the UNP-API can only return the bounds for a single character, not for a range
 231         int loc = [ range rangeValue ].location;
 232         int len = [ range rangeValue ].length;
 233         int minx = 0x7fffffff, miny = 0x7fffffff, maxx = 0, maxy = 0;
 234         for ( int i = 0; i < len; i++ ) {
 235             Rectangle vclRect = [ wrapper accessibleText ] -> getCharacterBounds ( loc + i );
 236             if ( vclRect.X < minx ) {
 237                 minx = vclRect.X;
 238             }
 239             if ( vclRect.Y < miny ) {
 240                 miny = vclRect.Y;
 241             }
 242             if ( vclRect.Width + vclRect.X > maxx ) {
 243                 maxx = vclRect.Width + vclRect.X;
 244             }
 245             if ( vclRect.Height + vclRect.Y > maxy ) {
 246                 maxy = vclRect.Height + vclRect.Y;
 247             }
 248         }
 249         if ( [ wrapper accessibleComponent ] ) {
 250             // get location on screen (must be added since get CharacterBounds returns values relative to parent)
 251             css::awt::Point screenPos = [ wrapper accessibleComponent ] -> getLocationOnScreen();
 252             css::awt::Point pos ( minx + screenPos.X, miny + screenPos.Y );
 253             css::awt::Point size ( maxx - minx, maxy - miny );
 254             NSValue * nsPos = [ AquaA11yUtil vclPointToNSPoint: pos ];
 255             rect = [ NSValue valueWithRect: NSMakeRect ( [ nsPos pointValue ].x, [ nsPos pointValue ].y - size.Y, size.X, size.Y ) ];
 256             //printf("Range: %s --- Rect: %s\n", [ NSStringFromRange ( [ range rangeValue ] ) UTF8String ], [ NSStringFromRect ( [ rect rectValue ] ) UTF8String ]);
 257         }
 258     } catch ( IndexOutOfBoundsException & ) {
 259         // empty
 260     }
 261     return rect;
 262 }
 263
 264 +(id)styleRangeForIndexAttributeForElement:(AquaA11yWrapper *)wrapper forParameter:(id)index {
 265     NSValue * range = nil;
 266     try {
 267         TextSegment textSegment = [ wrapper accessibleText ] -> getTextAtIndex ( [ index intValue ], AccessibleTextType::ATTRIBUTE_RUN );
 268         range = [ NSValue valueWithRange: NSMakeRange ( textSegment.SegmentStart, textSegment.SegmentEnd - textSegment.SegmentStart ) ];
 269     } catch ( IndexOutOfBoundsException & ) {
 270         // empty
 271     } catch ( IllegalArgumentException & ) {
 272         // empty
 273     }
 274     return range;
 275 }
 276
 277 +(id)rTFForRangeAttributeForElement:(AquaA11yWrapper *)wrapper forParameter:(id)range {
 278     NSData * rtfData = nil;
 279     NSAttributedString * attrString = static_cast<NSAttributedString *>([ AquaA11yTextWrapper attributedStringForRangeAttributeForElement: wrapper forParameter: range ]);
 280     if ( attrString != nil ) {
 281         @try {
 282             rtfData = [ attrString RTFFromRange: [ range rangeValue ] documentAttributes: @{NSDocumentTypeDocumentAttribute : NSRTFTextDocumentType} ];
 283         } @catch ( NSException *) {
 284             // empty
 285         }
 286     }
 287     return rtfData;
 288 }
 289
 290 +(BOOL)isAttributeSettable:(NSString *)attribute forElement:(AquaA11yWrapper *)wrapper {
 291     bool isSettable = false;
 292     if ( [ attribute isEqualToString: NSAccessibilityValueAttribute ]
 293       || [ attribute isEqualToString: NSAccessibilitySelectedTextAttribute ]
 294       || [ attribute isEqualToString: NSAccessibilitySelectedTextRangeAttribute ]
 295       || [ attribute isEqualToString: NSAccessibilityVisibleCharacterRangeAttribute ] ) {
 296         if ( ! [ [ wrapper accessibilityAttributeValue: NSAccessibilityRoleAttribute ] isEqualToString: NSAccessibilityStaticTextRole ] ) {
 297             isSettable = true;
 298         }
 299     }
 300     return isSettable;
 301 }
 302
 303 @end
 304
 305 /* vim:set shiftwidth=4 softtabstop=4 expandtab: */