fpicker/source/aqua/SalAquaFilePicker.mm

   1 /* -*- Mode: C++; tab-width: 4; indent-tabs-mode: nil; c-basic-offset: 4 -*- */
   2 /*
   3  * This file is part of the LibreOffice project.
   4  *
   5  * This Source Code Form is subject to the terms of the Mozilla Public
   6  * License, v. 2.0. If a copy of the MPL was not distributed with this
   7  * file, You can obtain one at http://mozilla.org/MPL/2.0/.
   8  *
   9  * This file incorporates work covered by the following license notice:
  10  *
  11  *   Licensed to the Apache Software Foundation (ASF) under one or more
  12  *   contributor license agreements. See the NOTICE file distributed
  13  *   with this work for additional information regarding copyright
  14  *   ownership. The ASF licenses this file to you under the Apache
  15  *   License, Version 2.0 (the "License"); you may not use this file
  16  *   except in compliance with the License. You may obtain a copy of
  17  *   the License at http://www.apache.org/licenses/LICENSE-2.0 .
  18  */
  19
  20 #include "sal/config.h"
  21
  22 #include <com/sun/star/lang/DisposedException.hpp>
  23 #include <com/sun/star/lang/XMultiServiceFactory.hpp>
  24 #include <com/sun/star/ui/dialogs/ExecutableDialogResults.hpp>
  25 #include <com/sun/star/ui/dialogs/CommonFilePickerElementIds.hpp>
  26 #include <com/sun/star/ui/dialogs/ExtendedFilePickerElementIds.hpp>
  27 #include <cppuhelper/interfacecontainer.h>
  28 #include <osl/diagnose.h>
  29 #include <com/sun/star/ui/dialogs/TemplateDescription.hpp>
  30 #include <com/sun/star/ui/dialogs/ControlActions.hpp>
  31 #include <com/sun/star/uno/Any.hxx>
  32 #include <FPServiceInfo.hxx>
  33 #include <osl/mutex.hxx>
  34 #include <vcl/svapp.hxx>
  35
  36 #include "resourceprovider.hxx"
  37
  38 #include <osl/file.hxx>
  39 #include "CFStringUtilities.hxx"
  40 #include "NSString_OOoAdditions.hxx"
  41 #include "NSURL_OOoAdditions.hxx"
  42
  43 #include <iostream>
  44
  45 #include "SalAquaFilePicker.hxx"
  46
  47 #include <objc/objc-runtime.h>
  48
  49 #pragma mark DEFINES
  50
  51 #define CLASS_NAME "SalAquaFilePicker"
  52
  53 //------------------------------------------------------------------------
  54 // namespace directives
  55 //------------------------------------------------------------------------
  56
  57 using namespace ::com::sun::star;
  58 using namespace ::com::sun::star::ui::dialogs;
  59 using namespace ::com::sun::star::ui::dialogs::TemplateDescription;
  60 using namespace ::com::sun::star::ui::dialogs::ExtendedFilePickerElementIds;
  61 using namespace ::com::sun::star::ui::dialogs::CommonFilePickerElementIds;
  62 using namespace ::com::sun::star::lang;
  63 using namespace ::com::sun::star::beans;
  64 using namespace ::com::sun::star::uno;
  65
  66 //------------------------------------------------------------------------
  67 // helper functions
  68 //------------------------------------------------------------------------
  69
  70 namespace
  71 {
  72     // controling event notifications
  73     const bool STARTUP_SUSPENDED = true;
  74     const bool STARTUP_ALIVE     = false;
  75
  76     uno::Sequence<rtl::OUString> SAL_CALL FilePicker_getSupportedServiceNames()
  77     {
  78         uno::Sequence<rtl::OUString> aRet(3);
  79         aRet[0] = rtl::OUString(RTL_CONSTASCII_USTRINGPARAM( "com.sun.star.ui.dialogs.FilePicker" ));
  80         aRet[1] = rtl::OUString(RTL_CONSTASCII_USTRINGPARAM( "com.sun.star.ui.dialogs.SystemFilePicker" ));
  81         aRet[2] = rtl::OUString(RTL_CONSTASCII_USTRINGPARAM( "com.sun.star.ui.dialogs.AquaFilePicker" ));
  82         return aRet;
  83     }
  84 }
  85
  86 #pragma mark Constructor
  87 //-----------------------------------------------------------------------------------------
  88 // constructor
  89 //-----------------------------------------------------------------------------------------
  90
  91 SalAquaFilePicker::SalAquaFilePicker()
  92   : SalAquaFilePicker_Base( m_rbHelperMtx )
  93    , m_pFilterHelper( NULL )
  94 {
  95     DBG_PRINT_ENTRY(CLASS_NAME, __func__);
  96
  97     m_pDelegate = [[AquaFilePickerDelegate alloc] initWithFilePicker:this];
  98     m_pControlHelper->setFilePickerDelegate(m_pDelegate);
  99
 100     DBG_PRINT_EXIT(CLASS_NAME, __func__);
 101 }
 102
 103 SalAquaFilePicker::~SalAquaFilePicker()
 104 {
 105     DBG_PRINT_ENTRY(CLASS_NAME, __func__);
 106
 107     if (NULL != m_pFilterHelper)
 108         delete m_pFilterHelper;
 109
 110     [m_pDelegate release];
 111
 112     DBG_PRINT_EXIT(CLASS_NAME, __func__);
 113 }
 114
 115
 116 #pragma mark XFilePickerNotifier
 117 //------------------------------------------------------------------------------------
 118 // XFilePickerNotifier
 119 //------------------------------------------------------------------------------------
 120
 121 void SAL_CALL SalAquaFilePicker::addFilePickerListener( const uno::Reference<XFilePickerListener>& xListener )
 122     throw( uno::RuntimeException )
 123 {
 124     DBG_PRINT_ENTRY(CLASS_NAME, __func__);
 125
 126     SolarMutexGuard aGuard;
 127     m_xListener = xListener;
 128
 129     DBG_PRINT_EXIT(CLASS_NAME, __func__);
 130 }
 131
 132 void SAL_CALL SalAquaFilePicker::removeFilePickerListener( const uno::Reference<XFilePickerListener>& )
 133     throw( uno::RuntimeException )
 134 {
 135     DBG_PRINT_ENTRY(CLASS_NAME, __func__);
 136
 137     SolarMutexGuard aGuard;
 138     m_xListener.clear();
 139
 140     DBG_PRINT_EXIT(CLASS_NAME, __func__);
 141 }
 142
 143 #pragma mark XAsynchronousExecutableDialog
 144 //-----------------------------------------------------------------------------------------
 145 // XExecutableDialog functions
 146 //-----------------------------------------------------------------------------------------
 147 void SAL_CALL SalAquaFilePicker::setTitle( const rtl::OUString& aTitle ) throw( uno::RuntimeException )
 148 {
 149     DBG_PRINT_ENTRY(CLASS_NAME, __func__, "title", aTitle);
 150
 151     SolarMutexGuard aGuard;
 152     implsetTitle(aTitle);
 153
 154     DBG_PRINT_EXIT(CLASS_NAME, __func__);
 155 }
 156
 157 sal_Int16 SAL_CALL SalAquaFilePicker::execute() throw( uno::RuntimeException )
 158 {
 159     DBG_PRINT_ENTRY(CLASS_NAME, __func__);
 160
 161     SolarMutexGuard aGuard;
 162
 163     sal_Int16 retVal = 0;
 164
 165     implInitialize();
 166
 167     // if m_pDialog is nil after initialization, something must have gone wrong before
 168     // or there was no initialization (see issue http://www.openoffice.org/issues/show_bug.cgi?id=100214)
 169     if (m_pDialog == nil) {
 170         m_nDialogType = NAVIGATIONSERVICES_OPEN;
 171     }
 172
 173     if (m_pFilterHelper) {
 174         m_pFilterHelper->SetFilters();
 175     }
 176
 177     if (m_nDialogType == NAVIGATIONSERVICES_SAVE) {
 178         if (m_sSaveFileName.getLength() == 0) {
 179             //if no filename is set, NavigationServices will set the name to "untitled". We don't want this!
 180             //So let's try to get the window title to get the real untitled name
 181             NSWindow *frontWindow = [NSApp keyWindow];
 182             if (NULL != frontWindow) {
 183                 NSString *windowTitle = [frontWindow title];
 184                 if (windowTitle != nil) {
 185                     rtl::OUString ouName = [windowTitle OUString];
 186                     //a window title will typically be something like "Untitled1 - OpenOffice.org Writer"
 187                     //but we only want the "Untitled1" part of it
 188                     sal_Int32 indexOfDash = ouName.indexOf(rtl::OUString(RTL_CONSTASCII_USTRINGPARAM(" - ")));
 189                     if (indexOfDash > -1) {
 190                         m_sSaveFileName = ouName.copy(0,indexOfDash);
 191                         if (m_sSaveFileName.getLength() > 0) {
 192                             setDefaultName(m_sSaveFileName);
 193                         }
 194                     } else {
 195                         OSL_TRACE("no dash present in window title");
 196                     }
 197                 } else {
 198                     OSL_TRACE("couldn't get window title");
 199                 }
 200             } else {
 201                 OSL_TRACE("no front window found");
 202             }
 203         }
 204     }
 205
 206     //Set the delegate to be notified of certain events
 207
 208     // I don't know why, but with gcc 4.2.1, this line results in the warning:
 209     // class 'AquaFilePickerDelegate' does not implement the 'NSOpenSavePanelDelegate' protocol
 210     // So instead of:
 211     // [m_pDialog setDelegate:m_pDelegate];
 212     // do:
 213     objc_msgSend(m_pDialog, @selector(setDelegate:), m_pDelegate);
 214
 215     int nStatus = runandwaitforresult();
 216
 217     [m_pDialog setDelegate:nil];
 218
 219     switch( nStatus )
 220     {
 221         case NSOKButton:
 222             OSL_TRACE("The dialog returned OK");
 223             retVal = ExecutableDialogResults::OK;
 224             break;
 225
 226         case NSCancelButton:
 227             OSL_TRACE("The dialog was cancelled by the user!");
 228             retVal = ExecutableDialogResults::CANCEL;
 229             break;
 230
 231         default:
 232             throw uno::RuntimeException(
 233                       rtl::OUString("The dialog returned with an unknown result!"),
 234                       static_cast<XFilePicker*>( static_cast<XFilePicker3*>( this ) ));
 235             break;
 236     }
 237
 238     DBG_PRINT_EXIT(CLASS_NAME, __func__, retVal);
 239
 240     return retVal;
 241 }
 242
 243
 244 #pragma mark XFilePicker
 245 //-----------------------------------------------------------------------------------------
 246 // XFilePicker functions
 247 //-----------------------------------------------------------------------------------------
 248
 249 void SAL_CALL SalAquaFilePicker::setMultiSelectionMode( sal_Bool bMode ) throw( uno::RuntimeException )
 250 {
 251     DBG_PRINT_ENTRY(CLASS_NAME, __func__, "multiSelectable?", bMode);
 252
 253     SolarMutexGuard aGuard;
 254
 255     if (m_nDialogType == NAVIGATIONSERVICES_OPEN) {
 256         [(NSOpenPanel*)m_pDialog setAllowsMultipleSelection:YES];
 257         OSL_TRACE("dialog allows multi-selection? %d", [(NSOpenPanel*)m_pDialog allowsMultipleSelection]);
 258     }
 259
 260     DBG_PRINT_EXIT(CLASS_NAME, __func__);
 261 }
 262
 263 void SAL_CALL SalAquaFilePicker::setDefaultName( const rtl::OUString& aName )
 264 throw( uno::RuntimeException )
 265 {
 266     DBG_PRINT_ENTRY(CLASS_NAME, __func__, "name", aName);
 267
 268     SolarMutexGuard aGuard;
 269
 270     m_sSaveFileName = aName;
 271
 272     DBG_PRINT_EXIT(CLASS_NAME, __func__);
 273 }
 274
 275 void SAL_CALL SalAquaFilePicker::setDisplayDirectory( const rtl::OUString& rDirectory )
 276 throw( lang::IllegalArgumentException, uno::RuntimeException )
 277 {
 278     DBG_PRINT_ENTRY(CLASS_NAME, __func__, "directory", rDirectory);
 279
 280     SolarMutexGuard aGuard;
 281
 282     implsetDisplayDirectory(rDirectory);
 283
 284     DBG_PRINT_EXIT(CLASS_NAME, __func__);
 285 }
 286
 287 rtl::OUString SAL_CALL SalAquaFilePicker::getDisplayDirectory() throw( uno::RuntimeException )
 288 {
 289     DBG_PRINT_ENTRY(CLASS_NAME, __func__);
 290
 291     rtl::OUString retVal = implgetDisplayDirectory();
 292
 293     DBG_PRINT_EXIT(CLASS_NAME, __func__, retVal);
 294     return retVal;
 295 }
 296
 297 uno::Sequence<rtl::OUString> SAL_CALL SalAquaFilePicker::getFiles() throw( uno::RuntimeException )
 298 {
 299     DBG_PRINT_ENTRY(CLASS_NAME, __func__);
 300
 301     SolarMutexGuard aGuard;
 302
 303     // OSL_TRACE("starting work");
 304     /*
 305      * If more than one file is selected in an OpenDialog, then the first result
 306      * is the directory and the remaining results contain just the files' names
 307      * without the basedir path.
 308      */
 309     NSArray *files = nil;
 310     if (m_nDialogType == NAVIGATIONSERVICES_OPEN) {
 311         files = [(NSOpenPanel*)m_pDialog URLs];
 312     }
 313     else if (m_nDialogType == NAVIGATIONSERVICES_SAVE) {
 314         files = [NSArray arrayWithObjects:[m_pDialog URL], nil];
 315     }
 316
 317     long nFiles = [files count];
 318     OSL_TRACE("# of items: %d", nFiles);
 319
 320     uno::Sequence< rtl::OUString > aSelectedFiles(nFiles > 1 ? nFiles + 1 : nFiles);
 321
 322     for(int nIndex = 0; nIndex < nFiles; nIndex += 1)
 323     {
 324         NSURL *url = [files objectAtIndex:nIndex];
 325         OSL_TRACE("handling %s", [[url description] UTF8String]);
 326         InfoType info = FULLPATH;
 327         if (nFiles > 1) {
 328             //just get the file's name (only in OpenDialog)
 329             info = FILENAME;
 330         }
 331         OUString sFileOrDirURL = [url OUStringForInfo:info];
 332
 333         //get the directory information, only on the first file processed
 334         if (nIndex == 0) {
 335             OUString sDirectoryURL = [url OUStringForInfo:PATHWITHOUTLASTCOMPONENT];
 336
 337             if (nFiles > 1) {
 338                 aSelectedFiles[0] = OUString(sDirectoryURL);
 339             }
 340         }
 341
 342         short nSequenceIndex = nFiles > 1 ? nIndex + 1 : nIndex;
 343         aSelectedFiles[nSequenceIndex] = sFileOrDirURL;
 344
 345         OSL_TRACE("Returned file in getFiles: \"%s\".", OUStringToOString(sFileOrDirURL, RTL_TEXTENCODING_UTF8).getStr());
 346     }
 347
 348     DBG_PRINT_EXIT(CLASS_NAME, __func__);
 349     return aSelectedFiles;
 350 }
 351
 352 #pragma mark XFilterManager
 353 //-----------------------------------------------------------------------------------------
 354 // XFilterManager functions
 355 //-----------------------------------------------------------------------------------------
 356
 357 void SAL_CALL SalAquaFilePicker::appendFilter( const rtl::OUString& aTitle, const rtl::OUString& aFilter )
 358 throw( lang::IllegalArgumentException, uno::RuntimeException )
 359 {
 360     DBG_PRINT_ENTRY(CLASS_NAME, __func__);
 361
 362     SolarMutexGuard aGuard;
 363
 364     ensureFilterHelper();
 365     m_pFilterHelper->appendFilter( aTitle, aFilter );
 366     m_pControlHelper->setFilterControlNeeded(YES);
 367
 368     DBG_PRINT_EXIT(CLASS_NAME, __func__);
 369 }
 370
 371 void SAL_CALL SalAquaFilePicker::setCurrentFilter( const rtl::OUString& aTitle )
 372 throw( lang::IllegalArgumentException, uno::RuntimeException )
 373 {
 374     DBG_PRINT_ENTRY(CLASS_NAME, __func__);
 375     OSL_TRACE( "Setting current filter to %s",
 376                OUStringToOString( aTitle, RTL_TEXTENCODING_UTF8 ).getStr() );
 377
 378     SolarMutexGuard aGuard;
 379
 380     ensureFilterHelper();
 381     m_pFilterHelper->setCurrentFilter(aTitle);
 382     updateFilterUI();
 383
 384     updateSaveFileNameExtension();
 385
 386     DBG_PRINT_EXIT(CLASS_NAME, __func__);
 387 }
 388
 389 rtl::OUString SAL_CALL SalAquaFilePicker::getCurrentFilter() throw( uno::RuntimeException )
 390 {
 391     DBG_PRINT_ENTRY(CLASS_NAME, __func__);
 392     SolarMutexGuard aGuard;
 393
 394     ensureFilterHelper();
 395
 396     DBG_PRINT_EXIT(CLASS_NAME, __func__);
 397     return m_pFilterHelper->getCurrentFilter();
 398 }
 399
 400 #pragma mark XFilterGroupManager
 401 //-----------------------------------------------------------------------------------------
 402 // XFilterGroupManager functions
 403 //-----------------------------------------------------------------------------------------
 404
 405 void SAL_CALL SalAquaFilePicker::appendFilterGroup( const rtl::OUString& sGroupTitle, const uno::Sequence<beans::StringPair>& aFilters )
 406 throw( lang::IllegalArgumentException, uno::RuntimeException )
 407 {
 408     DBG_PRINT_ENTRY(CLASS_NAME, __func__);
 409     SolarMutexGuard aGuard;
 410
 411     ensureFilterHelper();
 412     m_pFilterHelper->appendFilterGroup(sGroupTitle, aFilters);
 413     m_pControlHelper->setFilterControlNeeded(YES);
 414     DBG_PRINT_EXIT(CLASS_NAME, __func__);
 415 }
 416
 417 #pragma mark XFilePickerControlAccess
 418 //------------------------------------------------------------------------------------
 419 // XFilePickerControlAccess functions
 420 //------------------------------------------------------------------------------------
 421
 422 void SAL_CALL SalAquaFilePicker::setValue( sal_Int16 nControlId, sal_Int16 nControlAction, const uno::Any& rValue )
 423 throw( uno::RuntimeException )
 424 {
 425     DBG_PRINT_ENTRY(CLASS_NAME, __func__);
 426
 427     SolarMutexGuard aGuard;
 428
 429     m_pControlHelper->setValue(nControlId, nControlAction, rValue);
 430
 431     if (nControlId == ExtendedFilePickerElementIds::CHECKBOX_AUTOEXTENSION && m_nDialogType == NAVIGATIONSERVICES_SAVE) {
 432         updateSaveFileNameExtension();
 433     }
 434
 435     DBG_PRINT_EXIT(CLASS_NAME, __func__);
 436 }
 437
 438 uno::Any SAL_CALL SalAquaFilePicker::getValue( sal_Int16 nControlId, sal_Int16 nControlAction )
 439 throw( uno::RuntimeException )
 440 {
 441     DBG_PRINT_ENTRY(CLASS_NAME, __func__);
 442
 443     uno::Any aValue = m_pControlHelper->getValue(nControlId, nControlAction);
 444
 445     DBG_PRINT_EXIT(CLASS_NAME, __func__);
 446     return aValue;
 447 }
 448
 449 void SAL_CALL SalAquaFilePicker::enableControl( sal_Int16 nControlId, sal_Bool bEnable )
 450 throw( uno::RuntimeException )
 451 {
 452     DBG_PRINT_ENTRY(CLASS_NAME, __func__);
 453
 454     m_pControlHelper->enableControl(nControlId, bEnable);
 455
 456     DBG_PRINT_EXIT(CLASS_NAME, __func__);
 457 }
 458
 459 void SAL_CALL SalAquaFilePicker::setLabel( sal_Int16 nControlId, const ::rtl::OUString& aLabel )
 460 throw( uno::RuntimeException )
 461 {
 462     DBG_PRINT_ENTRY(CLASS_NAME, __func__);
 463
 464     SolarMutexGuard aGuard;
 465
 466     NSString* sLabel = [NSString stringWithOUString:aLabel];
 467     m_pControlHelper->setLabel( nControlId, sLabel ) ;
 468
 469     DBG_PRINT_EXIT(CLASS_NAME, __func__);
 470 }
 471
 472 rtl::OUString SAL_CALL SalAquaFilePicker::getLabel( sal_Int16 nControlId )
 473 throw( uno::RuntimeException )
 474 {
 475     DBG_PRINT_ENTRY(CLASS_NAME, __func__);
 476     DBG_PRINT_EXIT(CLASS_NAME, __func__);
 477
 478     return m_pControlHelper->getLabel(nControlId);
 479 }
 480
 481 #pragma mark XInitialization
 482 //------------------------------------------------------------------------------------
 483 // XInitialization
 484 //------------------------------------------------------------------------------------
 485
 486 void SAL_CALL SalAquaFilePicker::initialize( const uno::Sequence<uno::Any>& aArguments )
 487 throw( uno::Exception, uno::RuntimeException )
 488 {
 489     DBG_PRINT_ENTRY(CLASS_NAME, __func__, "arguments size", aArguments.getLength());
 490
 491     SolarMutexGuard aGuard;
 492
 493     // parameter checking
 494     uno::Any aAny;
 495     if( 0 == aArguments.getLength() )
 496         throw lang::IllegalArgumentException(rtl::OUString("no arguments"),
 497                                              static_cast<XFilePicker*>( static_cast<XFilePicker3*>(this) ), 1 );
 498
 499     aAny = aArguments[0];
 500
 501     if( ( aAny.getValueType() != ::getCppuType( ( sal_Int16* )0 ) ) &&
 502         (aAny.getValueType() != ::getCppuType( ( sal_Int8* )0 ) ) )
 503         throw lang::IllegalArgumentException(rtl::OUString( "invalid argument type" ),
 504                                              static_cast<XFilePicker*>( static_cast<XFilePicker3*>(this) ), 1 );
 505
 506     sal_Int16 templateId = -1;
 507     aAny >>= templateId;
 508
 509     switch( templateId )
 510     {
 511         case FILEOPEN_SIMPLE:
 512             m_nDialogType = NAVIGATIONSERVICES_OPEN;
 513             OSL_TRACE( "Template: FILEOPEN_SIMPLE" );
 514             break;
 515         case FILESAVE_SIMPLE:
 516             m_nDialogType = NAVIGATIONSERVICES_SAVE;
 517             OSL_TRACE( "Template: FILESAVE_SIMPLE" );
 518             break;
 519         case FILESAVE_AUTOEXTENSION_PASSWORD:
 520             m_nDialogType = NAVIGATIONSERVICES_SAVE;
 521             OSL_TRACE( "Template: FILESAVE_AUTOEXTENSION_PASSWORD" );
 522             break;
 523         case FILESAVE_AUTOEXTENSION_PASSWORD_FILTEROPTIONS:
 524             m_nDialogType = NAVIGATIONSERVICES_SAVE;
 525             OSL_TRACE( "Template: FILESAVE_AUTOEXTENSION_PASSWORD_FILTEROPTIONS" );
 526             break;
 527         case FILESAVE_AUTOEXTENSION_SELECTION:
 528             m_nDialogType = NAVIGATIONSERVICES_SAVE;
 529             OSL_TRACE( "Template: FILESAVE_AUTOEXTENSION_SELECTION" );
 530             break;
 531         case FILESAVE_AUTOEXTENSION_TEMPLATE:
 532             m_nDialogType = NAVIGATIONSERVICES_SAVE;
 533             OSL_TRACE( "Template: FILESAVE_AUTOEXTENSION_TEMPLATE" );
 534             break;
 535         case FILEOPEN_LINK_PREVIEW_IMAGE_TEMPLATE:
 536             m_nDialogType = NAVIGATIONSERVICES_OPEN;
 537             OSL_TRACE( "Template: FILEOPEN_LINK_PREVIEW_IMAGE_TEMPLATE" );
 538             break;
 539         case FILEOPEN_PLAY:
 540             m_nDialogType = NAVIGATIONSERVICES_OPEN;
 541             OSL_TRACE( "Template: FILEOPEN_PLAY" );
 542             break;
 543         case FILEOPEN_READONLY_VERSION:
 544             m_nDialogType = NAVIGATIONSERVICES_OPEN;
 545             OSL_TRACE( "Template: FILEOPEN_READONLY_VERSION" );
 546             break;
 547         case FILEOPEN_LINK_PREVIEW:
 548             m_nDialogType = NAVIGATIONSERVICES_OPEN;
 549             OSL_TRACE( "Template: FILEOPEN_LINK_PREVIEW" );
 550             break;
 551         case FILESAVE_AUTOEXTENSION:
 552             m_nDialogType = NAVIGATIONSERVICES_SAVE;
 553             OSL_TRACE( "Template: FILESAVE_AUTOEXTENSION" );
 554             break;
 555         default:
 556             throw lang::IllegalArgumentException(rtl::OUString("Unknown template"),
 557                                                  static_cast<XFilePicker*>( static_cast<XFilePicker3*>(this) ),
 558                                                  1 );
 559     }
 560
 561     m_pControlHelper->initialize(templateId);
 562
 563     implInitialize();
 564
 565     DBG_PRINT_EXIT(CLASS_NAME, __func__);
 566 }
 567
 568 #pragma mark XCancellable
 569 //------------------------------------------------------------------------------------
 570 // XCancellable
 571 //------------------------------------------------------------------------------------
 572
 573 void SAL_CALL SalAquaFilePicker::cancel() throw( uno::RuntimeException )
 574 {
 575     DBG_PRINT_ENTRY(CLASS_NAME, __func__);
 576
 577     SolarMutexGuard aGuard;
 578
 579     if (m_pDialog != nil) {
 580         [m_pDialog cancel:nil];
 581     }
 582
 583     DBG_PRINT_EXIT(CLASS_NAME, __func__);
 584 }
 585
 586 #pragma mark XEventListener
 587 //------------------------------------------------
 588 // XEventListener
 589 //------------------------------------------------
 590
 591 void SAL_CALL SalAquaFilePicker::disposing( const lang::EventObject& aEvent ) throw( uno::RuntimeException )
 592 {
 593     DBG_PRINT_ENTRY(CLASS_NAME, __func__);
 594
 595     SolarMutexGuard aGuard;
 596
 597     uno::Reference<XFilePickerListener> xFilePickerListener( aEvent.Source, ::com::sun::star::uno::UNO_QUERY );
 598
 599     if( xFilePickerListener.is() )
 600         removeFilePickerListener( xFilePickerListener );
 601
 602     DBG_PRINT_EXIT(CLASS_NAME, __func__);
 603 }
 604
 605 #pragma mark XServiceInfo
 606 // -------------------------------------------------
 607 // XServiceInfo
 608 // -------------------------------------------------
 609
 610 rtl::OUString SAL_CALL SalAquaFilePicker::getImplementationName()
 611 throw( uno::RuntimeException )
 612 {
 613     DBG_PRINT_ENTRY(CLASS_NAME, __func__);
 614
 615     rtl::OUString retVal(RTL_CONSTASCII_USTRINGPARAM( FILE_PICKER_IMPL_NAME ));
 616
 617     DBG_PRINT_EXIT(CLASS_NAME, __func__, retVal);
 618
 619     return retVal;
 620 }
 621
 622 sal_Bool SAL_CALL SalAquaFilePicker::supportsService( const rtl::OUString& sServiceName )
 623 throw( uno::RuntimeException )
 624 {
 625     DBG_PRINT_ENTRY(CLASS_NAME, __func__, "service name", sServiceName);
 626
 627     sal_Bool retVal = sal_False;
 628
 629     uno::Sequence <rtl::OUString> supportedServicesNames = FilePicker_getSupportedServiceNames();
 630
 631     for( sal_Int32 n = supportedServicesNames.getLength(); n--; ) {
 632         if( supportedServicesNames[n] == sServiceName ) {
 633             retVal = sal_True;
 634             break;
 635         }
 636     }
 637
 638     DBG_PRINT_EXIT(CLASS_NAME, __func__);
 639
 640     return retVal;
 641 }
 642
 643 uno::Sequence<rtl::OUString> SAL_CALL SalAquaFilePicker::getSupportedServiceNames()
 644 throw( uno::RuntimeException )
 645 {
 646     DBG_PRINT_ENTRY(CLASS_NAME, __func__);
 647     DBG_PRINT_EXIT(CLASS_NAME, __func__);
 648
 649     return FilePicker_getSupportedServiceNames();
 650 }
 651
 652 #pragma mark Misc/Private
 653 //-----------------------------------------------------------------------------------------
 654 // FilePicker Event functions
 655 //-----------------------------------------------------------------------------------------
 656
 657 void SAL_CALL SalAquaFilePicker::fileSelectionChanged( FilePickerEvent aEvent )
 658 {
 659     OSL_TRACE( "file selection changed");
 660     if (m_xListener.is())
 661         m_xListener->fileSelectionChanged( aEvent );
 662 }
 663
 664 void SAL_CALL SalAquaFilePicker::directoryChanged( FilePickerEvent aEvent )
 665 {
 666     OSL_TRACE("directory changed");
 667     if (m_xListener.is())
 668         m_xListener->directoryChanged( aEvent );
 669 }
 670
 671 void SAL_CALL SalAquaFilePicker::controlStateChanged( FilePickerEvent aEvent )
 672 {
 673     OSL_TRACE("control state changed");
 674     if (m_xListener.is())
 675         m_xListener->controlStateChanged( aEvent );
 676 }
 677
 678 void SAL_CALL SalAquaFilePicker::dialogSizeChanged()
 679 {
 680     OSL_TRACE("dialog size changed");
 681     if (m_xListener.is())
 682         m_xListener->dialogSizeChanged();
 683 }
 684
 685 //--------------------------------------------------
 686 // Misc
 687 //-------------------------------------------------
 688 void SalAquaFilePicker::ensureFilterHelper() {
 689     DBG_PRINT_ENTRY(CLASS_NAME, __func__);
 690
 691     SolarMutexGuard aGuard;
 692
 693     if (NULL == m_pFilterHelper) {
 694         m_pFilterHelper = new FilterHelper;
 695         m_pControlHelper->setFilterHelper(m_pFilterHelper);
 696         [m_pDelegate setFilterHelper:m_pFilterHelper];
 697     }
 698
 699     DBG_PRINT_EXIT(CLASS_NAME, __func__);
 700 }
 701
 702 void SalAquaFilePicker::implInitialize()
 703 {
 704     DBG_PRINT_ENTRY(CLASS_NAME, __func__);
 705
 706     //call super
 707     SalAquaPicker::implInitialize();
 708
 709     DBG_PRINT_EXIT(CLASS_NAME, __func__);
 710 }
 711
 712 void SalAquaFilePicker::updateFilterUI() {
 713     DBG_PRINT_ENTRY(CLASS_NAME, __func__);
 714
 715     m_pControlHelper->updateFilterUI();
 716
 717     DBG_PRINT_EXIT(CLASS_NAME, __func__);
 718 }
 719
 720 void SalAquaFilePicker::updateSaveFileNameExtension() {
 721     DBG_PRINT_ENTRY(CLASS_NAME, __func__);
 722
 723     if (m_nDialogType != NAVIGATIONSERVICES_SAVE) {
 724         return;
 725     }
 726
 727     // we need to set this here again because initial setting does
 728     //[m_pDialog setExtensionHidden:YES];
 729
 730     SolarMutexGuard aGuard;
 731
 732     if (m_pControlHelper->isAutoExtensionEnabled() == false) {
 733         OSL_TRACE("allowing other file types");
 734         [m_pDialog setAllowedFileTypes:nil];
 735         [m_pDialog setAllowsOtherFileTypes:YES];
 736     } else {
 737         ensureFilterHelper();
 738
 739         OUStringList aStringList = m_pFilterHelper->getCurrentFilterSuffixList();
 740         if( aStringList.empty()) // #i9328#
 741             return;
 742
 743         rtl::OUString suffix = (*(aStringList.begin())).copy(1);
 744         NSString *requiredFileType = [NSString stringWithOUString:suffix];
 745
 746 #if HAVE_GCC_PRAGMA_DIAGNOSTIC_MODIFY && HAVE_GCC_PRAGMA_DIAGNOSTIC_SCOPE
 747 #pragma GCC diagnostic push
 748 #pragma GCC diagnostic warning "-Wdeprecated-declarations"
 749 #endif
 750         [m_pDialog setRequiredFileType:requiredFileType];
 751 #if HAVE_GCC_PRAGMA_DIAGNOSTIC_MODIFY && HAVE_GCC_PRAGMA_DIAGNOSTIC_SCOPE
 752 #pragma GCC diagnostic pop
 753 #endif
 754
 755         OSL_TRACE("disallowing other file types");
 756         [m_pDialog setAllowsOtherFileTypes:NO];
 757     }
 758
 759     DBG_PRINT_EXIT(CLASS_NAME, __func__);
 760 }
 761
 762 void SalAquaFilePicker::filterControlChanged() {
 763     DBG_PRINT_ENTRY(CLASS_NAME, __func__);
 764
 765     if (m_pDialog == nil) {
 766         return;
 767     }
 768
 769     SolarMutexGuard aGuard;
 770
 771     updateSaveFileNameExtension();
 772
 773     [m_pDialog validateVisibleColumns];
 774
 775     FilePickerEvent evt;
 776     evt.ElementId = LISTBOX_FILTER;
 777     controlStateChanged( evt );
 778
 779     DBG_PRINT_EXIT(CLASS_NAME, __func__);
 780 }
 781
 782 /* vim:set shiftwidth=4 softtabstop=4 expandtab: */