fpicker/source/aqua/SalAquaPicker.mm

   1 /* -*- Mode: C++; tab-width: 4; indent-tabs-mode: nil; c-basic-offset: 4 -*- */
   2 /*
   3  * This file is part of the LibreOffice project.
   4  *
   5  * This Source Code Form is subject to the terms of the Mozilla Public
   6  * License, v. 2.0. If a copy of the MPL was not distributed with this
   7  * file, You can obtain one at http://mozilla.org/MPL/2.0/.
   8  *
   9  * This file incorporates work covered by the following license notice:
  10  *
  11  *   Licensed to the Apache Software Foundation (ASF) under one or more
  12  *   contributor license agreements. See the NOTICE file distributed
  13  *   with this work for additional information regarding copyright
  14  *   ownership. The ASF licenses this file to you under the Apache
  15  *   License, Version 2.0 (the "License"); you may not use this file
  16  *   except in compliance with the License. You may obtain a copy of
  17  *   the License at http://www.apache.org/licenses/LICENSE-2.0 .
  18  */
  19
  20 #include "sal/config.h"
  21
  22 #include <com/sun/star/lang/DisposedException.hpp>
  23 #include <com/sun/star/lang/XMultiServiceFactory.hpp>
  24 #include <cppuhelper/interfacecontainer.h>
  25 #include <osl/diagnose.h>
  26 #include <com/sun/star/uno/Any.hxx>
  27 #include <FPServiceInfo.hxx>
  28 #include <osl/mutex.hxx>
  29 #include <vcl/svapp.hxx>
  30 #include "SalAquaPicker.hxx"
  31 #include <osl/file.hxx>
  32 #include "CFStringUtilities.hxx"
  33 #include "NSString_OOoAdditions.hxx"
  34
  35 #include "NSURL_OOoAdditions.hxx"
  36
  37 #include "SalAquaFilePicker.hxx"
  38
  39 #include <stdio.h>
  40
  41 #pragma mark DEFINES
  42 #define CLASS_NAME "SalAquaPicker"
  43 #define kSetHideExtensionStateKey @"NSNavLastUserSetHideExtensionButtonState"
  44
  45 //------------------------------------------------------------------------
  46 // namespace directives
  47 //------------------------------------------------------------------------
  48
  49 using namespace ::rtl;
  50 using namespace ::com::sun::star;
  51 using namespace ::com::sun::star::lang;
  52 using namespace ::com::sun::star::uno;
  53
  54 // constructor
  55 SalAquaPicker::SalAquaPicker()
  56 : m_pDialog(NULL)
  57 , m_pControlHelper(new ControlHelper())
  58 {
  59     DBG_PRINT_ENTRY(CLASS_NAME, __func__);
  60     DBG_PRINT_EXIT(CLASS_NAME, __func__);
  61 }
  62
  63 SalAquaPicker::~SalAquaPicker()
  64 {
  65     DBG_PRINT_ENTRY(CLASS_NAME, __func__);
  66
  67     SolarMutexGuard aGuard;
  68
  69     NSAutoreleasePool *pool = [NSAutoreleasePool new];
  70
  71     if (NULL != m_pControlHelper)
  72         delete m_pControlHelper;
  73
  74     if (NULL != m_pDialog)
  75         [m_pDialog release];
  76
  77     [pool release];
  78
  79     DBG_PRINT_EXIT(CLASS_NAME, __func__);
  80 }
  81
  82 void SAL_CALL SalAquaPicker::implInitialize()
  83 {
  84     DBG_PRINT_ENTRY(CLASS_NAME, __func__);
  85
  86     SolarMutexGuard aGuard;
  87
  88     if (m_pDialog != nil) {
  89         return;
  90     }
  91
  92     switch (m_nDialogType)
  93     {
  94         case NAVIGATIONSERVICES_OPEN:
  95             OSL_TRACE("NAVIGATIONSERVICES_OPEN");
  96             m_pDialog = [NSOpenPanel openPanel];
  97             [(NSOpenPanel*)m_pDialog setCanChooseDirectories:NO];
  98             [(NSOpenPanel*)m_pDialog setCanChooseFiles:YES];
  99             break;
 100
 101         case NAVIGATIONSERVICES_SAVE:
 102             OSL_TRACE("NAVIGATIONSERVICES_SAVE");
 103             m_pDialog = [NSSavePanel savePanel];
 104             [(NSSavePanel*)m_pDialog setCanSelectHiddenExtension:NO]; //changed for issue #102102
 105             /* I would have loved to use
 106              * [(NSSavePanel*)m_pDialog setExtensionHidden:YES];
 107              * here but unfortunately this
 108              * a) only works when the dialog is already displayed because it seems to act on the corresponding checkbox (that we don't show but that doesn't matter)
 109              * b) Mac OS X saves this setting on an application-based level which means that the last state is always being restored again when the app runs for the next time
 110              *
 111              * So the only reliable way seems to be using the NSUserDefaults object because that is where that value is stored and
 112              * to just overwrite it if it has the wrong value.
 113              */
 114             {
 115                 NSUserDefaults *pDefaults = [NSUserDefaults standardUserDefaults];
 116                 NSNumber *pExtn = [pDefaults objectForKey:kSetHideExtensionStateKey];
 117                 if(pExtn == nil || [pExtn boolValue] == NO) {
 118                     OSL_TRACE("Hiding extension");
 119                     [pDefaults setBool:YES forKey:kSetHideExtensionStateKey];
 120                 }
 121             }
 122             break;
 123
 124         case NAVIGATIONSERVICES_DIRECTORY:
 125             OSL_TRACE("NAVIGATIONSERVICES_DIRECTORY");
 126             m_pDialog = [NSOpenPanel openPanel];
 127             [(NSOpenPanel*)m_pDialog setCanChooseDirectories:YES];
 128             [(NSOpenPanel*)m_pDialog setCanChooseFiles:NO];
 129             break;
 130
 131         default:
 132             OSL_TRACE("m_nDialogType is UNKNOWN: %d", m_nDialogType);
 133             break;
 134     }
 135
 136     if (m_pDialog == nil) {
 137         OSL_TRACE("An error occurred while creating the dialog!");
 138     }
 139     else {
 140         [(NSOpenPanel*)m_pDialog setCanCreateDirectories:YES];
 141         //Retain the dialog instance or it will go away immediately
 142         [m_pDialog retain];
 143     }
 144
 145     DBG_PRINT_EXIT(CLASS_NAME, __func__);
 146 }
 147
 148 int SalAquaPicker::run()
 149 {
 150     DBG_PRINT_ENTRY(CLASS_NAME, __func__);
 151
 152     SolarMutexGuard aGuard;
 153
 154     NSAutoreleasePool *pool = [NSAutoreleasePool new];
 155
 156     if (m_pDialog == NULL) {
 157         //this is the case e.g. for the folder picker at this stage
 158         implInitialize();
 159     }
 160
 161     NSView *userPane = m_pControlHelper->getUserPane();
 162     if (userPane != NULL) {
 163         [m_pDialog setAccessoryView:userPane];
 164     }
 165
 166     int retVal = 0;
 167
 168     NSString *startDirectory;
 169     if (m_sDisplayDirectory.getLength() > 0) {
 170         NSString *temp = [NSString stringWithOUString:m_sDisplayDirectory];
 171         NSURL *url = [NSURL URLWithString:temp];
 172         startDirectory = [url path];
 173
 174         OSL_TRACE("start dir: %s", [startDirectory UTF8String]);
 175         // NSLog(@"%@", startDirectory);
 176     }
 177     else {
 178         startDirectory = NSHomeDirectory();
 179     }
 180
 181 #if HAVE_GCC_PRAGMA_DIAGNOSTIC_MODIFY && HAVE_GCC_PRAGMA_DIAGNOSTIC_SCOPE
 182 #pragma GCC diagnostic push
 183 #pragma GCC diagnostic warning "-Wdeprecated-declarations"
 184 #endif
 185     switch(m_nDialogType) {
 186         case NAVIGATIONSERVICES_DIRECTORY:
 187         case NAVIGATIONSERVICES_OPEN:
 188             retVal = [(NSOpenPanel*)m_pDialog runModalForDirectory:startDirectory file:nil types:nil];
 189             break;
 190         case NAVIGATIONSERVICES_SAVE:
 191             retVal = [m_pDialog runModalForDirectory:startDirectory file:[NSString stringWithOUString:((SalAquaFilePicker*)this)->getSaveFileName()]/*[m_pDialog saveFilename]*/];
 192             break;
 193         // [m_pDialog beginSheetForDirectory:startDirectory file:[m_pDialog saveFilename] modalForWindow:[NSApp keyWindow] modalDelegate:((SalAquaFilePicker*)this)->getDelegate() didEndSelector:@selector(savePanelDidEnd:returnCode:contextInfo:) contextInfo:nil];
 194         default:
 195             break;
 196     }
 197
 198     if (retVal == NSFileHandlingPanelOKButton) {
 199         NSString* pDir = [m_pDialog directory];
 200         if (pDir) {
 201             implsetDisplayDirectory([[NSURL fileURLWithPath:pDir] OUStringForInfo:FULLPATH]);
 202         }
 203     }
 204 #if HAVE_GCC_PRAGMA_DIAGNOSTIC_MODIFY && HAVE_GCC_PRAGMA_DIAGNOSTIC_SCOPE
 205 #pragma GCC diagnostic pop
 206 #endif
 207     DBG_PRINT_EXIT(CLASS_NAME, __func__, retVal);
 208
 209     [pool release];
 210
 211     return retVal;
 212 }
 213
 214 int SalAquaPicker::runandwaitforresult()
 215 {
 216     DBG_PRINT_ENTRY(CLASS_NAME, __func__);
 217
 218     SolarMutexGuard aGuard;
 219
 220     int status = this->run();
 221
 222     DBG_PRINT_EXIT(CLASS_NAME, __func__, status);
 223     return status;
 224 }
 225
 226 void SAL_CALL SalAquaPicker::implsetDisplayDirectory( const rtl::OUString& aDirectory )
 227     throw( lang::IllegalArgumentException, uno::RuntimeException )
 228 {
 229     DBG_PRINT_ENTRY(CLASS_NAME, __func__, "directory", aDirectory);
 230
 231     SolarMutexGuard aGuard;
 232
 233     if (aDirectory != m_sDisplayDirectory) {
 234         m_sDisplayDirectory = aDirectory;
 235     }
 236
 237     DBG_PRINT_EXIT(CLASS_NAME, __func__);
 238 }
 239
 240 rtl::OUString SAL_CALL SalAquaPicker::implgetDisplayDirectory() throw( uno::RuntimeException )
 241 {
 242     DBG_PRINT_ENTRY(CLASS_NAME, __func__);
 243     DBG_PRINT_EXIT(CLASS_NAME, __func__, m_sDisplayDirectory);
 244
 245     return m_sDisplayDirectory;
 246 }
 247
 248 void SAL_CALL SalAquaPicker::implsetTitle( const rtl::OUString& aTitle ) throw( uno::RuntimeException )
 249 {
 250     DBG_PRINT_ENTRY(CLASS_NAME, __func__, "title", aTitle);
 251
 252     SolarMutexGuard aGuard;
 253
 254     if (m_pDialog != nil) {
 255         [m_pDialog setTitle:[NSString stringWithOUString:aTitle]];
 256     }
 257
 258     DBG_PRINT_EXIT(CLASS_NAME, __func__);
 259 }
 260
 261 /* vim:set shiftwidth=4 softtabstop=4 expandtab: */