solenv/bin/modules/installer/download.pm

   1 #
   2 # This file is part of the LibreOffice project.
   3 #
   4 # This Source Code Form is subject to the terms of the Mozilla Public
   5 # License, v. 2.0. If a copy of the MPL was not distributed with this
   6 # file, You can obtain one at http://mozilla.org/MPL/2.0/.
   7 #
   8 # This file incorporates work covered by the following license notice:
   9 #
  10 #   Licensed to the Apache Software Foundation (ASF) under one or more
  11 #   contributor license agreements. See the NOTICE file distributed
  12 #   with this work for additional information regarding copyright
  13 #   ownership. The ASF licenses this file to you under the Apache
  14 #   License, Version 2.0 (the "License"); you may not use this file
  15 #   except in compliance with the License. You may obtain a copy of
  16 #   the License at http://www.apache.org/licenses/LICENSE-2.0 .
  17 #
  18
  19 package installer::download;
  20
  21 use strict;
  22 use warnings;
  23
  24 use File::Spec;
  25 use installer::exiter;
  26 use installer::files;
  27 use installer::globals;
  28 use installer::logger;
  29 use installer::pathanalyzer;
  30 use installer::remover;
  31 use installer::systemactions;
  32
  33 BEGIN { # This is needed so that cygwin's perl evaluates ACLs
  34     # (needed for correctly evaluating the -x test.)
  35     if( $^O =~ /cygwin/i ) {
  36         require filetest; import filetest "access";
  37     }
  38 }
  39
  40 ##################################################################
  41 # Including the lowercase product name into the script template
  42 ##################################################################
  43
  44 sub put_productname_into_script
  45 {
  46     my ($scriptfile, $variableshashref) = @_;
  47
  48     my $productname = $variableshashref->{'PRODUCTNAME'};
  49     $productname = lc($productname);
  50     $productname =~ s/\.//g;    # openoffice.org -> openofficeorg
  51     $productname =~ s/\s*//g;
  52
  53     my $infoline = "Adding productname $productname into download shell script\n";
  54     push( @installer::globals::logfileinfo, $infoline);
  55
  56     for ( my $i = 0; $i <= $#{$scriptfile}; $i++ )
  57     {
  58         ${$scriptfile}[$i] =~ s/PRODUCTNAMEPLACEHOLDER/$productname/;
  59     }
  60 }
  61
  62 #########################################################
  63 # Including the linenumber into the script template
  64 #########################################################
  65
  66 sub put_linenumber_into_script
  67 {
  68     my ( $scriptfile ) = @_;
  69
  70     my $linenumber =  $#{$scriptfile} + 2;
  71
  72     my $infoline = "Adding linenumber $linenumber into download shell script\n";
  73     push( @installer::globals::logfileinfo, $infoline);
  74
  75     for ( my $i = 0; $i <= $#{$scriptfile}; $i++ )
  76     {
  77         ${$scriptfile}[$i] =~ s/LINENUMBERPLACEHOLDER/$linenumber/;
  78     }
  79 }
  80
  81 #########################################################
  82 # Determining the name of the new scriptfile
  83 #########################################################
  84
  85 sub determine_scriptfile_name
  86 {
  87     my ( $filename ) = @_;
  88
  89     $installer::globals::downloadfileextension = ".sh";
  90     $filename = $filename . $installer::globals::downloadfileextension;
  91     $installer::globals::downloadfilename = $filename;
  92
  93     my $infoline = "Setting download shell script file name to $filename\n";
  94     push( @installer::globals::logfileinfo, $infoline);
  95
  96     return $filename;
  97 }
  98
  99 #########################################################
 100 # Saving the script file in the installation directory
 101 #########################################################
 102
 103 sub save_script_file
 104 {
 105     my ($directory, $newscriptfilename, $scriptfile) = @_;
 106
 107     $newscriptfilename = $directory . $installer::globals::separator . $newscriptfilename;
 108     installer::files::save_file($newscriptfilename, $scriptfile);
 109
 110     my $infoline = "Saving script file $newscriptfilename\n";
 111     push( @installer::globals::logfileinfo, $infoline);
 112
 113     if ( ! $installer::globals::iswindowsbuild )
 114     {
 115         chmod 0775, $newscriptfilename;
 116     }
 117
 118     return $newscriptfilename;
 119 }
 120
 121 #########################################################
 122 # Including checksum and size into script file
 123 #########################################################
 124
 125 sub put_checksum_and_size_into_script
 126 {
 127     my ($scriptfile, $sumout) = @_;
 128
 129     my $checksum = "";
 130     my $size = "";
 131
 132     if  ( $sumout =~ /^\s*(\d+)\s+(\d+)\s*$/ )
 133     {
 134         $checksum = $1;
 135         $size = $2;
 136     }
 137     else
 138     {
 139         installer::exiter::exit_program("ERROR: Incorrect return value from /usr/bin/sum: $sumout", "put_checksum_and_size_into_script");
 140     }
 141
 142     my $infoline = "Adding checksum $checksum and size $size into download shell script\n";
 143     push( @installer::globals::logfileinfo, $infoline);
 144
 145     for ( my $i = 0; $i <= $#{$scriptfile}; $i++ )
 146     {
 147         ${$scriptfile}[$i] =~ s/CHECKSUMPLACEHOLDER/$checksum/;
 148         ${$scriptfile}[$i] =~ s/DISCSPACEPLACEHOLDER/$size/;
 149     }
 150
 151 }
 152
 153 #########################################################
 154 # Determining checksum and size of tar file
 155 #########################################################
 156
 157 sub call_sum
 158 {
 159     my ($filename) = @_;
 160
 161     my $systemcall = "/usr/bin/sum $filename |";
 162
 163     my $sumoutput = "";
 164
 165     open (SUM, "$systemcall");
 166     $sumoutput = <SUM>;
 167     close (SUM);
 168
 169     my $returnvalue = $?;   # $? contains the return value of the systemcall
 170
 171     my $infoline = "Systemcall: $systemcall\n";
 172     push( @installer::globals::logfileinfo, $infoline);
 173
 174     if ($returnvalue)
 175     {
 176         $infoline = "ERROR: Could not execute \"$systemcall\"!\n";
 177         push( @installer::globals::logfileinfo, $infoline);
 178     }
 179     else
 180     {
 181         $infoline = "Success: Executed \"$systemcall\" successfully!\n";
 182         push( @installer::globals::logfileinfo, $infoline);
 183     }
 184
 185     $sumoutput =~ s/\s+$filename\s$//;
 186     return $sumoutput;
 187 }
 188
 189 #########################################################
 190 # Searching for the getuid.so in the solver
 191 #########################################################
 192
 193 sub get_path_for_library
 194 {
 195     my ($includepatharrayref) = @_;
 196
 197     my $getuidlibraryname = "libgetuid.so";
 198
 199     my $getuidlibraryref = "";
 200
 201     if ( $installer::globals::include_paths_read )
 202     {
 203         $getuidlibraryref = installer::scriptitems::get_sourcepath_from_filename_and_includepath(\$getuidlibraryname, $includepatharrayref, 0);
 204     }
 205     else
 206     {
 207         $getuidlibraryref = installer::scriptitems::get_sourcepath_from_filename_and_includepath_classic(\$getuidlibraryname, $includepatharrayref, 0);
 208     }
 209
 210     return $$getuidlibraryref;
 211 }
 212
 213 #########################################################
 214 # Include the tar file into the script
 215 #########################################################
 216
 217 sub include_tar_into_script
 218 {
 219     my ($scriptfile, $temporary_tarfile) = @_;
 220
 221     my $systemcall = "cat $temporary_tarfile >> $scriptfile && rm $temporary_tarfile";
 222     my $returnvalue = system($systemcall);
 223
 224     my $infoline = "Systemcall: $systemcall\n";
 225     push( @installer::globals::logfileinfo, $infoline);
 226
 227     if ($returnvalue)
 228     {
 229         $infoline = "ERROR: Could not execute \"$systemcall\"!\n";
 230         push( @installer::globals::logfileinfo, $infoline);
 231     }
 232     else
 233     {
 234         $infoline = "Success: Executed \"$systemcall\" successfully!\n";
 235         push( @installer::globals::logfileinfo, $infoline);
 236     }
 237     return $returnvalue;
 238 }
 239
 240 #########################################################
 241 # Create a tar file from the binary package
 242 #########################################################
 243
 244 sub tar_package
 245 {
 246     my ( $installdir, $tarfilename, $getuidlibrary) = @_;
 247
 248     my $ldpreloadstring = "";
 249     if ( $getuidlibrary ne "" ) { $ldpreloadstring = "LD_PRELOAD=" . $getuidlibrary; }
 250
 251     my $systemcall = "cd $installdir; $ldpreloadstring tar -cf - * > $tarfilename";
 252
 253     my $returnvalue = system($systemcall);
 254
 255     my $infoline = "Systemcall: $systemcall\n";
 256     push( @installer::globals::logfileinfo, $infoline);
 257
 258     if ($returnvalue)
 259     {
 260         $infoline = "ERROR: Could not execute \"$systemcall\"!\n";
 261         push( @installer::globals::logfileinfo, $infoline);
 262     }
 263     else
 264     {
 265         $infoline = "Success: Executed \"$systemcall\" successfully!\n";
 266         push( @installer::globals::logfileinfo, $infoline);
 267     }
 268
 269     chmod 0775, $tarfilename;
 270
 271     return ( -s $tarfilename );
 272 }
 273
 274 #########################################################
 275 # Setting installation languages
 276 #########################################################
 277
 278 sub get_downloadname_language
 279 {
 280     my ($languagestringref) = @_;
 281
 282     my $languages = $$languagestringref;
 283
 284     if ( $installer::globals::added_english )
 285     {
 286         $languages =~ s/en-US_//;
 287         $languages =~ s/_en-US//;
 288     }
 289
 290     # do not list languages if there are too many
 291     if ( length ($languages) > $installer::globals::max_lang_length )
 292     {
 293         $languages = '';
 294     }
 295
 296     # do not list pure en-US, except for helppack and langpack
 297     if ( ( $languages eq "en-US" ) &&
 298          ( ! $installer::globals::languagepack ) &&
 299          ( ! $installer::globals::helppack ) )
 300     {
 301         $languages = '';
 302     }
 303
 304     return $languages;
 305 }
 306
 307 #########################################################
 308 # Setting download name
 309 #########################################################
 310
 311 sub get_downloadname_productname
 312 {
 313     my ($allvariables) = @_;
 314
 315     my $start = "LibreOffice";
 316
 317     if ( $allvariables->{'PRODUCTNAME'} eq "LibreOffice" ) { $start = "LibreOffice"; }
 318
 319     if ( $allvariables->{'PRODUCTNAME'} eq "LibreOfficeDev" ) { $start = "LibreOfficeDev"; }
 320
 321     if ( $allvariables->{'PRODUCTNAME'} eq "OxygenOffice" ) { $start = "OOOP"; }
 322
 323     return $start;
 324 }
 325
 326 #########################################################
 327 # Setting download version
 328 #########################################################
 329
 330 sub get_download_version
 331 {
 332     my ($allvariables) = @_;
 333
 334     my $version = "";
 335
 336     $version = $allvariables->{'PRODUCTVERSION'};
 337     if (( $allvariables->{'PRODUCTEXTENSION'} ) && ( $allvariables->{'PRODUCTEXTENSION'} ne "" )) { $version = $version . $allvariables->{'PRODUCTEXTENSION'}; }
 338
 339     return $version;
 340 }
 341
 342 #################################################################
 343 # Setting the platform name for download
 344 #################################################################
 345
 346 sub get_download_platformname
 347 {
 348     my $platformname = "";
 349
 350     if ( $installer::globals::islinuxbuild )
 351     {
 352         $platformname = "Linux";
 353     }
 354     elsif ( $installer::globals::issolarisbuild )
 355     {
 356         $platformname = "Solaris";
 357     }
 358     elsif ( $installer::globals::iswindowsbuild )
 359     {
 360         $platformname = "Win";
 361     }
 362     elsif ( $installer::globals::isfreebsdbuild )
 363     {
 364         $platformname = "FreeBSD";
 365     }
 366     elsif ( $installer::globals::ismacbuild )
 367     {
 368         $platformname = "MacOS";
 369     }
 370     else
 371     {
 372         $platformname = $installer::globals::compiler;
 373     }
 374
 375     return $platformname;
 376 }
 377
 378 #########################################################
 379 # Setting the architecture for the download name
 380 #########################################################
 381
 382 sub get_download_architecture
 383 {
 384     my $arch = "";
 385
 386     if ( $installer::globals::compiler =~ /unxlngi/ )
 387     {
 388         $arch = "x86";
 389     }
 390     elsif ( $installer::globals::compiler =~ /unxlngppc/ )
 391     {
 392         $arch = "PPC";
 393     }
 394     elsif ( $installer::globals::compiler =~ /unxlngx/ )
 395     {
 396         $arch = "x86-64";
 397     }
 398     elsif ( $installer::globals::issolarissparcbuild )
 399     {
 400         $arch = "Sparc";
 401     }
 402     elsif ( $installer::globals::issolarisx86build )
 403     {
 404         $arch = "x86";
 405     }
 406     elsif ( $installer::globals::iswindowsbuild )
 407     {
 408         $arch = "x86";
 409     }
 410     elsif ( $installer::globals::compiler =~ /^unxmacxi/ )
 411     {
 412         $arch = "x86";
 413     }
 414     elsif ( $installer::globals::compiler =~ /^unxmacxx/ )
 415     {
 416         $arch = "x86-64";
 417     }
 418
 419     return $arch;
 420 }
 421
 422 #########################################################
 423 # Setting the content type for the download name
 424 #########################################################
 425
 426 sub get_download_content
 427 {
 428     my ($allvariables) = @_;
 429
 430     my $content = "";
 431
 432     # content type included in the installer
 433     if ( $installer::globals::isrpmbuild )
 434     {
 435         $content = "rpm";
 436     }
 437     elsif ( $installer::globals::isdebbuild )
 438     {
 439         $content = "deb";
 440     }
 441     elsif ( $installer::globals::packageformat eq "archive" )
 442     {
 443         $content = "archive";
 444     }
 445
 446     return $content;
 447 }
 448
 449 #########################################################
 450 # Setting the functionality type for the download name
 451 #########################################################
 452
 453 sub get_download_functionality
 454 {
 455     my ($allvariables) = @_;
 456
 457     my $functionality = "";
 458
 459     if ( $installer::globals::languagepack )
 460     {
 461         $functionality = "langpack";
 462     }
 463     elsif ( $installer::globals::helppack )
 464     {
 465         $functionality = "helppack";
 466     }
 467     elsif ( $allvariables->{'POSTVERSIONEXTENSION'} eq "SDK" )
 468     {
 469         $functionality = "sdk";
 470     }
 471     elsif ( $allvariables->{'POSTVERSIONEXTENSION'} eq "TEST" )
 472     {
 473         $functionality = "test";
 474     }
 475     elsif ( $allvariables->{'PRODUCTNAME'} eq "URE" )
 476     {
 477         $functionality = "ure";
 478     }
 479
 480     return $functionality;
 481 }
 482
 483 ###############################################################################################
 484 # Setting the download file name
 485 # Syntax:
 486 # (PRODUCTNAME)_(VERSION)_(OS)_(ARCH)_(INSTALLTYPE)_(LANGUAGE).(FILEEXTENSION)
 487 ###############################################################################################
 488
 489 sub set_download_filename
 490 {
 491     my ($languagestringref, $allvariables) = @_;
 492
 493     my $start = get_downloadname_productname($allvariables);
 494     my $versionstring = get_download_version($allvariables);
 495     my $platform = get_download_platformname();
 496     my $architecture = get_download_architecture();
 497     my $content = get_download_content($allvariables);
 498     my $functionality = get_download_functionality($allvariables);
 499     my $language = get_downloadname_language($languagestringref);
 500
 501     # Setting the extension happens automatically
 502
 503     my $filename = $start . "_" . $versionstring . "_" . $platform . "_" . $architecture . "_" . $content . "_" . $functionality . "_" . $language;
 504
 505     # get rid of duplicit "_" delimiters when some strings are empty
 506     $filename =~ s/\_\_\_/\_/g;
 507     $filename =~ s/\_\_/\_/g;
 508     $filename =~ s/\_\s*$//;
 509
 510     $installer::globals::ooodownloadfilename = $filename;
 511
 512     return $filename;
 513 }
 514
 515
 516 #########################################################
 517 # Creating a tar.gz file
 518 #########################################################
 519
 520 sub create_tar_gz_file_from_directory
 521 {
 522     my ($installdir, $getuidlibrary, $downloaddir, $downloadfilename) = @_;
 523
 524     my $infoline = "";
 525
 526     my $packdir = $installdir;
 527     installer::pathanalyzer::make_absolute_filename_to_relative_filename(\$packdir);
 528     my $changedir = $installdir;
 529     installer::pathanalyzer::get_path_from_fullqualifiedname(\$changedir);
 530
 531     my $ldpreloadstring = "";
 532     if ( $getuidlibrary ne "" ) { $ldpreloadstring = "LD_PRELOAD=" . $getuidlibrary; }
 533
 534     $installer::globals::downloadfileextension = ".tar.gz";
 535     $installer::globals::downloadfilename = $downloadfilename . $installer::globals::downloadfileextension;
 536     my $targzname = $downloaddir . $installer::globals::separator . $installer::globals::downloadfilename;
 537
 538     # fdo#67060 - install script is for RPM only
 539     if ( -e "$installdir/install" && !$installer::globals::isrpmbuild )
 540     {
 541         unlink("$installdir/install");
 542     }
 543
 544     my $systemcall = "cd $changedir; $ldpreloadstring tar -cf - $packdir | gzip > $targzname";
 545
 546     my $returnvalue = system($systemcall);
 547
 548     $infoline = "Systemcall: $systemcall\n";
 549     push( @installer::globals::logfileinfo, $infoline);
 550
 551     if ($returnvalue)
 552     {
 553         $infoline = "ERROR: Could not execute \"$systemcall\"!\n";
 554         push( @installer::globals::logfileinfo, $infoline);
 555     }
 556     else
 557     {
 558         $infoline = "Success: Executed \"$systemcall\" successfully!\n";
 559         push( @installer::globals::logfileinfo, $infoline);
 560     }
 561
 562     return $targzname;
 563 }
 564
 565 #########################################################
 566 # Setting the variables in the download name
 567 #########################################################
 568
 569 sub resolve_variables_in_downloadname
 570 {
 571     my ($allvariables, $downloadname, $languagestringref) = @_;
 572
 573     # Typical name: soa-{productversion}-{extension}-bin-{os}-{languages}
 574
 575     my $productversion = "";
 576     if ( $allvariables->{'PRODUCTVERSION'} ) { $productversion = $allvariables->{'PRODUCTVERSION'}; }
 577     $downloadname =~ s/\{productversion\}/$productversion/;
 578
 579     my $packageversion = "";
 580     if ( $allvariables->{'PACKAGEVERSION'} ) { $packageversion = $allvariables->{'PACKAGEVERSION'}; }
 581     $downloadname =~ s/\{packageversion\}/$packageversion/;
 582
 583     my $extension = "";
 584     if ( $allvariables->{'PRODUCTEXTENSION'} ) { $extension = $allvariables->{'PRODUCTEXTENSION'}; }
 585     $extension = lc($extension);
 586     $downloadname =~ s/\{extension\}/$extension/;
 587
 588     my $os = "";
 589     if ( $installer::globals::iswindowsbuild ) { $os = "windows"; }
 590     elsif ( $installer::globals::issolarissparcbuild ) { $os = "solsparc"; }
 591     elsif ( $installer::globals::issolarisx86build ) { $os = "solia"; }
 592     elsif ( $installer::globals::islinuxbuild ) { $os = "linux"; }
 593     elsif ( $installer::globals::compiler =~ /unxmacxi/ ) { $os = "macosxi"; }
 594     elsif ( $installer::globals::compiler =~ /unxmacxx/ ) { $os = "macosxx"; }
 595     else { $os = ""; }
 596     $downloadname =~ s/\{os\}/$os/;
 597
 598     my $languages = $$languagestringref;
 599     $downloadname =~ s/\{languages\}/$languages/;
 600
 601     $downloadname =~ s/\-\-\-/\-/g;
 602     $downloadname =~ s/\-\-/\-/g;
 603     $downloadname =~ s/\-\s*$//;
 604
 605     return $downloadname;
 606 }
 607
 608 ##############################################################
 609 # Returning the complete block in all languages
 610 # for a specified string
 611 ##############################################################
 612
 613 sub get_language_block_from_language_file
 614 {
 615     my ($searchstring, $languagefile) = @_;
 616
 617     my @language_block = ();
 618
 619     for ( my $i = 0; $i <= $#{$languagefile}; $i++ )
 620     {
 621         if ( ${$languagefile}[$i] =~ /^\s*\[\s*$searchstring\s*\]\s*$/ )
 622         {
 623             my $counter = $i;
 624
 625             push(@language_block, ${$languagefile}[$counter]);
 626             $counter++;
 627
 628             while (( $counter <= $#{$languagefile} ) && (!( ${$languagefile}[$counter] =~ /^\s*\[/ )))
 629             {
 630                 push(@language_block, ${$languagefile}[$counter]);
 631                 $counter++;
 632             }
 633
 634             last;
 635         }
 636     }
 637
 638     return \@language_block;
 639 }
 640
 641 ##############################################################
 642 # Returning a specific language string from the block
 643 # of all translations
 644 ##############################################################
 645
 646 sub get_language_string_from_language_block
 647 {
 648     my ($language_block, $language) = @_;
 649
 650     my $newstring = "";
 651
 652     for ( my $i = 0; $i <= $#{$language_block}; $i++ )
 653     {
 654         if ( ${$language_block}[$i] =~ /^\s*$language\s*\=\s*\"(.*)\"\s*$/ )
 655         {
 656             $newstring = $1;
 657             last;
 658         }
 659     }
 660
 661     if ( $newstring eq "" )
 662     {
 663         $language = "en-US";    # defaulting to english
 664
 665         for ( my $i = 0; $i <= $#{$language_block}; $i++ )
 666         {
 667             if ( ${$language_block}[$i] =~ /^\s*$language\s*\=\s*\"(.*)\"\s*$/ )
 668             {
 669                 $newstring = $1;
 670                 last;
 671             }
 672         }
 673     }
 674
 675     return $newstring;
 676 }
 677
 678 ####################################################
 679 # Creating download installation sets
 680 ####################################################
 681
 682 sub create_download_sets
 683 {
 684     my ($installationdir, $includepatharrayref, $allvariableshashref, $downloadname, $languagestringref, $languagesarrayref) = @_;
 685
 686     my $infoline = "";
 687
 688     my $force = 1; # print this message even in 'quiet' mode
 689     installer::logger::print_message( "\n******************************************\n" );
 690     installer::logger::print_message( "... creating download installation set ...\n", $force );
 691     installer::logger::print_message( "******************************************\n" );
 692
 693     installer::logger::include_header_into_logfile("Creating download installation sets:");
 694
 695     my $firstdir = $installationdir;
 696     installer::pathanalyzer::get_path_from_fullqualifiedname(\$firstdir);
 697
 698     my $lastdir = $installationdir;
 699     installer::pathanalyzer::make_absolute_filename_to_relative_filename(\$lastdir);
 700
 701     if ( $installer::globals::iswindowsbuild && $lastdir =~ /\./ ) { $lastdir =~ s/\./_download_inprogress\./ }
 702     else { $lastdir = $lastdir . "_download_inprogress"; }
 703
 704     # removing existing directory "_native_packed_inprogress" and "_native_packed_witherror" and "_native_packed"
 705
 706     my $downloaddir = $firstdir . $lastdir;
 707
 708     if ( -d $downloaddir ) { installer::systemactions::remove_complete_directory($downloaddir); }
 709
 710     my $olddir = $downloaddir;
 711     $olddir =~ s/_inprogress/_witherror/;
 712     if ( -d $olddir ) { installer::systemactions::remove_complete_directory($olddir); }
 713
 714     $olddir = $downloaddir;
 715     $olddir =~ s/_inprogress//;
 716     if ( -d $olddir ) { installer::systemactions::remove_complete_directory($olddir); }
 717
 718     # creating the new directory
 719
 720     installer::systemactions::create_directory($downloaddir);
 721
 722     $installer::globals::saveinstalldir = $downloaddir;
 723
 724     # evaluating the name of the download file
 725
 726     if ( $allvariableshashref->{'OOODOWNLOADNAME'} ) { $downloadname = set_download_filename($languagestringref, $allvariableshashref); }
 727     else { $downloadname = resolve_variables_in_downloadname($allvariableshashref, $downloadname, $languagestringref); }
 728
 729     if ( ! $installer::globals::iswindowsbuild )    # Unix specific part
 730     {
 731
 732         # getting the path of the getuid.so (only required for Solaris and Linux)
 733         my $getuidlibrary = "";
 734         if (( $installer::globals::issolarisbuild ) || ( $installer::globals::islinuxbuild )) { $getuidlibrary = get_path_for_library($includepatharrayref); }
 735
 736         if ( $allvariableshashref->{'OOODOWNLOADNAME'} )
 737         {
 738             my $downloadfile = create_tar_gz_file_from_directory($installationdir, $getuidlibrary, $downloaddir, $downloadname);
 739         }
 740         else
 741         {
 742             # find and read setup script template
 743             my $scriptfilename = "downloadscript.sh";
 744
 745             my $scriptref = "";
 746
 747             if ( $installer::globals::include_paths_read )
 748             {
 749                 $scriptref = installer::scriptitems::get_sourcepath_from_filename_and_includepath(\$scriptfilename, $includepatharrayref, 0);
 750             }
 751             else
 752             {
 753                 $scriptref = installer::scriptitems::get_sourcepath_from_filename_and_includepath_classic(\$scriptfilename, $includepatharrayref, 0);
 754             }
 755
 756             if ($$scriptref eq "") { installer::exiter::exit_program("ERROR: Could not find script file $scriptfilename!", "create_download_sets"); }
 757             my $scriptfile = installer::files::read_file($$scriptref);
 758
 759             $infoline = "Found  script file $scriptfilename: $$scriptref \n";
 760             push( @installer::globals::logfileinfo, $infoline);
 761
 762             # add product name into script template
 763             put_productname_into_script($scriptfile, $allvariableshashref);
 764
 765             # replace linenumber in script template
 766             put_linenumber_into_script($scriptfile);
 767
 768             # create tar file
 769             my $temporary_tarfile_name = $downloaddir . $installer::globals::separator . 'installset.tar';
 770             my $size = tar_package($installationdir, $temporary_tarfile_name, $getuidlibrary);
 771             installer::exiter::exit_program("ERROR: Could not create tar file $temporary_tarfile_name!", "create_download_sets") unless $size;
 772
 773             # calling sum to determine checksum and size of the tar file
 774             my $sumout = call_sum($temporary_tarfile_name);
 775
 776             # writing checksum and size into scriptfile
 777             put_checksum_and_size_into_script($scriptfile, $sumout);
 778
 779             # saving the script file
 780             my $newscriptfilename = determine_scriptfile_name($downloadname);
 781             $newscriptfilename = save_script_file($downloaddir, $newscriptfilename, $scriptfile);
 782
 783             installer::logger::print_message( "... including installation set into $newscriptfilename ... \n" );
 784             # Append tar file to script
 785             include_tar_into_script($newscriptfilename, $temporary_tarfile_name);
 786         }
 787     }
 788
 789     return $downloaddir;
 790 }
 791
 792 1;