slideshow/opengl/reflectionVertexShader.glsl

   1 /* -*- Mode: C; tab-width: 4; indent-tabs-mode: nil; c-basic-offset: 4 -*- */
   2 /*
   3  * This file is part of the LibreOffice project.
   4  *
   5  * This Source Code Form is subject to the terms of the Mozilla Public
   6  * License, v. 2.0. If a copy of the MPL was not distributed with this
   7  * file, You can obtain one at http://mozilla.org/MPL/2.0/.
   8  */
   9
  10 #version 130
  11
  12 attribute vec3 a_position;
  13 attribute vec3 a_normal;
  14 attribute vec2 a_texCoord;
  15
  16 uniform mat4 u_projectionMatrix;
  17 uniform mat4 u_modelViewMatrix;
  18 uniform mat4 u_sceneTransformMatrix;
  19 uniform mat4 u_primitiveTransformMatrix;
  20 uniform mat4 u_operationsTransformMatrix;
  21
  22 varying vec2 v_texturePosition;
  23 varying vec3 v_normal;
  24 varying float v_isShadow;
  25
  26 #if __VERSION__ < 140
  27 mat4 inverse(mat4 m)
  28 {
  29     float a00 = m[0][0], a01 = m[0][1], a02 = m[0][2], a03 = m[0][3];
  30     float a10 = m[1][0], a11 = m[1][1], a12 = m[1][2], a13 = m[1][3];
  31     float a20 = m[2][0], a21 = m[2][1], a22 = m[2][2], a23 = m[2][3];
  32     float a30 = m[3][0], a31 = m[3][1], a32 = m[3][2], a33 = m[3][3];
  33
  34     float b00 = a00 * a11 - a01 * a10;
  35     float b01 = a00 * a12 - a02 * a10;
  36     float b02 = a00 * a13 - a03 * a10;
  37     float b03 = a01 * a12 - a02 * a11;
  38     float b04 = a01 * a13 - a03 * a11;
  39     float b05 = a02 * a13 - a03 * a12;
  40     float b06 = a20 * a31 - a21 * a30;
  41     float b07 = a20 * a32 - a22 * a30;
  42     float b08 = a20 * a33 - a23 * a30;
  43     float b09 = a21 * a32 - a22 * a31;
  44     float b10 = a21 * a33 - a23 * a31;
  45     float b11 = a22 * a33 - a23 * a32;
  46
  47     float det = b00 * b11 - b01 * b10 + b02 * b09 + b03 * b08 - b04 * b07 + b05 * b06;
  48
  49     return mat4(
  50         a11 * b11 - a12 * b10 + a13 * b09,
  51         a02 * b10 - a01 * b11 - a03 * b09,
  52         a31 * b05 - a32 * b04 + a33 * b03,
  53         a22 * b04 - a21 * b05 - a23 * b03,
  54         a12 * b08 - a10 * b11 - a13 * b07,
  55         a00 * b11 - a02 * b08 + a03 * b07,
  56         a32 * b02 - a30 * b05 - a33 * b01,
  57         a20 * b05 - a22 * b02 + a23 * b01,
  58         a10 * b10 - a11 * b08 + a13 * b06,
  59         a01 * b08 - a00 * b10 - a03 * b06,
  60         a30 * b04 - a31 * b02 + a33 * b00,
  61         a21 * b02 - a20 * b04 - a23 * b00,
  62         a11 * b07 - a10 * b09 - a12 * b06,
  63         a00 * b09 - a01 * b07 + a02 * b06,
  64         a31 * b01 - a30 * b03 - a32 * b00,
  65         a20 * b03 - a21 * b01 + a22 * b00) / det;
  66 }
  67 #endif
  68
  69 void main( void )
  70 {
  71     mat4 modelViewMatrix = u_modelViewMatrix * u_operationsTransformMatrix * u_sceneTransformMatrix * u_primitiveTransformMatrix;
  72     mat3 normalMatrix = mat3(transpose(inverse(modelViewMatrix)));
  73     gl_Position = u_projectionMatrix * modelViewMatrix * vec4(a_position, 1.0);
  74     v_texturePosition = a_texCoord;
  75     v_normal = normalize(normalMatrix * a_normal);
  76     v_isShadow = float(gl_VertexID >= 6);
  77 }
  78
  79 /* vim:set shiftwidth=4 softtabstop=4 expandtab: */