autogen.sh

   1 :
   2 #
   3 # This script checks various configure parameters and uses three files:
   4 #   * autogen.input (ro)
   5 #   * autogen.lastrun (rw)
   6 #   * autogen.lastrun.bak (rw)
   7 #
   8 # If _no_ parameters:
   9 #   Read args from autogen.input or autogen.lastrun
  10 # Else
  11 #   Backup autogen.lastrun as autogen.lastrun.bak
  12 #   Write autogen.lastrun with new commandline args
  13 #
  14 # Run configure with checked args
  15 #
  16     eval 'exec perl -S $0 ${1+"$@"}'
  17         if 0;
  18
  19 use strict;
  20 use Cwd ('cwd', 'realpath');
  21 use File::Basename;
  22
  23 my $src_path=dirname(realpath($0));
  24 my $build_path=realpath(cwd());
  25 # since this looks crazy, if you have a symlink on a path up to and including
  26 # the current directory, we need our configure to run in the realpath of that
  27 # such that compiled (realpath'd) dependency filenames match the filenames
  28 # used in our makefiles - ie. this gets dependencies right via SRC_ROOT
  29 chdir ($build_path);
  30 # more amazingly, if you don't clobber 'PWD' shells will re-assert their
  31 # old path from the environment, not cwd.
  32 $ENV{PWD} = $build_path;
  33
  34 my $aclocal;
  35 my $autoconf;
  36
  37 # check we have various vital tools
  38 sub sanity_checks($)
  39 {
  40     my $system = shift;
  41     my @path = split (':', $ENV{'PATH'});
  42     my %required =
  43       (
  44        'pkg-config' => "pkg-config is required to be installed",
  45        $autoconf    => "autoconf is required",
  46        $aclocal     => "$aclocal is required",
  47       );
  48
  49     for my $elem (@path) {
  50         for my $app (keys %required) {
  51             if (-f "$elem/$app") {
  52                 delete $required{$app};
  53             }
  54         }
  55     }
  56     if ((keys %required) > 0) {
  57         print ("Various low-level dependencies are missing, please install them:\n");
  58         for my $app (keys %required) {
  59             print "\t $app: " . $required{$app} . "\n";
  60         }
  61         exit (1);
  62     }
  63 }
  64
  65 # one argument per line
  66 sub read_args($)
  67 {
  68     my $file = shift;
  69     my $fh;
  70     my @lst;
  71     open ($fh, $file) || die "can't open file: $file";
  72     while (<$fh>) {
  73         chomp();
  74         s/^\s+//;
  75         s/\s+$//;
  76         # migrate from the old system
  77         if ( substr($_, 0, 1) eq "'" ) {
  78             print STDERR "Migrating options from the old autogen.lastrun format, using:\n";
  79             my @opts;
  80             @opts = split(/'/);
  81             foreach my $opt (@opts) {
  82                 if ( substr($opt, 0, 1) eq "-" ) {
  83                     push @lst, $opt;
  84                     print STDERR "  $opt\n";
  85                 }
  86             }
  87         } elsif ( /^INCLUDE:(.*)/ ) {
  88             # include another .conf into this one
  89             my $config = "$src_path/distro-configs/$1.conf";
  90             if (! -f $config) {
  91                 invalid_distro ($config, $1);
  92             }
  93             push @lst, read_args ($config);
  94         } elsif ( substr($_, 0, 1) eq "#" ) {
  95             # comment
  96         } elsif ( length == 0 ) {
  97             # empty line
  98         } else {
  99             push @lst, $_;
 100         }
 101     }
 102     close ($fh);
 103     # print "read args from file '$file': @lst\n";
 104     return @lst;
 105 }
 106
 107 sub show_distro_configs($$)
 108 {
 109     my ($prefix, $path) = @_;
 110     my $dirh;
 111     opendir ($dirh, "$path");
 112     while (($_ = readdir ($dirh))) {
 113         if (-d "$path/$_") {
 114             show_distro_configs(
 115                     $prefix eq "" ? "$_/" : "$prefix/$_/", "$path/$_")
 116                 unless $_ eq '.' || $_ eq '..';
 117             next;
 118         }
 119         /(.*)\.conf$/ || next;
 120         print STDERR "\t$prefix$1\n";
 121     }
 122     closedir ($dirh);
 123 }
 124
 125 sub invalid_distro($$)
 126 {
 127     my ($config, $distro) = @_;
 128     print STDERR "Can't find distro option set: $config\n";
 129     print STDERR "Distros with distro option sets are:\n";
 130     show_distro_configs("", "$src_path/distro-configs");
 131     exit (1);
 132 }
 133
 134 # Avoid confusing "aclocal: error: non-option arguments are not accepted: '.../m4'." error message.
 135 die "\$src_path must not contain spaces, but it is '$src_path'." if ($src_path =~ / /);
 136
 137 # Alloc $ACLOCAL to specify which aclocal to use
 138 $aclocal = $ENV{ACLOCAL} ? $ENV{ACLOCAL} : 'aclocal';
 139 # Alloc $AUTOCONF to specify which autoconf to use
 140 # (e.g. autoconf268 from a backports repo)
 141 $autoconf = $ENV{AUTOCONF} ? $ENV{AUTOCONF} : 'autoconf';
 142
 143 my $system = `uname -s`;
 144 chomp $system;
 145
 146 sanity_checks ($system) unless($system eq 'Darwin');
 147
 148 # If we are running in a LODE env, make sure we find the right aclocal
 149 # by making sure that LODE_HOME/opt/bin is in the PATH
 150 if (defined $ENV{LODE_HOME})
 151 {
 152     my $lode_path = quotemeta "$ENV{LODE_HOME}/opt/bin";
 153     if($ENV{PATH} !~ $lode_path)
 154     {
 155         $ENV{PATH}="$ENV{LODE_HOME}/opt/bin:$ENV{PATH}";
 156         print STDERR "add LODE_HOME/opt/bin in PATH\n";
 157     }
 158 }
 159
 160 my $aclocal_flags = $ENV{ACLOCAL_FLAGS};
 161
 162 $aclocal_flags .= " -I $src_path/m4";
 163 $aclocal_flags .= " -I $src_path/m4/mac" if ($system eq 'Darwin');
 164
 165 $ENV{AUTOMAKE_EXTRA_FLAGS} = '--warnings=no-portability' if (!($system eq 'Darwin'));
 166
 167 if ($src_path ne $build_path)
 168 {
 169     system ("ln -sf $src_path/configure.ac configure.ac");
 170     system ("ln -sf $src_path/g g");
 171     my $src_path_win=$src_path;
 172     if ($system =~ /CYGWIN.*/) {
 173         $src_path_win=`cygpath -m $src_path`;
 174         chomp $src_path_win;
 175     }
 176     my @modules = <$src_path/*/Makefile>;
 177     foreach my $module (@modules)
 178     {
 179         my $dir = basename (dirname ($module));
 180         mkdir ($dir);
 181         system ("rm -f $dir/Makefile");
 182         system ("printf 'module_directory:=$src_path_win/$dir/\ninclude \$(module_directory)/../solenv/gbuild/partial_build.mk\n' > $dir/Makefile");
 183     }
 184     my @external_modules = <$src_path/external/*/Makefile>;
 185     mkdir ("external");
 186     system ("ln -sf $src_path/external/Module_external.mk external/");
 187     foreach my $module (@external_modules)
 188     {
 189         my $dir = basename (dirname ($module));
 190         mkdir ("external/$dir");
 191         system ("rm -f external/$dir/Makefile");
 192         system ("printf 'module_directory:=$src_path_win/external/$dir/\ninclude \$(module_directory)/../../solenv/gbuild/partial_build.mk\n' > external/$dir/Makefile");
 193     }
 194 }
 195 system ("$aclocal $aclocal_flags") && die "Failed to run aclocal";
 196 unlink ("configure");
 197 system ("$autoconf -I ${src_path}") && die "Failed to run autoconf";
 198 die "Failed to generate the configure script" if (! -f "configure");
 199
 200 # Handle help arguments first, so we don't clobber autogen.lastrun
 201 for my $arg (@ARGV) {
 202     if ($arg =~ /^(--help|-h|-\?)$/) {
 203         print STDOUT "autogen.sh - libreoffice configuration helper\n";
 204         print STDOUT "   --with-distro  use a config from distro-configs/\n";
 205         print STDOUT "                  the name needs to be passed without extension\n";
 206         print STDOUT "   --best-effort  don't fail on un-known configure with/enable options\n";
 207         print STDOUT "\nOther arguments passed directly to configure:\n\n";
 208         system ("./configure --help");
 209         exit;
 210     }
 211 }
 212
 213 my @cmdline_args = ();
 214
 215 my $input = "autogen.input";
 216 my $lastrun = "autogen.lastrun";
 217
 218 if (!@ARGV) {
 219     if (-f $input) {
 220         if (-f $lastrun) {
 221             print STDERR <<WARNING;
 222 ********************************************************************
 223 *
 224 *   Reading $input and ignoring $lastrun!
 225 *   Consider removing $lastrun to get rid of this warning.
 226 *
 227 ********************************************************************
 228 WARNING
 229         }
 230         @cmdline_args = read_args ($input);
 231     } elsif (-f $lastrun) {
 232         print STDERR "Reading $lastrun. Please rename it to $input to avoid this message.\n";
 233         @cmdline_args = read_args ($lastrun);
 234     }
 235 } else {
 236     if (-f $input) {
 237         print STDERR <<WARNING;
 238 ********************************************************************
 239 *
 240 *   Using commandline arguments and ignoring $input!
 241 *
 242 ********************************************************************
 243 WARNING
 244     }
 245     @cmdline_args = @ARGV;
 246 }
 247
 248 my @args;
 249 my $default_config = "$src_path/distro-configs/default.conf";
 250 my $option_checking = 'fatal';
 251
 252 if (-f $default_config) {
 253     print STDERR "Reading default config file: $default_config.\n";
 254     push @args, read_args ($default_config);
 255 }
 256 for my $arg (@cmdline_args) {
 257     if ($arg =~ m/--with-distro=(.*)$/) {
 258         my $config = "$src_path/distro-configs/$1.conf";
 259         if (! -f $config) {
 260             invalid_distro ($config, $1);
 261         }
 262         push @args, read_args ($config);
 263     } elsif ($arg =~ m/--best-effort$/) {
 264         $option_checking = 'warn';
 265     } else {
 266         push @args, $arg;
 267     }
 268 }
 269
 270 if (defined $ENV{NOCONFIGURE}) {
 271     print "Skipping configure process.";
 272 } else {
 273     # Save autogen.lastrun only if we did get some arguments on the command-line
 274     if (! -f $input && @ARGV) {
 275         if (scalar(@cmdline_args) > 0) {
 276             # if there's already an autogen.lastrun, make a backup first
 277             if (-e $lastrun) {
 278                 open (my $fh, $lastrun) || warn "Can't open $lastrun.\n";
 279                 open (BAK, ">$lastrun.bak") || warn "Can't create backup file $lastrun.bak.\n";
 280                 while (<$fh>) {
 281                     print BAK;
 282                 }
 283                 close (BAK) && close ($fh);
 284             }
 285             # print "Saving command-line args to $lastrun\n";
 286             my $fh;
 287             open ($fh, ">autogen.lastrun") || die "Can't open autogen.lastrun: $!";
 288             for my $arg (@cmdline_args) {
 289                 print $fh "$arg\n";
 290             }
 291             close ($fh);
 292         }
 293     }
 294     push @args, "--srcdir=$src_path";
 295     push @args, "--enable-option-checking=$option_checking";
 296
 297     # When running a shell script from Perl on WSL, weirdly named
 298     # environment variables like the "ProgramFiles(x86)" one don't get
 299     # imported by the shell. So export it as PROGRAMFILESX86 instead.
 300     my $building_for_linux = 0;
 301     my $building_with_emscripten = 0;
 302     foreach my $arg (@args) {
 303         $building_for_linux = 1 if ($arg =~ /--host=x86_64.*linux/);
 304         $building_with_emscripten = 1 if ($arg =~ /^--host=wasm.*-emscripten$/);
 305     }
 306
 307     unshift @args, "./configure";
 308     unshift @args, "emconfigure" if ($building_with_emscripten);
 309
 310     print "Running '" . join (" ", @args), "'\n";
 311
 312     if (`wslsys 2>/dev/null` ne "" && !$building_for_linux) {
 313         if (!$ENV{"ProgramFiles(x86)"}) {
 314             print STDERR "To build for Windows on WSL, you need to set the WSLENV environment variable in the Control Panel to 'ProgramFiles(x86)'\n";
 315             print STDERR "If you actually do want to build for WSL (Linux) on WSL, pass a --host=x86_64-pc-linux-gnu option\n";
 316             exit (1);
 317         }
 318         $ENV{"PROGRAMFILESX86"} = $ENV{"ProgramFiles(x86)"};
 319     }
 320
 321     system (@args) && die "Error running configure";
 322 }
 323
 324 # Local Variables:
 325 # mode: perl
 326 # cperl-indent-level: 4
 327 # tab-width: 4
 328 # indent-tabs-mode: nil
 329 # End:
 330
 331 # vim:set ft=perl shiftwidth=4 softtabstop=4 expandtab: #