avmedia/source/macavf/framegrabber.mm

   1 /* -*- Mode: C++; tab-width: 4; indent-tabs-mode: nil; c-basic-offset: 4 -*- */
   2 /*
   3  * This file is part of the LibreOffice project.
   4  *
   5  * This Source Code Form is subject to the terms of the Mozilla Public
   6  * License, v. 2.0. If a copy of the MPL was not distributed with this
   7  * file, You can obtain one at http://mozilla.org/MPL/2.0/.
   8  *
   9  * This file incorporates work covered by the following license notice:
  10  *
  11  *   Licensed to the Apache Software Foundation (ASF) under one or more
  12  *   contributor license agreements. See the NOTICE file distributed
  13  *   with this work for additional information regarding copyright
  14  *   ownership. The ASF licenses this file to you under the Apache
  15  *   License, Version 2.0 (the "License"); you may not use this file
  16  *   except in compliance with the License. You may obtain a copy of
  17  *   the License at http://www.apache.org/licenses/LICENSE-2.0 .
  18  */
  19
  20 #include "framegrabber.hxx"
  21 #include "player.hxx"
  22
  23 #include <tools/stream.hxx>
  24 #include <vcl/graph.hxx>
  25 #include <vcl/cvtgrf.hxx>
  26 #include <unotools/localfilehelper.hxx>
  27
  28 using namespace ::com::sun::star;
  29
  30 namespace avmedia { namespace macavf {
  31
  32 FrameGrabber::FrameGrabber( const uno::Reference< lang::XMultiServiceFactory >& /*rxMgr*/ )
  33 :   mpImageGen( nullptr )
  34 {}
  35
  36
  37 FrameGrabber::~FrameGrabber()
  38 {
  39     if( mpImageGen )
  40         CFRelease( mpImageGen );
  41 }
  42
  43
  44 bool FrameGrabber::create( const ::rtl::OUString& rURL )
  45 {
  46     NSString* pNSStr = [NSString stringWithCharacters:reinterpret_cast<unichar const *>(rURL.getStr()) length:rURL.getLength()];
  47     SAL_WNODEPRECATED_DECLARATIONS_PUSH
  48         //TODO: 10.11 stringByAddingPercentEscapesUsingEncoding
  49     NSURL* pNSURL = [NSURL URLWithString: [pNSStr stringByAddingPercentEscapesUsingEncoding:NSUTF8StringEncoding]];
  50     SAL_WNODEPRECATED_DECLARATIONS_POP
  51     AVAsset* pMovie = [AVURLAsset URLAssetWithURL:pNSURL options:nil];
  52     if( !pMovie )
  53     {
  54         SAL_WARN("avmedia", "AVGrabber::create() cannot load url=" << [pNSStr UTF8String] );
  55         return false;
  56     }
  57
  58     return create( pMovie );
  59 }
  60
  61
  62 bool FrameGrabber::create( AVAsset* pMovie )
  63 {
  64     if( [[pMovie tracksWithMediaType:AVMediaTypeVideo] count] == 0)
  65     {
  66         SAL_WARN("avmedia", "AVGrabber::create() found no video content!" );
  67         return false;
  68     }
  69
  70     mpImageGen = [AVAssetImageGenerator assetImageGeneratorWithAsset:pMovie];
  71     CFRetain( mpImageGen );
  72     return true;
  73 }
  74
  75
  76 uno::Reference< graphic::XGraphic > SAL_CALL FrameGrabber::grabFrame( double fMediaTime )
  77 {
  78     uno::Reference< graphic::XGraphic > xRet;
  79     if( !mpImageGen )
  80         return xRet;
  81
  82     // get the requested image from the movie
  83     CGImage* pCGImage = [mpImageGen copyCGImageAtTime:CMTimeMakeWithSeconds(fMediaTime,1000) actualTime:nullptr error:nullptr];
  84
  85     // convert the image to a TIFF-formatted byte-array
  86     CFMutableDataRef pCFData = CFDataCreateMutable( kCFAllocatorDefault, 0 );
  87     CGImageDestination* pCGImgDest = CGImageDestinationCreateWithData( pCFData, kUTTypeTIFF, 1, nullptr );
  88     CGImageDestinationAddImage( pCGImgDest, pCGImage, nullptr );
  89     CGImageDestinationFinalize( pCGImgDest );
  90     CFRelease( pCGImgDest );
  91     const long nBitmapLen = CFDataGetLength( pCFData );
  92     UInt8 * pBitmapBytes = const_cast<UInt8 *>(CFDataGetBytePtr( pCFData ));
  93
  94     // convert the image into the return-value type which is a graphic::XGraphic
  95     SvMemoryStream aMemStm( pBitmapBytes, nBitmapLen, StreamMode::READ | StreamMode::WRITE );
  96     Graphic aGraphic;
  97     if( GraphicConverter::Import( aMemStm, aGraphic, ConvertDataFormat::TIF ) == ERRCODE_NONE )
  98         xRet = aGraphic.GetXGraphic();
  99
 100     // clean up resources
 101     CFRelease( pCFData );
 102     return xRet;
 103 }
 104
 105
 106 ::rtl::OUString SAL_CALL FrameGrabber::getImplementationName(  )
 107 {
 108     return ::rtl::OUString( AVMEDIA_MACAVF_FRAMEGRABBER_IMPLEMENTATIONNAME );
 109 }
 110
 111 sal_Bool SAL_CALL FrameGrabber::supportsService( const ::rtl::OUString& ServiceName )
 112 {
 113     return ServiceName == AVMEDIA_MACAVF_FRAMEGRABBER_SERVICENAME;
 114 }
 115
 116 uno::Sequence< ::rtl::OUString > SAL_CALL FrameGrabber::getSupportedServiceNames(  )
 117 {
 118     return { AVMEDIA_MACAVF_FRAMEGRABBER_SERVICENAME };
 119 }
 120
 121 } // namespace macavf
 122 } // namespace avmedia
 123
 124 /* vim:set shiftwidth=4 softtabstop=4 expandtab: */