avmedia/source/macavf/player.mm

   1 /* -*- Mode: C++; tab-width: 4; indent-tabs-mode: nil; c-basic-offset: 4 -*- */
   2 /*
   3  * This file is part of the LibreOffice project.
   4  *
   5  * This Source Code Form is subject to the terms of the Mozilla Public
   6  * License, v. 2.0. If a copy of the MPL was not distributed with this
   7  * file, You can obtain one at http://mozilla.org/MPL/2.0/.
   8  *
   9  * This file incorporates work covered by the following license notice:
  10  *
  11  *   Licensed to the Apache Software Foundation (ASF) under one or more
  12  *   contributor license agreements. See the NOTICE file distributed
  13  *   with this work for additional information regarding copyright
  14  *   ownership. The ASF licenses this file to you under the Apache
  15  *   License, Version 2.0 (the "License"); you may not use this file
  16  *   except in compliance with the License. You may obtain a copy of
  17  *   the License at http://www.apache.org/licenses/LICENSE-2.0 .
  18  */
  19
  20 #include "player.hxx"
  21 #include "framegrabber.hxx"
  22 #include "window.hxx"
  23
  24 #include <cmath> // for log10()
  25
  26 using namespace ::com::sun::star;
  27
  28 @implementation MacAVObserverObject
  29
  30 - (void)observeValueForKeyPath:(NSString*)pKeyPath ofObject:(id)pObject change:(NSDictionary*)pChangeDict context:(void*)pContext
  31 {
  32     (void) pObject;
  33     (void) pChangeDict;
  34     avmedia::macavf::MacAVObserverHandler* pHandler = static_cast<avmedia::macavf::MacAVObserverHandler*>(pContext);
  35     pHandler->handleObservation( pKeyPath );
  36 }
  37
  38 - (void)onNotification:(NSNotification*)pNotification
  39 {
  40     NSString* pNoteName = (NSString*)[pNotification name];
  41     HandlersForObject::iterator it = maHandlersForObject.find( [pNotification object]);
  42     if( it != maHandlersForObject.end() )
  43         (*it).second->handleObservation( pNoteName );
  44 }
  45
  46 - (void)setHandlerForObject:(NSObject*)pObject handler:(avmedia::macavf::MacAVObserverHandler*)pHandler
  47 {
  48     maHandlersForObject[ pObject] = pHandler;
  49 }
  50
  51 - (void)removeHandlerForObject:(NSObject*)pObject
  52 {
  53     maHandlersForObject.erase( pObject);
  54 }
  55
  56 @end
  57
  58
  59 namespace avmedia { namespace macavf {
  60
  61 MacAVObserverObject* MacAVObserverHandler::mpMacAVObserverObject = nullptr;
  62
  63 MacAVObserverObject* MacAVObserverHandler::getObserver()
  64 {
  65     if( !mpMacAVObserverObject)
  66     {
  67         mpMacAVObserverObject = [MacAVObserverObject alloc];
  68         [mpMacAVObserverObject retain];
  69     }
  70     return mpMacAVObserverObject;
  71 }
  72
  73
  74 Player::Player( const uno::Reference< lang::XMultiServiceFactory >& rxMgr )
  75 :   mxMgr( rxMgr )
  76 ,   mpPlayer( nullptr )
  77 ,   mfUnmutedVolume( 0 )
  78 ,   mfStopTime( DBL_MAX )
  79 ,   mbMuted( false )
  80 ,   mbLooping( false )
  81 {}
  82
  83
  84 Player::~Player()
  85 {
  86     if( !mpPlayer )
  87         return;
  88     // remove the observers
  89     [mpPlayer removeObserver:getObserver() forKeyPath:@"currentItem.status"];
  90     AVPlayerItem* pOldPlayerItem = [mpPlayer currentItem];
  91     [[NSNotificationCenter defaultCenter] removeObserver:getObserver()
  92         name:AVPlayerItemDidPlayToEndTimeNotification
  93         object:pOldPlayerItem];
  94     [getObserver() removeHandlerForObject:pOldPlayerItem];
  95     // release the AVPlayer
  96     CFRelease( mpPlayer );
  97 }
  98
  99
 100 bool Player::handleObservation( NSString* pKeyPath )
 101 {
 102     if( [pKeyPath isEqualToString:AVPlayerItemDidPlayToEndTimeNotification])
 103     {
 104         if( mbLooping )
 105             setMediaTime( 0.0);
 106     }
 107     return true;
 108 }
 109
 110
 111 bool Player::create( const ::rtl::OUString& rURL )
 112 {
 113     // get the media asset
 114     NSString* aNSStr = [NSString stringWithCharacters:reinterpret_cast<unichar const *>(rURL.getStr()) length:rURL.getLength()];
 115     SAL_WNODEPRECATED_DECLARATIONS_PUSH
 116         //TODO: 10.11 stringByAddingPercentEscapesUsingEncoding
 117     NSURL* aNSURL = [NSURL URLWithString: [aNSStr stringByAddingPercentEscapesUsingEncoding:NSUTF8StringEncoding]];
 118     SAL_WNODEPRECATED_DECLARATIONS_POP
 119     // get the matching AVPlayerItem
 120     AVPlayerItem* pPlayerItem = [AVPlayerItem playerItemWithURL:aNSURL];
 121
 122     // create or update the AVPlayer with the new AVPlayerItem
 123     if( !mpPlayer )
 124     {
 125         mpPlayer = [AVPlayer playerWithPlayerItem:pPlayerItem];
 126         CFRetain( mpPlayer );
 127         [mpPlayer setActionAtItemEnd:AVPlayerActionAtItemEndNone];
 128     }
 129     else
 130     {
 131         // remove the obsoleted observers
 132         AVPlayerItem* pOldPlayerItem = [mpPlayer currentItem];
 133         [mpPlayer removeObserver:getObserver() forKeyPath:@"currentItem.status"];
 134         [getObserver() removeHandlerForObject:pOldPlayerItem];
 135         [[NSNotificationCenter defaultCenter] removeObserver:getObserver()
 136             name:AVPlayerItemDidPlayToEndTimeNotification
 137             object:pOldPlayerItem];
 138         // replace the playeritem
 139         [mpPlayer replaceCurrentItemWithPlayerItem:pPlayerItem];
 140     }
 141
 142     // observe the status of the current player item
 143     [mpPlayer addObserver:getObserver() forKeyPath:@"currentItem.status" options:0 context:this];
 144
 145     // observe playback-end needed for playback looping
 146     [[NSNotificationCenter defaultCenter] addObserver:getObserver()
 147         selector:@selector(onNotification:)
 148         name:AVPlayerItemDidPlayToEndTimeNotification
 149         object:pPlayerItem];
 150     [getObserver() setHandlerForObject:pPlayerItem handler:this];
 151
 152     return true;
 153 }
 154
 155
 156 void SAL_CALL Player::start()
 157 {
 158     if( !mpPlayer )
 159         return;
 160
 161     [mpPlayer play];
 162     // else // TODO: delay until it becomes ready
 163 }
 164
 165
 166 void SAL_CALL Player::stop()
 167 {
 168     if( !mpPlayer )
 169         return;
 170     const bool bPlaying = isPlaying();
 171     if( bPlaying )
 172         [mpPlayer pause];
 173 }
 174
 175
 176 sal_Bool SAL_CALL Player::isPlaying()
 177 {
 178     if( !mpPlayer )
 179         return false;
 180     const float fRate = [mpPlayer rate];
 181     return (fRate != 0.0);
 182 }
 183
 184
 185 double SAL_CALL Player::getDuration()
 186 {
 187     // slideshow checks for non-zero duration, so cheat here
 188     double duration = 0.01;
 189
 190     if( mpPlayer )
 191     {
 192         AVPlayerItem* pItem = [mpPlayer currentItem];
 193         if( [pItem status] == AVPlayerItemStatusReadyToPlay )
 194             duration = CMTimeGetSeconds( [pItem duration] );
 195         else // fall back to AVAsset's best guess
 196             duration = CMTimeGetSeconds( [[pItem asset] duration] );
 197     }
 198
 199     return duration;
 200 }
 201
 202
 203 void SAL_CALL Player::setMediaTime( double fTime )
 204 {
 205     if( mpPlayer )
 206         [mpPlayer seekToTime: CMTimeMakeWithSeconds(fTime,1000) ];
 207 }
 208
 209
 210 double SAL_CALL Player::getMediaTime()
 211 {
 212     if( !mpPlayer )
 213         return 0.0;
 214
 215     const double position = CMTimeGetSeconds( [mpPlayer currentTime] );
 216     if( position >= mfStopTime )
 217         if( isPlaying() )
 218             stop();
 219
 220     return position;
 221 }
 222
 223
 224 void SAL_CALL Player::setStopTime( double fTime )
 225 {
 226     mfStopTime = fTime;
 227 }
 228
 229
 230 double SAL_CALL Player::getStopTime()
 231 {
 232     return mfStopTime;
 233 }
 234
 235
 236 void SAL_CALL Player::setPlaybackLoop( sal_Bool bSet )
 237 {
 238     mbLooping = bSet;
 239 }
 240
 241
 242 sal_Bool SAL_CALL Player::isPlaybackLoop()
 243 {
 244     return mbLooping;
 245 }
 246
 247
 248 void SAL_CALL Player::setMute( sal_Bool bSet )
 249 {
 250     if( !mpPlayer )
 251         return;
 252
 253     mbMuted = bSet;
 254     [mpPlayer setMuted:mbMuted];
 255 }
 256
 257
 258 sal_Bool SAL_CALL Player::isMute()
 259 {
 260     return mbMuted;
 261 }
 262
 263
 264 void SAL_CALL Player::setVolumeDB( sal_Int16 nVolumeDB )
 265 {
 266     // -40dB <-> AVPlayer volume 0.0
 267     //   0dB <-> AVPlayer volume 1.0
 268     mfUnmutedVolume = (nVolumeDB <= -40) ? 0.0 : pow( 10.0, nVolumeDB / 20.0 );
 269
 270     // change volume
 271     if( !mbMuted && mpPlayer )
 272         [mpPlayer setVolume:mfUnmutedVolume];
 273 }
 274
 275
 276 sal_Int16 SAL_CALL Player::getVolumeDB()
 277 {
 278     if( !mpPlayer )
 279         return 0;
 280
 281     // get the actual volume
 282     const float fVolume = [mpPlayer volume];
 283
 284     // convert into Dezibel value
 285     // -40dB <-> AVPlayer volume 0.0
 286     //   0dB <-> AVPlayer volume 1.0
 287     const int nVolumeDB = (fVolume <= 0) ? -40 : lrint( 20.0*log10(fVolume));
 288
 289     return (sal_Int16)nVolumeDB;
 290 }
 291
 292
 293 awt::Size SAL_CALL Player::getPreferredPlayerWindowSize()
 294 {
 295     awt::Size aSize( 0, 0 ); // default size
 296
 297     AVAsset* pMovie = [[mpPlayer currentItem] asset];
 298     NSArray* pVideoTracks = [pMovie tracksWithMediaType:AVMediaTypeVideo];
 299     if ([pVideoTracks count] > 0)
 300     {
 301         AVAssetTrack* pFirstVideoTrack = (AVAssetTrack*) [pVideoTracks objectAtIndex:0];
 302         const CGSize aPrefSize = [pFirstVideoTrack naturalSize];
 303         aSize = awt::Size( aPrefSize.width, aPrefSize.height );
 304     }
 305
 306     return aSize;
 307 }
 308
 309
 310 uno::Reference< ::media::XPlayerWindow > SAL_CALL Player::createPlayerWindow( const uno::Sequence< uno::Any >& aArguments )
 311 {
 312     // get the preferred window size
 313     const awt::Size aSize( getPreferredPlayerWindowSize() );
 314
 315     // get the parent view
 316     sal_IntPtr nNSViewPtr = 0;
 317     aArguments[0] >>= nNSViewPtr;
 318     NSView* pParentView = reinterpret_cast<NSView*>(nNSViewPtr);
 319
 320     // check the window parameters
 321     uno::Reference< ::media::XPlayerWindow > xRet;
 322     if( (aSize.Width <= 0) || (aSize.Height <= 0) || (pParentView == nullptr) )
 323          return xRet;
 324
 325     // create the window
 326     ::avmedia::macavf::Window* pWindow = new ::avmedia::macavf::Window( mxMgr, *this, pParentView );
 327     xRet = pWindow;
 328     return xRet;
 329 }
 330
 331
 332 uno::Reference< media::XFrameGrabber > SAL_CALL Player::createFrameGrabber()
 333 {
 334     uno::Reference< media::XFrameGrabber > xRet;
 335
 336     FrameGrabber* pGrabber = new FrameGrabber( mxMgr );
 337     AVAsset* pMovie = [[mpPlayer currentItem] asset];
 338     if( pGrabber->create( pMovie ) )
 339         xRet = pGrabber;
 340
 341     return xRet;
 342 }
 343
 344
 345 ::rtl::OUString SAL_CALL Player::getImplementationName(  )
 346 {
 347     return ::rtl::OUString( AVMEDIA_MACAVF_PLAYER_IMPLEMENTATIONNAME );
 348 }
 349
 350
 351 sal_Bool SAL_CALL Player::supportsService( const ::rtl::OUString& ServiceName )
 352 {
 353     return ServiceName == AVMEDIA_MACAVF_PLAYER_SERVICENAME;
 354 }
 355
 356
 357 uno::Sequence< ::rtl::OUString > SAL_CALL Player::getSupportedServiceNames(  )
 358 {
 359     return { AVMEDIA_MACAVF_PLAYER_SERVICENAME };
 360 }
 361
 362 } // namespace macavf
 363 } // namespace avmedia
 364
 365 /* vim:set shiftwidth=4 softtabstop=4 expandtab: */