modules/CMakeProjectCreator.pm

   1 package CMakeProjectCreator;
   2
   3 # ************************************************************
   4 # Description   : A CMake Project Creator
   5 # Author        : Chad Elliott
   6 # Create Date   : 10/10/2022
   7 # ************************************************************
   8
   9 # ************************************************************
  10 # Pragmas
  11 # ************************************************************
  12
  13 use strict;
  14
  15 use ProjectCreator;
  16
  17 use vars qw(@ISA);
  18 @ISA = qw(ProjectCreator);
  19
  20 # ************************************************************
  21 # Subroutine Section
  22 # ************************************************************
  23
  24 sub pre_generation {
  25   my $self = shift;
  26
  27   ## For CMake, we are expecting a hybrid of custom types and modules.
  28   ## We are turning off all automatic output so that the modules defined
  29   ## for CMake can handle these artifacts.
  30   foreach my $gentype (keys %{$self->{'generated_exts'}}) {
  31     $self->{'generated_exts'}->{$gentype}->{'automatic_out'} = 0;
  32   }
  33 }
  34
  35 sub default_to_library {
  36   ## In case there are only generated source files...
  37   return 1;
  38 }
  39
  40 sub need_to_write_project {
  41   my $self = shift;
  42
  43   ## Because we do not automatically add custom output, it is possible that
  44   ## the project only has generated source files and expects them to cause
  45   ## an automatic library name to be chosen.  If the base
  46   ## need_to_write_project() tells us that it's only generated source files
  47   ## but the user didn't mark this project as "custom only", then we have to
  48   ## override it back to 1 to retain the user provided target name.
  49   my $status = $self->SUPER::need_to_write_project();
  50   if ($status == 2 && !$self->get_assignment('custom_only')) {
  51     $status = 1;
  52   }
  53
  54   return $status;
  55 }
  56
  57 sub get_use_env {
  58   ## Override the option getter so that, for CMake, MPC always functions as
  59   ## if the -use_env option was supplied on the command line.
  60   return 1;
  61 }
  62
  63 sub pre_write_output_file {
  64   my $self = shift;
  65   return $self->combine_custom_types();
  66 }
  67
  68 sub dollar_special {
  69   return 1;
  70 }
  71
  72 sub project_file_prefix {
  73   return "CMakeLists.";
  74 }
  75
  76 sub escape_spaces {
  77   #my $self = shift;
  78   return 1;
  79 }
  80
  81 sub get_dll_exe_template_input_file {
  82   return 'cmakeexe';
  83 }
  84
  85 sub get_dll_template_input_file {
  86   return 'cmakedll';
  87 }
  88
  89 sub fill_value {
  90   my($self, $name) = @_;
  91
  92   if ($name eq 'language') {
  93     ## Currently, we only support C++
  94     return 'CXX' if ($self->get_language() eq Creator::cplusplus());
  95   }
  96   elsif ($name =~ /^env_(\w+)/) {
  97     my $dotdir = '${CMAKE_CURRENT_SOURCE_DIR}' .
  98                  ($1 eq 'libpaths' ? ' ${CMAKE_CURRENT_BINARY_DIR}' : '');
  99     my $paths = $self->get_assignment($1);
 100     if (defined $paths) {
 101       $paths = $self->create_array($paths);
 102       foreach my $path (@$paths) {
 103         if ($path eq '.') {
 104           $path = $dotdir;
 105         }
 106         else {
 107           $path =~ s/\$\(([^\)]+)\)/\${$1}/g;
 108         }
 109       }
 110       return "@$paths";
 111     }
 112   }
 113
 114   return undef;
 115 }
 116
 117 1;