modules/HTMLProjectCreator.pm

   1 package HTMLProjectCreator;
   2
   3 # ************************************************************
   4 # Description   : An HTML project creator to display all settings
   5 # Author        : Justin Michel & Chad Elliott
   6 # Create Date   : 8/25/2003
   7 # ************************************************************
   8
   9 # ************************************************************
  10 # Pragmas
  11 # ************************************************************
  12
  13 use strict;
  14
  15 use ProjectCreator;
  16 use XMLProjectBase;
  17
  18 use vars qw(@ISA);
  19 @ISA = qw(XMLProjectBase ProjectCreator);
  20
  21 # ************************************************************
  22 # Data Section
  23 # ************************************************************
  24
  25 my $style_indent = .5;
  26
  27 # ************************************************************
  28 # Subroutine Section
  29 # ************************************************************
  30
  31 sub file_sorter {
  32   #my $self  = shift;
  33   #my $left  = shift;
  34   #my $right = shift;
  35   return lc($_[1]) cmp lc($_[2]);
  36 }
  37
  38
  39 sub label_nodes {
  40   my($self, $hash, $nodes, $level) = @_;
  41
  42   foreach my $key (sort keys %$hash) {
  43     push(@$nodes, [$level, $key]);
  44     $self->label_nodes($$hash{$key}, $nodes, $level + 1);
  45   }
  46 }
  47
  48
  49 sub count_levels {
  50   my($self, $hash, $current, $count) = @_;
  51
  52   foreach my $key (keys %$hash) {
  53     $self->count_levels($$hash{$key}, $current + 1, $count);
  54   }
  55   $$count = $current if ($current > $$count);
  56 }
  57
  58
  59 sub fill_value {
  60   my($self, $name) = @_;
  61   my $value;
  62
  63   if ($name eq 'inheritance_nodes') {
  64     ## Get the nodes with numeric labels for the level
  65     my @nodes;
  66     $self->label_nodes($self->get_inheritance_tree(), \@nodes, 0);
  67
  68     ## Push each node onto the value array
  69     $value = [];
  70     for(my $i = 0; $i <= $#nodes; ++$i) {
  71       my $file = $nodes[$i]->[1];
  72       my $dir  = $self->mpc_dirname($file);
  73       my $base = $self->mpc_basename($file);
  74
  75       ## Relative paths do not work at all in a web browser
  76       $file = $base if ($dir eq '.');
  77
  78       my $path = ($base eq $file ? $self->getcwd() . '/' : '');
  79       my $name;
  80
  81       if ($i == 0) {
  82         ## If this is the first node, then replace the base filename
  83         ## with the actual project name.
  84         $name = $self->project_name();
  85       }
  86       else {
  87         ## This is a base project, so we use the basename and
  88         ## remove the file extension.
  89         $name = $base;
  90         $name =~ s/\.[^\.]+$//;
  91       }
  92
  93       ## Create the div and a tags.
  94       push(@$value, '<a href="file://' . $path . $file .
  95                     '" onClick="return popup(this, \'Project File\')" ' .
  96                     'target=_blank>' .
  97                     '<div class="tree' . $nodes[$i]->[0] . '">' .
  98                      $name . '</div></a>');
  99     }
 100   }
 101   elsif ($name eq 'tree_styles') {
 102     ## Count the number of levels deep the inheritance goes
 103     my $count = 0;
 104     $self->count_levels($self->get_inheritance_tree(), 0, \$count);
 105
 106     my $margin = 0;
 107     my $start  = 100;
 108     my $max    = 255;
 109     my $inc    = ($count ne 0 ? int(($max - $start) / $count) : $max);
 110
 111     ## Push each tree style onto the value array
 112     $value = [];
 113     for(my $i = 0; $i < $count; ++$i) {
 114       push(@$value, ".tree$i { background-color: #" .
 115                     sprintf("%02x%02x%02x", 0, $start, $start) . ';' .
 116                     ($margin != 0 ? " margin-left: $margin" . 'in;' : '') .
 117                     ' }');
 118       $start += $inc;
 119       $margin += $style_indent;
 120     }
 121   }
 122
 123   return $value;
 124 }
 125
 126
 127 sub project_file_extension {
 128   #my $self = shift;
 129   return '.html';
 130 }
 131
 132
 133 1;