mogfileinfo

   1 #!/usr/bin/perl
   2
   3 =head1 NAME
   4
   5 mogfileinfo -- Fetch key metadata from a MogileFS installation
   6
   7 =head1 SYNOPSIS
   8
   9     $ mogfileinfo --trackers=host --domain=foo --key="/hello.jpg"
  10
  11 =head1 OPTIONS
  12
  13 =over
  14
  15 =item --trackers=host1:7001,host2:7001
  16
  17 Use these MogileFS trackers to negotiate with.
  18
  19 =item --domain=<domain>
  20
  21 Set the MogileFS domain to use.
  22
  23 =item --key="<key>"
  24
  25 The key to inspect. Can be an arbitrary string.
  26
  27 =back
  28
  29 =head1 AUTHOR
  30
  31 Dormando E<lt>L<dormando@rydia.net>E<gt>
  32
  33 =head1 BUGS
  34
  35 None known, but output might change in the future.
  36
  37 =head1 LICENSE
  38
  39 Licensed for use and redistribution under the same terms as Perl itself.
  40
  41 =cut
  42
  43 use strict;
  44 use warnings;
  45
  46 use lib './lib';
  47 use MogileFS::Utils;
  48
  49 my $util = MogileFS::Utils->new;
  50 my $usage = "--trackers=host --domain=foo --key='/hello.jpg'";
  51 my $c = $util->getopts($usage, 'key=s');
  52
  53 my $mogc = $util->client;
  54
  55 my $fid = $mogc->file_info($c->{key});
  56 if ($mogc->errcode) {
  57     die "Error fetching file info: " . $mogc->errstr;
  58 }
  59 die "Key not found: " . $c->{key} unless $fid;
  60
  61 # Might replace this with just fetching the devids from above...
  62 my @paths = $mogc->get_paths($c->{key}, { noverify => 1, pathcount => 99 });
  63 if ($mogc->errcode) {
  64     die "Error fetching paths: " . $mogc->errstr;
  65 }
  66 die "No paths found or key does not exist" unless @paths;
  67
  68 print "- file: ", $c->{key}, "\n";
  69 for my $item (sort keys %$fid) {
  70     printf("  %8s: %20s\n", $item, $fid->{$item});
  71 }
  72
  73 for my $path (@paths) {
  74     print " - ", $path, "\n";
  75 }