pkgs/build-support/closure-info.nix

   1 # This derivation builds two files containing information about the
   2 # closure of 'rootPaths': $out/store-paths contains the paths in the
   3 # closure, and $out/registration contains a file suitable for use with
   4 # "nix-store --load-db" and "nix-store --register-validity
   5 # --hash-given".
   6
   7 { stdenv, buildPackages }:
   8
   9 { rootPaths }:
  10
  11 assert builtins.langVersion >= 5;
  12
  13 stdenv.mkDerivation {
  14   name = "closure-info";
  15
  16   __structuredAttrs = true;
  17
  18   exportReferencesGraph.closure = rootPaths;
  19
  20   preferLocalBuild = true;
  21
  22   PATH = "${buildPackages.coreutils}/bin:${buildPackages.jq}/bin";
  23
  24   builder = builtins.toFile "builder"
  25     ''
  26       . .attrs.sh
  27
  28       out=''${outputs[out]}
  29
  30       mkdir $out
  31
  32       jq -r ".closure | map(.narSize) | add" < .attrs.json > $out/total-nar-size
  33       jq -r '.closure | map([.path, .narHash, .narSize, "", (.references | length)] + .references) | add | map("\(.)\n") | add' < .attrs.json | head -n -1 > $out/registration
  34       jq -r .closure[].path < .attrs.json > $out/store-paths
  35     '';
  36 }