pkgs/applications/audio/mbrola/default.nix

   1 { stdenv, lib, fetchFromGitHub, runCommandLocal, mbrola-voices }:
   2
   3 let
   4   pname = "mbrola";
   5   version = "3.3";
   6
   7   meta = with lib; {
   8     license = licenses.agpl3Plus;
   9     maintainers = with maintainers; [ davidak ];
  10     platforms = platforms.all;
  11     description = "Speech synthesizer based on the concatenation of diphones";
  12     homepage = "https://github.com/numediart/MBROLA";
  13   };
  14
  15   bin = stdenv.mkDerivation {
  16     pname = "${pname}-bin";
  17     inherit version;
  18
  19     src = fetchFromGitHub {
  20       owner = "numediart";
  21       repo = "MBROLA";
  22       rev = version;
  23       sha256 = "1w86gv6zs2cbr0731n49z8v6xxw0g8b0hzyv2iqb9mqcfh38l8zy";
  24     };
  25
  26     # required for cross compilation
  27     makeFlags = [ "CC=${stdenv.cc.targetPrefix}cc" ];
  28
  29     env = lib.optionalAttrs stdenv.cc.isGNU {
  30       NIX_CFLAGS_COMPILE = "-Wno-error=implicit-function-declaration";
  31     };
  32
  33     installPhase = ''
  34       runHook preInstall
  35       install -D Bin/mbrola $out/bin/mbrola
  36       rm -rf $out/share/mbrola/voices/*
  37       runHook postInstall
  38     '';
  39
  40     meta = meta // {
  41       description = "Speech synthesizer based on the concatenation of diphones (binary only)";
  42     };
  43   };
  44
  45 in
  46   runCommandLocal
  47     "${pname}-${version}"
  48     {
  49       inherit pname version meta;
  50     }
  51     ''
  52       mkdir -p "$out/share/mbrola"
  53       ln -s '${mbrola-voices}/data' "$out/share/mbrola/voices"
  54       ln -s '${bin}/bin' "$out/"
  55     ''