pkgs/applications/audio/mbrola/voices.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   mbrola,
   6   languages ? [ ],
   7 }:
   8
   9 let
  10   src = fetchFromGitHub {
  11     owner = "numediart";
  12     repo = "MBROLA-voices";
  13     rev = "fe05a0ccef6a941207fd6aaad0b31294a1f93a51";
  14     hash = "sha256-QBUggnde5iNeCESzxE0btVVTDOxc3Kdk483mdGUXHvA=";
  15   };
  16
  17   meta = {
  18     description = "Speech synthesizer based on the concatenation of diphones (voice files)";
  19     homepage = "https://github.com/numediart/MBROLA-voices";
  20     license = mbrola.meta.license;
  21   };
  22 in
  23
  24 if (languages == [ ]) then
  25   src // { inherit meta; }
  26 else
  27   stdenv.mkDerivation {
  28     pname = "mbrola-voices";
  29     version = "0-unstable-2020-03-30";
  30
  31     inherit src;
  32
  33     postPatch = ''
  34       shopt -s extglob
  35       pushd data
  36       rm -rfv !(${lib.concatStringsSep "|" languages})
  37       popd
  38     '';
  39
  40     installPhase = ''
  41       runHook preInstall
  42
  43       mkdir $out
  44       cp -R data $out/
  45
  46       runHook postInstall
  47     '';
  48
  49     inherit meta;
  50   }