pkgs/applications/audio/mellowplayer/default.nix

   1 { cmake
   2 , fetchFromGitLab
   3 , lib
   4 , libnotify
   5 , mkDerivation
   6 , pkg-config
   7 , qtbase
   8 , qtdeclarative
   9 , qtgraphicaleffects
  10 , qtquickcontrols2
  11 , qttools
  12 , qtwebengine
  13 , stdenv
  14 }:
  15
  16 mkDerivation rec {
  17   pname = "MellowPlayer";
  18   version = "3.6.8";
  19
  20   src = fetchFromGitLab {
  21     owner = "ColinDuquesnoy";
  22     repo = "MellowPlayer";
  23     rev = version;
  24     hash = "sha256-rsF2xQet7U8d4oGU/HgghvE3vvmkxjlGXPBlLD9mWTk=";
  25   };
  26
  27   nativeBuildInputs = [ cmake pkg-config ];
  28
  29   buildInputs = [
  30     libnotify
  31     qtbase
  32     qtdeclarative
  33     qtgraphicaleffects
  34     qtquickcontrols2
  35     qttools
  36     qtwebengine
  37   ];
  38
  39   doCheck = true;
  40
  41   cmakeFlags = [ "-DBUILD_TESTS=ON" ];
  42
  43   preCheck = ''
  44     # Running the tests requires a location at the home directory for logging.
  45     export HOME="$NIX_BUILD_TOP/home"
  46     mkdir -p "$HOME/.local/share/MellowPlayer.Tests/MellowPlayer.Tests/Logs"
  47
  48     # Without this, the tests fail because they cannot create the QT Window
  49     export QT_QPA_PLATFORM=offscreen
  50   ''
  51   # TODO: The tests are failing because it can't locate QT plugins. Is there a better way to do this?
  52   + (builtins.concatStringsSep "\n" (lib.lists.flatten (builtins.map
  53       (pkg: [
  54         (lib.optionalString (pkg ? qtPluginPrefix) ''
  55           export QT_PLUGIN_PATH="${pkg}/${pkg.qtPluginPrefix}"''${QT_PLUGIN_PATH:+':'}$QT_PLUGIN_PATH
  56         '')
  57
  58         (lib.optionalString (pkg ? qtQmlPrefix) ''
  59           export QML2_IMPORT_PATH="${pkg}/${pkg.qtQmlPrefix}"''${QML2_IMPORT_PATH:+':'}$QML2_IMPORT_PATH
  60         '')
  61       ]) buildInputs)));
  62
  63   meta = with lib; {
  64     inherit (qtbase.meta) platforms;
  65     broken = stdenv.hostPlatform.isDarwin; # test build fails, but the project is not maintained anymore
  66
  67     description = "Cloud music integration for your desktop";
  68     mainProgram = "MellowPlayer";
  69     homepage = "https://gitlab.com/ColinDuquesnoy/MellowPlayer";
  70     license = licenses.gpl2;
  71     maintainers = with maintainers; [ kalbasit ];
  72   };
  73 }