pkgs/applications/blockchains/solana-validator/default.nix

   1 # largely inspired from https://github.com/saber-hq/saber-overlay/blob/master/packages/solana/solana.nix
   2
   3 { stdenv
   4 , fetchFromGitHub
   5 , lib
   6 , rustPlatform
   7 , pkg-config
   8 , darwin
   9 , udev
  10 , zlib
  11 , protobuf
  12 , openssl
  13 , libclang
  14 , libcxx
  15 , rocksdb_8_3
  16 , rustfmt
  17 , perl
  18 , hidapi
  19 , solanaPkgs ? [
  20     "solana"
  21     "solana-bench-tps"
  22     "solana-faucet"
  23     "solana-gossip"
  24     "solana-install"
  25     "solana-keygen"
  26     "solana-ledger-tool"
  27     "solana-log-analyzer"
  28     "solana-net-shaper"
  29     "solana-validator"
  30     "cargo-build-bpf"
  31     "cargo-test-bpf"
  32     "solana-dos"
  33     "solana-install-init"
  34     "solana-stake-accounts"
  35     "solana-test-validator"
  36     "solana-tokens"
  37     "solana-watchtower"
  38   ] ++ [
  39     # XXX: Ensure `solana-genesis` is built LAST!
  40     # See https://github.com/solana-labs/solana/issues/5826
  41     "solana-genesis"
  42   ]
  43 }:
  44 let
  45   pinData = lib.importJSON ./pin.json;
  46   version = pinData.version;
  47   hash = pinData.hash;
  48   rocksdb = rocksdb_8_3;
  49   inherit (darwin.apple_sdk_11_0) Libsystem;
  50   inherit (darwin.apple_sdk_11_0.frameworks) System IOKit AppKit Security;
  51 in
  52 rustPlatform.buildRustPackage rec {
  53   pname = "solana-validator";
  54   inherit version;
  55
  56   src = fetchFromGitHub {
  57     owner = "solana-labs";
  58     repo = "solana";
  59     rev = "v${version}";
  60     inherit hash;
  61   };
  62
  63   cargoLock = {
  64     lockFile = ./Cargo.lock;
  65     outputHashes = {
  66       "crossbeam-epoch-0.9.5" = "sha256-Jf0RarsgJiXiZ+ddy0vp4jQ59J9m0k3sgXhWhCdhgws=";
  67       "tokio-1.29.1" = "sha256-Z/kewMCqkPVTXdoBcSaFKG5GSQAdkdpj3mAzLLCjjGk=";
  68     };
  69   };
  70
  71   cargoBuildFlags = builtins.map (n: "--bin=${n}") solanaPkgs;
  72
  73   # weird errors. see https://github.com/NixOS/nixpkgs/issues/52447#issuecomment-852079285
  74   # LLVM_CONFIG_PATH = "${llvm}/bin/llvm-config";
  75
  76   nativeBuildInputs = [ pkg-config protobuf rustfmt perl rustPlatform.bindgenHook ];
  77   buildInputs =
  78     [ openssl zlib libclang hidapi ] ++ (lib.optionals stdenv.hostPlatform.isLinux [ udev ])
  79     ++ lib.optionals stdenv.hostPlatform.isDarwin [ Security System Libsystem libcxx ];
  80   strictDeps = true;
  81
  82   doCheck = false;
  83
  84   env = {
  85     # Used by build.rs in the rocksdb-sys crate. If we don't set these, it would
  86     # try to build RocksDB from source.
  87     ROCKSDB_LIB_DIR = "${lib.getLib rocksdb}/lib";
  88
  89     # If set, always finds OpenSSL in the system, even if the vendored feature is enabled.
  90     OPENSSL_NO_VENDOR = "1";
  91   } // lib.optionalAttrs stdenv.hostPlatform.isDarwin {
  92     # Require this on darwin otherwise the compiler starts rambling about missing
  93     # cmath functions
  94     CPPFLAGS = "-isystem ${lib.getDev libcxx}/include/c++/v1";
  95     LDFLAGS = "-L${lib.getLib libcxx}/lib";
  96   };
  97
  98   meta = with lib; {
  99     description = "Web-Scale Blockchain for fast, secure, scalable, decentralized apps and marketplaces.";
 100     homepage = "https://solana.com";
 101     license = licenses.asl20;
 102     maintainers = with maintainers; [ adjacentresearch ];
 103     platforms = platforms.unix;
 104   };
 105   passthru.updateScript = ./update.sh;
 106 }