pkgs/applications/editors/emacs/elisp-packages/elpa-devel-packages.nix

   1 /*
   2
   3 # Updating
   4
   5 To update the list of packages from ELPA,
   6
   7 1. Run `./update-elpa-devel`.
   8 2. Check for evaluation errors:
   9      # "../../../../../" points to the default.nix from root of Nixpkgs tree
  10      env NIXPKGS_ALLOW_BROKEN=1 nix-instantiate ../../../../../ -A emacs.pkgs.elpaDevelPackages
  11 3. Run `git commit -m "elpa-devel-packages $(date -Idate)" -- elpa-devel-generated.nix`
  12
  13 ## Update from overlay
  14
  15 Alternatively, run the following command:
  16
  17 ./update-from-overlay
  18
  19 It will update both melpa and elpa packages using
  20 https://github.com/nix-community/emacs-overlay. It's almost instantenous and
  21 formats commits for you.
  22
  23 */
  24
  25 { lib, pkgs, buildPackages }:
  26
  27 self: let
  28
  29   inherit (import ./lib-override-helper.nix pkgs lib)
  30     markBroken
  31     ;
  32
  33   # Use custom elpa url fetcher with fallback/uncompress
  34   fetchurl = buildPackages.callPackage ./fetchelpa.nix { };
  35
  36   generateElpa = lib.makeOverridable ({
  37     generated ? ./elpa-devel-generated.nix
  38   }: let
  39
  40     imported = import generated {
  41       callPackage = pkgs: args: self.callPackage pkgs (args // {
  42         inherit fetchurl;
  43       });
  44     };
  45
  46     super = imported;
  47
  48     commonOverrides = import ./elpa-common-overrides.nix pkgs lib buildPackages;
  49
  50     overrides = self: super: {
  51     };
  52
  53     elpaDevelPackages =
  54       let super' = super // (commonOverrides self super); in super' // (overrides self super');
  55
  56   in elpaDevelPackages);
  57
  58 in generateElpa { }