pkgs/applications/editors/libresprite/default.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , fetchpatch
   5
   6 , cmake
   7 , pkg-config
   8 , ninja
   9 , gtest
  10
  11 , curl
  12 , freetype
  13 , giflib
  14 , libjpeg
  15 , libpng
  16 , libwebp
  17 , pixman
  18 , tinyxml
  19 , zlib
  20 , SDL2
  21 , SDL2_image
  22 , lua
  23 , AppKit
  24 , Cocoa
  25 , Foundation
  26
  27 , nixosTests
  28 }:
  29
  30 stdenv.mkDerivation (finalAttrs: {
  31   pname = "libresprite";
  32   version = "1.0";
  33
  34   src = fetchFromGitHub {
  35     owner = "LibreSprite";
  36     repo = "LibreSprite";
  37     rev = "v${finalAttrs.version}";
  38     fetchSubmodules = true;
  39     hash = "sha256-d8GmVHYomDb74iSeEhJEVTHvbiVXggXg7xSqIKCUSzY=";
  40   };
  41
  42   # Backport GCC 13 build fix
  43   # FIXME: remove in next release
  44   patches = [
  45     (fetchpatch {
  46       url = "https://github.com/LibreSprite/LibreSprite/commit/6ffe8472194bf5d0a73b4b2cd7f6804d3c80aa0c.patch";
  47       hash = "sha256-5chXt0H+koofIspYsCJ7/eUxMGcCBVXJcXe3U/7F9Vc=";
  48     })
  49   ];
  50
  51   nativeBuildInputs = [
  52     cmake
  53     pkg-config
  54     ninja
  55     gtest
  56   ];
  57
  58   buildInputs = [
  59     curl
  60     freetype
  61     giflib
  62     libjpeg
  63     libpng
  64     libwebp
  65     pixman
  66     tinyxml
  67     zlib
  68     SDL2
  69     SDL2_image
  70     lua
  71     # no v8 due to missing libplatform and libbase
  72   ] ++ lib.optionals stdenv.hostPlatform.isDarwin [
  73     AppKit
  74     Cocoa
  75     Foundation
  76   ];
  77
  78   cmakeFlags = [
  79     "-DWITH_DESKTOP_INTEGRATION=ON"
  80     "-DWITH_WEBP_SUPPORT=ON"
  81   ];
  82
  83   hardeningDisable = lib.optional stdenv.hostPlatform.isDarwin "format";
  84
  85   # Install mime icons. Note that the mimetype is still "x-aseprite"
  86   postInstall = ''
  87     src="$out/share/libresprite/data/icons"
  88     for size in 16 32 48 64; do
  89       dst="$out"/share/icons/hicolor/"$size"x"$size"
  90       install -Dm644 "$src"/doc"$size".png "$dst"/mimetypes/aseprite.png
  91     done
  92   '';
  93
  94   passthru.tests = {
  95     libresprite-can-open-png = nixosTests.libresprite;
  96   };
  97
  98   meta = with lib; {
  99     homepage = "https://libresprite.github.io/";
 100     description = "Animated sprite editor & pixel art tool, fork of Aseprite";
 101     license = licenses.gpl2Only;
 102     longDescription = ''
 103         LibreSprite is a program to create animated sprites. Its main features are:
 104
 105           - Sprites are composed by layers & frames (as separated concepts).
 106           - Supported color modes: RGBA, Indexed (palettes up to 256 colors), and Grayscale.
 107           - Load/save sequence of PNG files and GIF animations (and FLC, FLI, JPG, BMP, PCX, TGA).
 108           - Export/import animations to/from Sprite Sheets.
 109           - Tiled drawing mode, useful to draw patterns and textures.
 110           - Undo/Redo for every operation.
 111           - Real-time animation preview.
 112           - Multiple editors support.
 113           - Pixel-art specific tools like filled Contour, Polygon, Shading mode, etc.
 114           - Onion skinning.
 115       '';
 116     maintainers = with maintainers; [ fgaz ];
 117     platforms = platforms.all;
 118     # https://github.com/LibreSprite/LibreSprite/issues/308
 119     broken = stdenv.hostPlatform.isDarwin;
 120   };
 121 })