pkgs/applications/editors/vim/plugins/build-vim-plugin.nix

   1 { lib
   2 , stdenv
   3 , rtpPath
   4 , toVimPlugin
   5 }:
   6
   7 {
   8   addRtp = drv: lib.warn "`addRtp` is deprecated, does nothing." drv;
   9
  10   buildVimPlugin =
  11     { name ? "${attrs.pname}-${attrs.version}"
  12     , src
  13     , unpackPhase ? ""
  14     , configurePhase ? ":"
  15     , buildPhase ? ":"
  16     , preInstall ? ""
  17     , postInstall ? ""
  18     , path ? "."
  19     , addonInfo ? null
  20     , meta ? { }
  21     , ...
  22     }@attrs:
  23     let
  24       drv = stdenv.mkDerivation (attrs // {
  25         name = lib.warnIf (attrs ? vimprefix) "The 'vimprefix' is now hardcoded in toVimPlugin" name;
  26
  27         __structuredAttrs = true;
  28         inherit unpackPhase configurePhase buildPhase addonInfo preInstall postInstall;
  29
  30         installPhase = ''
  31           runHook preInstall
  32
  33           target=$out/${rtpPath}/${path}
  34           mkdir -p $out/${rtpPath}
  35           cp -r . $target
  36
  37           runHook postInstall
  38         '';
  39
  40         meta = {
  41           platforms = lib.platforms.all;
  42         } // meta;
  43       });
  44     in
  45       toVimPlugin drv;
  46
  47 }