pkgs/applications/networking/cluster/kuma/default.nix

   1 { lib
   2 , fetchFromGitHub
   3 , buildGoModule
   4 , coredns
   5 , installShellFiles
   6 , isFull ? false
   7 , enableGateway ? false
   8 , pname ? "kuma"
   9 , components ? lib.optionals isFull [
  10     "kumactl"
  11     "kuma-cp"
  12     "kuma-dp"
  13   ]
  14 }:
  15
  16 buildGoModule rec {
  17   inherit pname;
  18   version = "2.8.3";
  19   tags = lib.optionals enableGateway [ "gateway" ];
  20
  21   src = fetchFromGitHub {
  22     owner = "kumahq";
  23     repo = "kuma";
  24     rev = version;
  25     hash = "sha256-wGEO7DJLWy/d6SYsTb8EZhF9c1ptYBXDL/Owter4nfo=";
  26   };
  27
  28   vendorHash = "sha256-PAW2Byzz6Ky4I51QrJoNoyn1QH/i0SeU2dDHvj2BqXM=";
  29
  30   # no test files
  31   doCheck = false;
  32
  33   nativeBuildInputs = [ installShellFiles ] ++ lib.optionals isFull [ coredns ];
  34
  35   preBuild = ''
  36     export HOME=$TMPDIR
  37   '';
  38
  39   subPackages = map (p: "app/" + p) components;
  40
  41   postInstall = lib.concatMapStringsSep "\n" (p: ''
  42     installShellCompletion --cmd ${p} \
  43       --bash <($out/bin/${p} completion bash) \
  44       --fish <($out/bin/${p} completion fish) \
  45       --zsh <($out/bin/${p} completion zsh)
  46   '') components + lib.optionalString isFull ''
  47     ln -sLf ${coredns}/bin/coredns $out/bin
  48   '';
  49
  50   ldflags = let
  51     prefix = "github.com/kumahq/kuma/pkg/version";
  52   in [
  53     "-s" "-w"
  54     "-X ${prefix}.version=${version}"
  55     "-X ${prefix}.gitTag=${version}"
  56     "-X ${prefix}.gitCommit=${version}"
  57     "-X ${prefix}.buildDate=${version}"
  58   ];
  59
  60   meta = with lib; {
  61     description = "Service mesh controller";
  62     homepage = "https://kuma.io/";
  63     changelog = "https://github.com/kumahq/kuma/blob/${version}/CHANGELOG.md";
  64     license = licenses.asl20;
  65     maintainers = with maintainers; [ zbioe ];
  66   };
  67 }